freertos任务读取福申甲醛传感器

esp32开发包自带freertos移植。
注意使用了结构体，字符串需要明确的长度，否则esp32会无限重启。

#include <ArduinoJson.h>

#include <AsyncWebSocket.h>
#include <ESPAsyncWebServer.h>

#include <SPIFFS.h>
#include <WiFi.h>

#define ESP_getChipId()   ((uint32_t)ESP.getEfuseMac())
#define MAX_CLIENTS 4
#define QUEUE_SIZE 6

typedef struct {
  float value;
  const char *pdata;
} MyData;
QueueHandle_t queue;


// http
AsyncWebServer server(80);
AsyncWebSocket ws("/chat");
AsyncWebSocketClient* activeClients[MAX_CLIENTS];

// custom
char crc(String s);
void onWsEvent(AsyncWebSocket *server, AsyncWebSocketClient *client, AwsEventType type,
               void *arg, uint8_t *data, size_t len);

void task_readsensor(void* parameter) {
  float value = 0;
  String buffer = "";
  String buffer2 = "";
  for (;;) {
    // 读甲醛传感器
    if (Serial2.available() > 0) {
      int data = Serial2.read();
      buffer += (char)data;
      buffer2 += String(data, HEX) + " ";
    }

    if (buffer.charAt(0) == 0xff && buffer.length() == 9) {
      // 验证crc
      char crcValue = crc(buffer);
      if (crcValue == buffer.charAt(8)) {
        value = (float)(buffer.charAt(4) * 256 + buffer.charAt(5)) / 1000.0;
        // 生产数据
        MyData data;
        data.value = value;
        data.pdata = buffer2.c_str();
        xQueueSend(queue, &data, portMAX_DELAY);
      }
      else
        Serial.println("crc not equal");

      buffer = "";
      buffer2 = "";
    }  // if 1

    vTaskDelay(5);
  } //for
}

void task_hmi(void* parameter) {
  for (;;) {
    // json
    DynamicJsonDocument  doc(100);
    doc.clear();
    doc["time"] = millis() / 1000;
    // 消费数据
    MyData data;
    BaseType_t ok = xQueueReceive(queue, &data, portMAX_DELAY);
    if (ok == pdTRUE) {
      doc["value"] = data.value;
      doc["raw"] = String(data.pdata);
    }
    // websocket， 发送数据
    String result = "";
    serializeJson(doc, result);

    ws.cleanupClients();
    for (int i = 0; i < MAX_CLIENTS; i++) {
      if (activeClients[i] != nullptr) {
        if (!activeClients[i]->queueIsFull())
          activeClients[i]->text(result);
      }
    }

    //
    vTaskDelay(500);
  }

}

void setup() {
  // Initialize the slots
  for (int i = 0; i < MAX_CLIENTS; i++) activeClients[i] = nullptr;

  Serial.begin(9600);
  Serial2.begin(9600);
  // spiffs
  if (!SPIFFS.begin()) {
    Serial.println("An Error has occurred while mounting SPIFFS");
  }
  // wifi
  IPAddress ip(192, 168, 1, 1);
  IPAddress gw(192, 168, 1, 1);
  IPAddress mask(255, 255, 255, 0);
  WiFi.softAPConfig(ip, gw, mask);
  String chip_id = "ESP_" + String(ESP_getChipId());
  const char *ssid = chip_id.c_str();

  //wifi_power_t wifi_power;
  WiFi.softAP(ssid);
  WiFi.setTxPower(WIFI_POWER_19_5dBm);
  Serial.println("Tx power-----");
  Serial.println(WiFi.getTxPower());
  Serial.println("------Tx power");

  // http
  server.on("/", HTTP_GET, [](AsyncWebServerRequest * request) {
    request->send(SPIFFS, "/index.html", "text/html");
  });

  server.on("/zepto.js.gz", HTTP_GET, [](AsyncWebServerRequest * request) {
    AsyncWebServerResponse *response = request->beginResponse(SPIFFS, "/zepto.js.gz", "text/javascript");
    response->addHeader("Content-Encoding", "gzip");
    request->send(response);
  });

  server.on("/mini-nord.css.gz", HTTP_GET, [](AsyncWebServerRequest * request) {
    AsyncWebServerResponse *response = request->beginResponse(SPIFFS, "/mini-nord.css.gz", "text/css");
    response->addHeader("Content-Encoding", "gzip");
    request->send(response);
  });

  ws.onEvent(onWsEvent);
  server.addHandler(&ws);
  server.begin();

  queue = xQueueCreate(QUEUE_SIZE, sizeof(MyData));

  // task
  xTaskCreate(
    task_readsensor,
    "task_1",
    10000,
    NULL,
    1,
    NULL);
  xTaskCreate(
    task_hmi,
    "task_2",
    10000,
    NULL,
    3,
    NULL);
}

void loop() {

  delay(100);

  // loop
}

// CRC计算
char crc(String s) {
  int sum = 0;
  for (int i = 1; i < s.length() - 1; i++)
    sum += s[i];
  int value = ~sum + 1;
  return value & 0xff;

}

void onWsEvent(AsyncWebSocket *server, AsyncWebSocketClient *client, AwsEventType type,
               void *arg, uint8_t *data, size_t len) {
  switch (type) {
    case WS_EVT_CONNECT:
      Serial.printf("WebSocket client #%u connected from %s\n", client->id(), client->remoteIP().toString().c_str());
      for (int i = 0; i < MAX_CLIENTS; i++)
        if (activeClients[i] == nullptr) {
          activeClients[i] = client;
          activeClients[i]->keepAlivePeriod(1);
          break;
        }
      break;
    case WS_EVT_DISCONNECT:
      Serial.printf("WebSocket client #%u disconnected\n", client->id());
      for (int i = 0; i < MAX_CLIENTS; i++)
        if (activeClients[i] == client) {
          activeClients[i] = nullptr;
          break;
        }
      break;
    case WS_EVT_DATA:
    case WS_EVT_PONG:
    case WS_EVT_ERROR:
      Serial.printf("ws[%s][%u] error(%u): %s\n", server->url(), client->id(), *((uint16_t*)arg), (char*)data);
      break;
  }
}