halcon PCB板上找焊盘的实例讲解

最新推荐文章于 2025-11-15 09:49:23 发布

原创最新推荐文章于 2025-11-15 09:49:23 发布 · 5.2k 阅读

6 ·

CC 4.0 BY-SA版权

文章标签：

#halcon

图形开发专栏收录该内容

18 篇文章

订阅专栏

本文介绍了一种用于检测半导体封装中球形焊点的图像处理算法。该算法通过二值化、形态学操作等步骤从图像中识别并测量焊点的尺寸。

* ball.hdev: Inspection of Ball Bonding
*
dev_update_window ('off')
dev_close_window ()
dev_open_window (0, 0, 728, 512, 'black', WindowID)
read_image (Bond, 'die/die_03')
dev_display (Bond)
set_display_font (WindowID, 14, 'mono', 'true', 'false')
disp_continue_message (WindowID, 'black', 'true')
stop ()
*二值化
threshold (Bond, Bright, 100, 255)
*把区域变换为长方形
shape_trans (Bright, Die, 'rectangle2')
dev_set_color ('green')
dev_set_line_width (3)
dev_set_draw ('margin')
dev_display (Die)
disp_continue_message (WindowID, 'black', 'true')
stop ()
*重新剪切图片,边上的不要

reduce_domain (Bond, Die, DieGrey)

*二值化
threshold (DieGrey, Wires, 0, 50)
*填充中间空洞

fill_up_shape (Wires, WiresFilled, 'area', 1, 100)

dev_display (Bond)
dev_set_draw ('fill')
dev_set_color ('red')
dev_display (WiresFilled)
disp_continue_message (WindowID, 'black', 'true')
stop ()
*开运算,先腐蚀后膨胀,用来清除掉小杂点;闭运算相反,用来填充.

opening_circle (WiresFilled, Balls, 15.5)

dev_set_color ('green')
dev_display (Balls)
disp_continue_message (WindowID, 'black', 'true')
stop ()
*计算连通区域
connection (Balls, SingleBalls)
*选择像圆的区域
select_shape (SingleBalls, IntermediateBalls, 'circularity', 'and', 0.85, 1.0)
*排队排队
sort_region (IntermediateBalls, FinalBalls, 'first_point', 'true', 'column')
dev_display (Bond)
dev_set_colored (12)
dev_display (FinalBalls)
disp_continue_message (WindowID, 'black', 'true')
stop ()
*这个关键了,最小化拟合圆,还得到了中心点和半径
smallest_circle (FinalBalls, Row, Column, Radius)
NumBalls := |Radius|
Diameter := 2*Radius
meanDiameter := sum(Diameter)/NumBalls
mimDiameter := min(Diameter)
dev_display (Bond)
disp_circle (WindowID, Row, Column, Radius)
dev_set_color ('white')
for i := 1 to NumBalls by 1
if (fmod(i,2)=1)
disp_message (WindowID, 'D: '+Diameter[i-1], 'image', Row[i-1]-2.7*Radius[i-1], max([Column[i-1]-60,0]), 'white', 'false')
else
disp_message (WindowID, 'D: '+Diameter[i-1], 'image', Row[i-1]+1.2*Radius[i-1], max([Column[i-1]-60,0]), 'white', 'false')
endif

endfor

* dump_window (WindowID, 'tiff_rgb', './ball')
dev_set_color ('green')
dev_update_window ('on')
disp_continue_message (WindowID, 'black', 'true')
stop ()
dev_close_window ()