身份证号校验的 js

关注

原创最新推荐文章于 2026-02-06 01:48:42 发布 1.1k 阅读 AI 写同款· GEO 优化 ›

身份证号校验原理及JavaScript实现在网站中，总有各种各样的表单，用户使用表单来向服务器发送数据，进行交互。然而，代代相传的经验是，永远不要信任用户的输入，一定要对数据进行验证。如果使用不经验证的表单，轻则会有大量无效提交进入服务器，严重影响网站运行；重则招致XSS攻击~ 所以对输入进行验证是必要的。而为了减轻服务器的压力，除了密码正误等需要向数据库交互才能验证的输入之外，绝大部分输入的验证都应当在前端进行。其中。。阅读详情

var Errors=new Array(

"验证通过!",

"身份证号码位数不对!",

"身份证号码出生日期超出范围或含有非法字符!",

"身份证号码校验错误!",

"身份证地区非法!"

);

var result=checkIdcard(IDCardNoValue);

if(result!=0)

{

//你的代码 here

}

''' -----------------------------------------------------------------------------
    ''' <summary>
    ''' 将15位的身份证号码升级到18位
    ''' </summary>
    ''' <param name="IDCard15">15位的身份证号码</param>
    ''' <returns>18位的身份证号码</returns>
    ''' <remarks>
    '''     根据〖中华人民共和国国家标准 GB 11643-1999〗中有关公民身份号码的规定，公民身份号码是特征组合码，由十七位数字本体码和一位数字校验码组成。
    ''' 排列顺序从左至右依次为：六位数字地址码，八位数字出生日期码，三位数字顺序码和一位数字校验码。
    ''' 地址码表示编码对象常住户口所在县(市、旗、区)的行政区划代码。
    ''' 生日期码表示编码对象出生的年、月、日，其中年份用四位数字表示，年、月、日之间不用分隔符。
    ''' 顺序码表示同一地址码所标识的区域范围内，对同年、月、日出生的人员编定的顺序号。
    ''' 顺序码的奇数分给男性，偶数分给女性。
    ''' 校验码是根据前面十七位数字码，按照ISO 7064:1983.MOD 11-2校验码计算出来的检验码。
    '''
    ''' 注意:这里没有考虑1900年以及之前出生的人的情况
    '''
    ''' </remarks>
    ''' <history>
    '''     [Hudan]    2005-8-8    Created
    ''' </history>
    ''' -----------------------------------------------------------------------------
    Public Function IDCard15to18(ByVal IDCard15 As String) As String

        Dim IDCard17 As String

        '将出生年扩展为4位,即在2位数的出生年前面加19 (这里没有考虑1900年以及之前出生的人的情况)
        'IDCard18 = IDCard15.Substring(0, 6) + "19" + IDCard15.Substring(6)
        IDCard17 = IDCard15.Insert(6, "19")

        '计算校验码
        Dim code As Char
        code = GetCheckCode(IDCard17)

        '返回18位身份证号码
        Return IDCard17 + code.ToString()

    End Function

    ''' -----------------------------------------------------------------------------
    ''' <summary>
    ''' 判断身份证号码的校验码是否正确
    ''' </summary>
    ''' <param name="IDCard18">18位身份证号码</param>
    ''' <returns>true表示验证码正确,否则表示验证码错误</returns>
    ''' <remarks>
    ''' 注意:
    ''' 此方法只是对验证码进行判断,不判断身份证号码其它部分的合法性.
    ''' 比如出现666666198013320014这样的号码,显然是非法的身份证号码
    ''' 666666的地区号目前是不存在的
    ''' 1980年没有13月,也没有32日
    ''' 但是它的校验码4却是正确的
    ''' </remarks>
    ''' <history>
    '''     [Hudan]    2005-8-8    Created
    ''' </history>
    ''' -----------------------------------------------------------------------------
    Public Function ValidCheckcode(ByVal IDCard18 As String) As Boolean

        '参数IDCard18中的校验码
        Dim currentCode As Char
        currentCode = IDCard18.Chars(17)

        '正确的验证码
        Dim ValidCode As Char
        ValidCode = GetCheckCode(IDCard18.Substring(0, 17))

        Return ValidCode.Equals(currentCode)

    End Function

    ''' -----------------------------------------------------------------------------
    ''' <summary>
    ''' 根据身份证号码的前17位数字生成最后一位的校验码
    ''' </summary>
    ''' <param name="IDCard17">身份证号码的前17位数字</param>
    ''' <returns>校验码(身份证号码的第18位)</returns>
    ''' <remarks>
    ''' </remarks>
    ''' <history>
    '''     [Hudan]    2005-8-8    Created
    ''' </history>
    ''' -----------------------------------------------------------------------------
    Public Function GetCheckCode(ByVal IDCard17 As String) As Char

        '按照ISO 7064:1983.MOD 11-2校验码计算出来的检验码
        '公式如下:
        '∑(ai×Wi)(mod 11)
        'i----表示号码字符从右至左包括校验码在内的位置序号；
        'ai----表示第i位置上的号码字符值；
        'Wi----示第i位置上的加权因子，其数值依据公式Wi=2^(n-1)(mod 11)计算得出。
        Dim num As Integer = 0
        For i As Integer = 18 To 2 Step -1
            num += CInt(IDCard17.Substring(18 - i, 1)) * (2 ^ (i - 1) Mod 11)
        Next
        num = num Mod 11

        '然后根据计算的结果，从下面的表中查出相应的校验码，其中X表示计算结果为10：
        '∑(ai×WI)(mod 11) 0 1 2 3 4 5 6 7 8 9 10
        '校验码字符值ai 1 0 X 9 8 7 6 5 4 3 2
        Dim checkcode As String
        Select Case num
            Case 0
                checkcode = "1"
            Case 1
                checkcode = "0"
            Case 2
                'TODO: X是大写还是小写还未确定(刚好我的身份证的校验码是小写x,不知道大写X是否也可行)
                checkcode = "x"
            Case Else
                checkcode = CStr(12 - num)
        End Select

        Return CChar(checkcode)

    End Function

4下面是写成数据库的函数形式(原著不名,我在网上搜索到的都没有标明作者),其实知道了算法,写成SQL语句也不困难:

Create function getCheckCode(@SFZH char(18))
  Returns char(1)
  As
  Begin
  declare @r char(1)
  declare @i int
  if len(@SFZH) <> 18
  set @r = '?'
  else
  set @i = cast(substring(@SFZH,1,1) as int) * 7
  +cast(substring(@SFZH,2,1) as int) * 9
  +cast(substring(@SFZH,3,1) as int) * 10
  +cast(substring(@SFZH,4,1) as int) * 5
  +cast(substring(@SFZH,5,1) as int) * 8
  +cast(substring(@SFZH,6,1) as int) * 4
  +cast(substring(@SFZH,7,1) as int) * 2
  +cast(substring(@SFZH,8,1) as int) * 1
  +cast(substring(@SFZH,9,1) as int) * 6
  +cast(substring(@SFZH,10,1) as int) * 3
  +cast(substring(@SFZH,11,1) as int) * 7
  +cast(substring(@SFZH,12,1) as int) * 9
  +cast(substring(@SFZH,13,1) as int) * 10
  +cast(substring(@SFZH,14,1) as int) * 5
  +cast(substring(@SFZH,15,1) as int) * 8
  +cast(substring(@SFZH,16,1) as int) * 4
  +cast(substring(@SFZH,17,1) as int) * 2
  set @i = @i - @i/11 * 11
  set @r = (case @i
  when 0 then '1' when 1 then '0' when 2 then 'X' when 3 then '9'
  when 4 then '8' when 5 then '7' when 6 then '6' when 7 then '5'
  when 8 then '4' when 9 then '3' when 10 then '2' else '/' end)
  Return(@r)
  End

收录于