CMake教程及使用案例

Ubuntu下cmake教程实践从入门到会用 如果你下载别人的开源代码,你会发现很多人的项目中有个CMakeLists.txt。其实这是因为他们用cmake这个软件来编译整个项目。 为何要用cmake? 如果不用cmake的话那么我们一般会用visual studio这种软件来编译运行整个项目。但是这里有个问题我visual studio2010的项目很可能vs2017打不开。这就很麻烦。于是人们开始想我能不能有个软件,我们写好各个模块的... 阅读详情

转载:https://www.hahack.com/codes/cmake

为什么需要CMake

如果你一直在windows平台上开发,使用最多的可能就是VS的开发环境,它已经集成了全套的开发环境包括构建编译等。你或许听过好几种 Make 工具,例如 GNU Make ,QT 的 qmake ,微软的 MS nmake,BSD Make(pmake),Makepp,等等。这些 Make 工具遵循着不同的规范和标准,所执行的 Makefile 格式也千差万别。这样就带来了一个严峻的问题:如果软件想跨平台,必须要保证能够在不同平台编译。而如果使用上面的 Make 工具,就得为每一种标准写一次 Makefile ,这将是一件让人抓狂的工作。

CMake就是针对上面问题所设计的工具:它首先允许开发者编写一种平台无关的 CMakeList.txt 文件来定制整个编译流程,然后再根据目标用户的平台进一步生成所需的本地化 Makefile 和工程文件,如 Unix 的 Makefile 或 Windows 的 Visual Studio 工程。从而做到"Write once, run everywhere”。显然,CMake 是一个比上述几种 make 更高级的编译配置工具。一些使用 CMake 作为项目架构系统的知名开源项目有 VTK、ITK、KDE、OpenCV、OSG 等。

这里先给出CMake的官方教程。

Linux 下安装CMake

1、安装gcc等必备程序包(已安装则略过此步)

yum install -y gcc gcc-c++ make automake 

2、安装wget (已安装则略过此步)

yum install -y wget

3、安装OpenSSL

yum install openssl
yum install openssl-devel

4、获取CMake源码包

wget https://cmake.org/files/v3.19/cmake-3.19.0-rc1.tar.gz

5、解压CMake源码包

tar -zxvf cmake-3.19.0-rc1.tar.gz

6、进入cmark的源码目录

cd cmake-3.19.0-rc1

7、运行当前目录下的一个文件

./bootstrap

8、运行gmake命令(这步时间有点长),如果安装了make却提示找不到gmake,只需要使用sudo ln -s /usr/bin/make /usr/bin/gmake,然后

gmake

9、进行安装

sudo gmake install

10、 安装完成,查看cmake版本号,如果输出版本号,则安装成功。

cmake --version

入门:单个源文件

简单的项目,只需要单个源文件就可以。如果现在有一个main.cpp,内容如下:

#include <iostream>
using namespace std;
int main(int argc, char **argv)
{
    cout << "Hello CMake!" << endl;
    return 0;
}

我们在同级目录下新建一个CMakeList.txt,其内容如下:

# CMake 最低版本号要求
cmake_minimum_required(VERSION 3.19)
# 项目名称
project(demo1)
# 指定生成目标,将main.cpp生成一个名为demo1的可以执行文件
add_executable(demo1 main.cpp)

需要注意的是,CMake是不区分大小写的;# 开头该行会被视为注释;命令由命令名称、小括号、参数组成;参数之间用空格间隔。

CMake编译运行

现在我们在当前目录中使用cmake .执行,可以观察到多了几个和CMake相关的文件,如下:

CMakeCache.txt  CMakeFiles  CMakelists.txt  Makefile  cmake_install.cmake  demo1  main.cpp

其中有一个文件是Makefile,再用make命令编译就得到demo1可执行文件。

  • 直接生成二进制文件

还可以直接调用CMake构建系统以实际编译/链接项目

cmake --build .

可以看到生成了可执行二进制文件。

同目录多个源文件

实际项目中在一个目录中会有很多个源文件,现在开始编写一个目录中,多个源文件情况:

├── CMakelists.txt
├── MyMath.cpp
├── MyMath.h
└── main.cpp

MyMath.h文件内容如下:

#pragma once
int my_add(int a, int b);

MyMath.cpp文件内容如下:

#include "MyMath.h"
int my_add(int a, int b)
{
    return a + b;
}

main.cpp文件内容如下:

#include <iostream>
#include "MyMath.h"
using namespace std;
int main(int argc, char **argv)
{
    cout << my_add(1, 2) << endl;
    return 0;
}

CMakelists.txt文件内容如下:

# CMake 最低版本号要求
cmake_minimum_required(VERSION 3.19)
# 项目名称
project(demo2)
# 指定生成目标,将main.cpp,MyMath.cpp生成一个名为demo2的可以执行文件
add_executable(demo2 main.cpp MyMath.cpp)

和单个文件类似,仅仅只在add_executable中添加了一个MyMath.cpp源文件,虽然这样写没有问题,但是当源文件很多时,把所有的源文件加入是很繁琐的工作。

我们可以使用aux_source_directory命令,该命令会查找指定目录下所有的源文件,并将结果存在指定的变量名中,如下:

aux_source_directory(<dir> <variable>)

因此,修改CMakeList为如下:

# CMake 最低版本号要求
cmake_minimum_required(VERSION 3.19)
# 项目名称
project(demo2)
# 将当前目录所有源文件保存在变量DIR_SRCS中
aux_source_directory(. DIR_SRCS)
# 指定生成目标,将DIR_SRCS变量的所有源文件生成一个名为demo2的可以执行文件
add_executable(demo2 ${DIR_SRCS})

多目录&多源文件

现在我们的项目中不仅有多个源文件,还有一些其他的库目录,比如我们要使用一个自己的math目录,其文件结构如下:

├── CMakelists.txt
├── MyPrint.cpp
├── MyPrint.h
├── main.cpp
└── math
    ├── CMakelists.txt
    ├── MyMath.cpp
    └── MyMath.h
  • 子目录math下文件内容

MyPrint.h的文件内容:

#pragma once
int my_add(int a, int b);

MyPrint.cpp的文件内容:

#include "MyMath.h"
int my_add(int a, int b)
{
    return a + b;
}

CMakelists.txt的文件内容:

# 将当前目录所有源文件保存在变量DIR_LIB_SRCS中
aux_source_directory(. DIR_LIB_SRCS)
# 将DIR_LIB_SRCS变量中的所有源文件编译成静态链接库,链接库名为MyMath
add_library (MyMath ${DIR_LIB_SRCS})
  • 主目录下文件内容

MyPrint.h的文件内容:

#pragma once
void my_print(int a);

MyPrint.cpp的文件内容:

#include "MyPrint.h"
#include <stdio.h>
void my_print(int a)
{
    printf("%d", a);
}

main.cpp的文件内容:

#include "math/MyMath.h"
#include "MyPrint.h"
#include <iostream>
using namespace std;
int main(int argc, char **argv)
{
    my_print(my_add(1, 2));
    return 0;
}

CMakelists.txt的文件内容:

# CMake 最低版本号要求
cmake_minimum_required(VERSION 3.19)
# 项目名称
project(demo3)
# 将当前目录所有源文件保存在变量DIR_SRCS中
aux_source_directory(. DIR_SRCS)
# 添加子目录
add_subdirectory(math)
# 指定生成目标,将DIR_SRCS变量的所有源文件生成一个名为demo2的可以执行文件
add_executable(demo3 ${DIR_SRCS})
# 添加链接库,MyMath是子目录中的链接库名
target_link_libraries(demo3 MyMath)

add_subdirectory指明本项目包含一个子目录math,这样math下的CMakelists.txt文件和源代码也会被处理。

target_link_libraries指明可执行文件 demo3需要链接一个名为MyMath的链接库。

add_library将某个目录中的源文件编译为静态链接库。

自定义编译选项

CMake可以为项目增加编译选项,从而可以根据用户的环境和需求选择最合适的编译方案。

例如,可以将MyMath库设计为一个可选库,如果该选项为ON,就是用该库中定义的数学函数来进行宏运算。否则就调用标准库中的数学函数库。

现在用abs函数来举例,在MyMath库中重新定义一个my_abs函数,当前文件目录如下:

├── CMakelists.txt
├── config.h.in
├── main.cpp
└── math
    ├── CMakelists.txt
    ├── MyMath.cpp
    └── MyMath.h
  • 子目录math下文件内容

MyMath.h的文件内容:

#pragma once
int my_abs(int a);

MyMath.cpp的文件内容:

#include "MyMath.h"
int my_abs(int a)
{
    return a >= 0 ? a : -a;
}

CMakelists.txt的文件内容:

# 将当前目录所有源文件保存在变量DIR_LIB_SRCS中
aux_source_directory(. DIR_LIB_SRCS)
# 生成链接库名为MyMath
add_library (MyMath ${DIR_LIB_SRCS})
  • 主目录下文件内容

config.h.in的文件内容:

#cmakedefine USE_MYMATH

main.cpp的文件内容:

#include "math/MyMath.h"
#include "config.h"
#include <stdio.h>

#ifdef USE_MYMATH
#include "math/MyMath.h"
#else
#include "math.h"
#endif

int main(int argc, char **argv)
{
#ifdef USE_MYMATH
    printf("my abs: %d", my_abs(-1));
#else
    printf("std abs: %d", abs(-1));
#endif
    return 0;
}

CMakelists.txt的文件内容:

# CMake 最低版本号要求
cmake_minimum_required(VERSION 3.19)
# 项目名称
project(demo4)

# 加入一个配置头文件,用于处理CMake对源码的设置
configure_file(
    "${PROJECT_SOURCE_DIR}/config.h.in"
    "${PROJECT_BINARY_DIR}/config.h"
)
# 加入一个配置头文件,用于处理CMake对源码的设置
configure_file(
    "${PROJECT_SOURCE_DIR}/config.h.in"
    "${PROJECT_BINARY_DIR}/config.h"
)
# 是否使用自己的MyMath库
option(USE_MYMATH "Use MyMath" ON)
# 是否加入MyMath库
if(USE_MYMATH)
    include_directories ("${PROJECT_SOURCE_DIR}/math")
    add_subdirectory (math)  
    list(APPEND EXTRA_LIBS MyMath)
    list(APPEND EXTRA_INCLUDE "${PROJECT_SOURCE_DIR}/math")
endif(USE_MYMATH)

# 将当前目录所有源文件保存在变量DIR_SRCS中
aux_source_directory(. DIR_SRCS)
# 指定生成目标,将DIR_SRCS变量的所有源文件生成一个名为demo2的可以执行文件
add_executable(demo4 ${DIR_SRCS})

# 添加链接库,MyMath是子目录中的库的名字
target_link_libraries(demo4 PUBLIC ${EXTRA_LIBS})
# 添加二进制树到头文件搜索路径,才能发现config.h
target_include_directories(demo4 PUBLIC "${PROJECT_BINARY_DIR}" ${EXTRA_INCLUDE})

其中configure_file命令将config.h.in生成config.h文件,通过这种机制,可以通过预定义一些参数和变量来控制代码的生成。

option命令添加了一个USE_MYMATH选项,并且设置为ON。

根据 USE_MYMATH 变量的值来决定是否使用我们自己编写的MyMath库。

main.cpp中,主函数根据USE_MYMATH的预定义值决定使用标准库还是MyMath库。

主函数中引入头文件#include "config.h",我们并不直接编写这个文件,而是从CMakeList.txt中配置的config.h.in文件来生成它,我们只需要编写config.h.in文件,其内容如上面代码所示,如果option的USE_MYMATH为ON,生成的config.h中定义的内容是#define USE_MYMATH,如果为OFF,生成的config.h中定义的内容是/* #undef USE_MYMATH */。

还可以交互式的选择该变量的值,使用ccmake命令,也可以使用 cmake -i 命令,该命令会提供一个会话式的交互式配置界面,从中可以找到定义的 USE_MYMATH 选项,按键盘的方向键可以在不同的选项窗口间跳转,按下 enter 键可以修改该选项。修改完成后可以按下 c 选项完成配置,之后再按 g 键确认生成 Makefile 。ccmake 的其他操作可以参考其窗口下方给出的指令提示。

定制安装规则&测试

CMake可以指定安装规则,以及添加测试。这两个功能分别可以通过在产生Makefile后使用make install来执行。在以前的GNU Makefile中,你可能需要为此编写install和test两个伪目标和相应的规则,但是在CMake里,这样的工作同样只需要几条命令。

为工程定制安装规则

还是使用上面demo4例子,首先在math/CMakelists.txt文件末尾添加下面几行:

# 指定MyMath库的安装路径
install(TARGETS MyMath DESTINATION bin)
install(FILES MyMath.h DESTINATION include)

用来指明MyMath库的安装路径。然后再修改根目录的CMakelists.txt文件,在末尾添加下面几行:

# 指定安装路径
install(TARGETS demo4 DESTINATION bin)
install(FILES "${PROJECT_BINARY_DIR}/config.h" DESTINATION include)

通过上卖弄的定制,生成的Demo文件和MyMath函数库libMyMath.a文件会被复制到/usr/local/bin 中,而MyMath.h和生成的config.h文件则会被复制到/usr/local/include中。我们可以验证一下(注意:这里的/usr/local/是默认安装到的根目录,可以通过修改CMAKE_INSTALL_PREFIX变量的值来指定这些文件应该拷贝到哪个根目录)

[crazyang@zt demo4]$ sudo make install
[ 50%] Built target MyMath
[100%] Built target demo4
Install the project...
-- Install configuration: ""
-- Installing: /usr/local/bin/libMyMath.a
-- Installing: /usr/local/include/MyMath.h
-- Installing: /usr/local/bin/demo4
-- Installing: /usr/local/include/config.h
[crazyang@zt demo4]$ ls /usr/local/bin/
demo4  libMyMath.a
[crazyang@zt demo4]$ ls /usr/local/include/
MyMath.h  config.h

为工程添加测试

添加测试也比较简单。CMake提供了一个称为CTest的测试工具。我们要做的只是在项目根目录的CMakelists文件中调用一系列的add_test命令。

还是使用demo4举例子,但是为了方便演示,将demo4的主函数修改一下,使用传入的参数:

#include "math/MyMath.h"
#include "config.h"
#include <stdio.h>
#include <stdlib.h>

#ifdef USE_MYMATH
#include "math/MyMath.h"
#else
#include "math.h"
#endif

int main(int argc, char **argv)
{
    if (argc < 2)
    {
        printf(Usage:);
        return 1;
    }
#ifdef USE_MYMATH
    printf("my abs: %d", my_abs(atoi(argv[1])));
#else
    printf("std abs: %d", abs(atoi(argv[1])));
#endif
    return 0;
}

在根目录的CMakelists.txt文件,在末尾添加下面几行:

# 启用测试
enable_testing()

# 测试程序是否成功运行
add_test(test_run demo4 -1)
# 测试帮助信息是否可以正常提示
add_test (test_usage demo4)
set_tests_properties (test_usage PROPERTIES PASS_REGULAR_EXPRESSION "Usage:.*")

# 测试-2的绝对值
add_test(test_-2 demo4 -2)
set_tests_properties (test_-2 PROPERTIES PASS_REGULAR_EXPRESSION "2")
# 测试5的绝对值
add_test(test_5 demo4 5)
set_tests_properties (test_5 PROPERTIES PASS_REGULAR_EXPRESSION "5")

上面的CMake包含了3个测试,test_run用来测试程序是否成功并返回0值,括号中分别是测试名,二进制运行文件名,主函数传入的参数。剩下的两个测试分别用来测试-2的绝对值、5的绝对值是否能得到正确的结果。其中PASS_REGULAR_EXPRESSION用来测试输出是否包含后面跟着的字符串。

测试的结果如下:

[crazyang@zt-2013412:/mnt/d/CODE/demo4]$ make test
Running tests...
Test project /mnt/d/CODE/demo4
    Start 1: test_run
1/4 Test #1: test_run .........................   Passed    0.04 sec
    Start 2: test_usage
2/4 Test #2: test_usage .......................   Passed    0.05 sec
    Start 3: test_1
3/4 Test #3: test_1 ...........................   Passed    0.04 sec
    Start 4: test_2
4/4 Test #4: test_2 ...........................   Passed    0.04 sec

100% tests passed, 0 tests failed out of 4

Total Test time (real) =   0.17 sec

如果测试太多数据,按上面那么写会非常繁琐。这是可以通过编写宏来实现:

# 定义一个宏,用来简化测试工作
macro(do_test arg1 result)
    add_test(test_${arg1} demo4 ${arg1})
    set_tests_properties(test_${arg1} PROPERTIES PASS_REGULAR_EXPRESSION ${result})
endmacro(do_test arg1 result)

# 使用该宏进行一系列的数据测试
do_test(-1 "1")
do_test(-5 "5")
do_test(10 "10")

关于CTest的更详细文档可以用过命令man 1 ctest 参考CTest的文档。

支持gdb调试

使CMake支持gdb设置也很容易,只需要指定Debug模式下开启-g选项:

set(CMAKE_BUILD_TYPE "Debug")
set(CMAKE_CXX_FLAGS_DEBUG "$ENV{CXXFLAGS} -O0 -Wall -g -ggdb")
set(CMAKE_CXX_FLAGS_RELEASE "$ENV{CXXFLAGS} -O3 -Wall")

之后可以直接对生成的程序使用 gdb 来调试。

添加环境检查

有时候我们需要对系统环境做检查,例如要使用一个平台相关的特性的时候。在还是继续使用demo4,我们需要检查系统是否自带abs函数。如果系统带有abs函数,就使用它,否则使用我们自定义的my_abs函数。

添加CheckFunctionExists宏

首先在项目目录下的CMakelists.txt文件中添加CheckFunctionExists.cmake宏,并调用check_function_exists命令测试连接器能否在链接阶段找到abs函数。

# 检查系统是否支持abs函数
include(${CMAKE_ROOT}/Modules/CheckFunctionExists.cmake)
check_function_exists(abs HAVE_ABS)

注意:这段代码必须放在configure_file命令前面,并且删除上面的demo4的CMakelists.txt中的option(USE_MYMATH "Use MyMath" ON),并将条件判断变量修改成HAVE_ABS,如下所示:

# 检查系统是否支持abs函数
include(${CMAKE_ROOT}/Modules/CheckFunctionExists.cmake)
check_function_exists(abs HAVE_ABS)

# 加入一个配置头文件,用于处理CMake对源码的设置
configure_file(
    "${PROJECT_SOURCE_DIR}/config.h.in"
    "${PROJECT_BINARY_DIR}/config.h"
)
# 是否加入MyMath库
if(HAVE_ABS)
    include_directories ("${PROJECT_SOURCE_DIR}/math")
    add_subdirectory (math)  
    list(APPEND EXTRA_LIBS MyMath)
    list(APPEND EXTRA_INCLUDE "${PROJECT_SOURCE_DIR}/math")
endif(HAVE_ABS)

预定于相关宏变量

现在修改config.h.in文件,预定义相关的宏变量。

#cmakedefine HAVE_ABS

在代码中使用宏和函数

最后一步是修改main.cpp,在代码中使用宏和函数,主要代码如下:

#ifdef HAVE_ABS
#include "math.h"
#else
#include "math/MyMath.h"
#endif

int main(int argc, char **argv)
{
    if (argc < 2)
    {
        printf("Usage:%s", argv[0]);
        return 1;
    }

#ifdef HAVE_ABS
    printf("Use StdLib. \n");
    printf("std abs: %d", abs(atoi(argv[1])));
#else
    printf("Use MyLib. \n");
    printf("my abs: %d", my_abs(atoi(argv[1])));
#endif
    return 0;
}

添加版本号

给项目添加和维护版本号是一个好的习惯,这样有利于了解每个版本的维护情况,并及时了解当前所用的版本号是否过时,或是否可能出现不兼容的情况。

首先修改顶层CMakelists文件,在project命令之后加入下面两行:

# 项目版本号
set(DEMO4_VERSION_MAJOR 1) # 指定主版本号
set(DEMO4_VERSION_MINOR 0) # 指定副版本号

用于分别指定当前项目中的主版本号和副版本号。

之后,我们可以在代码中获得版本号的信息,先修改config.h.in文件,添加两个预定义变量:

#define DEMO4_VERSION_MAJOR @DEMO4_VERSION_MAJOR@
#define DEMO4_VERSION_MINOR @DEMO4_VERSION_MINOR@

这样就可以直接在代码中打印版本信息了:

#include "math/MyMath.h"
#include "config.h"
#include <stdio.h>
#include <stdlib.h>

#ifdef HAVE_ABS
#include "math.h"
#else
#include "math/MyMath.h"
#endif

int main(int argc, char **argv)
{
    if (argc < 2)
    {
        printf("%s Version %d.%d\n", argv[0], DEMO4_VERSION_MAJOR, DEMO4_VERSION_MINOR);
        printf("Usage:%s", argv[0]);
        return 1;
    }

#ifdef HAVE_ABS
    printf("Use StdLib. \n");
    printf("std abs: %d", abs(atoi(argv[1])));
#else
    printf("Use MyLib. \n");
    printf("my abs: %d", my_abs(atoi(argv[1])));
#endif
    return 0;
}

运行的结果:

[crazyang@zt-2013412:/mnt/d/CODE/demo4]$ ./demo4 
./demo4 Version 1.0

生成安装包

我们可以配置生成各种平台上的安装包,包括二进制安装包和源码安装包。为了完成这个任务,我们需要用到CPack,它同样也是由CMake提供的一个工具,专门用于打包。

首先顶层的CMakelists.txt文件末尾添加下面几行:

# 构建一个 CPack 安装包
include (InstallRequiredSystemLibraries)
set (CPACK_RESOURCE_FILE_LICENSE
  "${CMAKE_CURRENT_SOURCE_DIR}/License.txt")
set (CPACK_PACKAGE_VERSION_MAJOR "${DEMO4_VERSION_MAJOR}")
set (CPACK_PACKAGE_VERSION_MINOR "${DEMO4_VERSION_MINOR}")
include (CPack)

这几行代码的工作如下:

  1. 导入InstallRequiredSystemLibraries模块,以便之后导入CPack模块
  2. 设置些CPack相关变量,包括版权信息和版本信息,其中版本信息用了上一节定义的版本号
  3. 导入CPack模块

然后我们在顶层创建一个License.txt文件,主要是一些版权信息相关的,因为没有此文件会有如下报错。

CMake Error at /usr/local/share/cmake-3.19/Modules/CPack.cmake:580 (message):CPack license resource file:"/mnt/d/CODE/demo4/License.txt" could notbe found.

接下来仍然使用cmake .构建工程,然后执行cpack相关命令:

  • 生成二进制安装包:

    cpack -C CPackConfig.cmake
    
  • 生成源码安装包:

    cpack -C CPackSourceConfig.cmake
    

在项目生成后,我们执行cpack -C CPackConfig.cmake命令:

[crazyang@zt-2013412:/mnt/d/CODE/demo4]$ cpack -C CPackConfig.cmake
CPack: Create package using STGZ
CPack: Install projects
CPack: - Run preinstall target for: demo4
CPack: - Install project: demo4 [CPackConfig.cmake]
CPack: Create package
CPack: - package: /mnt/d/CODE/demo4/demo4-1.0.1-Linux.sh generated.
CPack: Create package using TGZ
CPack: Install projects
CPack: - Run preinstall target for: demo4
CPack: - Install project: demo4 [CPackConfig.cmake]
CPack: Create package
CPack: - package: /mnt/d/CODE/demo4/demo4-1.0.1-Linux.tar.gz generated.
CPack: Create package using TZ
CPack: Install projects
CPack: - Run preinstall target for: demo4
CPack: - Install project: demo4 [CPackConfig.cmake]
CPack: Create package
CPack: - package: /mnt/d/CODE/demo4/demo4-1.0.1-Linux.tar.Z generated.

此时在该项目下创建3个不同格式的二进制文件:

[crazyang@zt-2013412:/mnt/d/CODE/demo4]$ ls demo4-*
demo4-1.0.1-Linux.sh  demo4-1.0.1-Linux.tar.Z  demo4-1.0.1-Linux.tar.gz

这 3 个二进制包文件所包含的内容是完全相同的,我们可以执行其中一个,此时会出现一个由 CPack 自动生成的交互式安装界面:

[crazyang@zt-2013412:/mnt/d/CODE/demo4]$ sh demo4-1.0.1-Linux.sh 
demo4 Installer Version: 1.0.1, Copyright (c) Humanity
This is a self-extracting archive.
The archive will be extracted to: /mnt/d/WPS云文档/WindSun的云文档/CODE/demo4

If you want to stop extracting, please press <ctrl-C>.
This is a cmake test file. #这是License.txt文件中的内容


Do you accept the license? [yn]: 
Y
By default the demo4 will be installed in:
  "/mnt/d/CODE/demo4/demo4-1.0.1-Linux"
Do you want to include the subdirectory demo4-1.0.1-Linux?
Saying no will install in: "/mnt/d/CODE/demo4" [Yn]: 
Y

Using target directory: /mnt/d/CODE/demo4/demo4-1.0.1-Linux
Extracting, please wait...

Unpacking finished successfully

安装后提示安装到了demo4-1.0.1-Linux子目录中,我们可以去执行该程序:

[crazyang@zt-2013412:/mnt/d/CODE/demo4]$ ./demo4-1.0.1-Linux/bin/demo4 -1
Use StdLib. 
std abs: 1

关于 CPack 的更详细的用法可以通过 man 1 cpack 参考 CPack 的文档。

将其他平台的项目迁移到CMake

CMake 可以很轻松地构建出在适合各个平台执行的工程环境。而如果当前的工程环境不是 CMake ,而是基于某个特定的平台,是否可以迁移到 CMake 呢?答案是可能的。下面针对几个常用的平台,列出了它们对应的迁移方案。

autotools

qmake

Visual Studio

  • vcproj2cmake.rb 可以根据 Visual Studio 的工程文件(后缀名是 .vcproj 或 .vcxproj)生成 CMakeLists.txt 文件。
  • vcproj2cmake.ps1 vcproj2cmake 的 PowerShell 版本。
  • folders4cmake 根据 Visual Studio 项目文件生成相应的 “source_group” 信息,这些信息可以很方便的在 CMake 脚本中使用。支持 Visual Studio 9/10 工程文件。

CMakeLists.txt 自动推导

  • gencmake 根据现有文件推导 CMakeLists.txt 文件。
  • CMakeListGenerator 应用一套文件和目录分析创建出完整的 CMakeLists.txt 文件。仅支持 Win32 平台。
yakit 验证码识别 进行webfuzzer 在渗透测试的过程中,我们可能需要对管理员密码进行枚举,或者密码喷洒的时候,遇到验证码就很烦。有没有自动化识别验证码的办法呢?有的,兄弟,有的。验证码的识别率很低,captcha-killer-modified对算术验证码识别正确率非常低,还会识别成乱七八糟的结果,这就非常麻烦。因为你不知道到底是验证码不对,还是密码不对。这是 ddddocr 识别率的问题,如果师傅们找到准确度更高的工具,完全可以替换上去。 阅读详情

相关推荐

python解析通达信dat与blk数据文件【附源码】

本文介绍了一个完整的通达信金融数据解析器项目,该项目攻克了通达信专有二进制文件格式解析的技术难题。项目采用模块化架构,从基础二进制解析到增强数据分类,最终实现智能语义化列名生成,形成完整的数据处理链路。核心技术包括自适应编码检测、智能数据类型推断和基于业务规则的语义化处理,解决了逆向工程、多编码兼容性等挑战。项目成果显著,解析成功率达100%,数据可读性大幅提升,开发效率提高50%,为量化交易、可视化分析等场景提供了可靠数据支持。该方案不仅具备技术创新性,更具有实际工程应用价值,为金融数据分析领域提供了可复

qq_36224726的博客 2694

cmake工程通过rc文件给程序添加图标

1,准备rc文件,用记事本编辑以下内容保存为logo.rc文件 IDI_ICON1 ICON DISCARDABLE "logo.ico" 2,在CMakeLists文件中将logo.rc文件加入到源文件列表中 list(APPEND SOURCES ${SOURCES_DIR}/logo.rc) 3,最后将准备好的logo.ico文件放到与rc文件的同级目录...

qq_27279997的博客 7511

提示词注入攻击全面解析与防御策略

提示词注入(Prompt Injection)是指攻击者通过精心构造的输入内容,操纵或欺骗AI系统执行非预期行为的技术手段。这种攻击类似于传统的SQL注入或XSS攻击,但其目标是AI模型的提示词处理机制而非数据库或网页。提示词注入利用了大语言模型的一个基本特性:它们被设计为遵循指令。攻击者通过在用户输入中嵌入特定指令,试图覆盖或绕过系统原有的安全限制和行为规则,让模型执行本不应该执行的操作。深度防御:实施多层次防御策略,不依赖单一安全措施持续更新:随着攻击技术的发展不断更新防御措施安全设计优先。

免责声明:本资料部分整理自合法网络公开渠道,部分为个人学习积累成果,仅作学习参考、学术交流使用。所收费用仅为资料搜集整理的时间劳务酬劳。版权归原作者及出版方所有,本人不承担相关版权及内容法律责任,若有侵权请告知,即刻删除处理。 4216

【cmake】CMake设置程序图标

【代码】【cmake】CMake设置程序图标。

qq_43331089的博客 5994

Microsoft AI SDK 与 SAP ABAP:让企业级 AI 能力触手可及的深度整合指南

借助 Microsoft AI SDK,ABAP 开发者无需跳出熟悉的事务码与数据字典,就能把 GPT‑4 的强大语言理解与生成能力深度植入采购、销售、财务等核心业务流程。只要掌握“初始化 SDK → 构造 Prompt → 解析输出”这一范式,未来无论 Azure OpenAI、OpenAI 还是本地化 LLM,都能在同一套代码骨架内快速切换,实现真正的“AI 即服务”。现在,就让我们在下一行 ABAP 里拥抱智能未来。参考链接均于 2025‑07‑22 提取,推荐读者结合实际版本进一步验证。

2007 年 ~ 2025 年,深耕 SAP 技术 18 年 438

OpenCV 直线的表示与 LineIterator 编程

其中,LineIterator 是 OpenCV 中用于处理直线的一个功能强大的类。然后,我们定义了直线的起点和终点,这里起点是 (50, 50),终点是 (250, 250)。接下来,我们使用 LineIterator 类创建了一个迭代器 line_iterator,用于遍历直线上的像素。在循环中,我们将直线上的像素设置为白色,即将像素的值设置为 255。通过使用 LineIterator,您可以轻松地迭代直线上的像素,并进行相应的处理。它可以帮助我们获取直线上的所有像素,并进行相应的处理。

DevSavantX的博客 509

windows下使用Cmake为自己创建的库添加版本信息

文章目录一、windows平台二、具体方法三、例子Reference 一、windows平台 windows下使用visual studio自带的动态库工程开发dll,可以帮助我们把版本号、公司名等信息生成到dll中,但是Cmake中的add_library生成的dll没有任何额外信息。 如下cuda.dll,右键通过详细信息就可以看到 文件说明、类型、文件版本、版权等多种信息,再也不需要去查文档、查头文件就能知道这个DLL是哪个版本,是什么时候生成的了。 二、具体方法 准备一个.rc.in的文件,里面

hjxu2016的博客 3403

Unity3D 加密 Assembly-CSharp.dll (Android平台) 防止反编译

0、加密的原理 Unity3D 是基于 Mono的,我们平时写的 C# 脚本都被编译到了 Assembly-CSharp.dll ,然后 再由 Mono 来加载、解析、然后执行。 Mono 加载 Assembly-CSharp.dll 的时候就是读取文件到内存中,和平时读取一个 游戏资源 文件没什么区别。 为了防止别人破解,我们会对游戏资源加密,简单点的 比如修改文件的一个字节 或者 位移一下

Circle 8726

CMakeRC:C++资源编译的利器

在软件开发的世界中,资源的有效管理和集成是确保应用程序轻便、高效运行的关键。今天,我们将介绍一个强大的开源工具——CMakeRC,它是一个基于CMake的独立C++资源编译器,能够帮助开发者轻松地将任意数据编译进程序中,从而简化应用程序的部署和分发。 ## 项目介绍 CMakeRC是一个资源编译器,通过一个单一的CMake脚本实现,可以轻松地集成到其他项目中。它的主要功能是将任意数据编译进程序

gitblog_00911的博客 643

AutoSAR从0开始实战 --- 目录

​​​​​​本专栏是全网最真实的AutoSAR实战专栏,博主将从一个0基础小白的身份来讲解AutoSAR工具的配置,以及相应代码的讲解。

wj博客 1730

Idea插件Plugins无法联网下载 解决方法(终极版必解决!)

插件联网的Bug疑难杂症,网络上不一样的解决方式以及独特的彩蛋!包解决

码农研究僧的博客 5520

vs cmake为动态库添加公司、版本等库信息

cmake。

u010096608的博客 1560

手把手教你学Simulink--逆变器场景:基于Simulink的单相全桥逆变器PWM控制仿真建模

本文介绍了使用Simulink和Simscape Electrical库进行单相全桥逆变器PWM控制仿真建模的详细步骤。主要内容包括:从创建Simulink项目、添加电力电子组件、构建逆变器模型,到设置参数、运行仿真和结果分析。重点讲解了逆变器核心模块的配置、PWM信号生成、负载建模等关键环节,并提供了优化改进建议。该指南适用于电力电子初学者,通过仿真可以帮助理解单相全桥逆变器的工作原理和PWM控制技术,为实际应用和算法开发提供基础平台。

MHD0815的博客 667

Cmake使用教程及案例

旨在记录Cmake的学习。

chengyongkang的博客 590

复分析 阿尔福斯(Ahlfors) 第三版答案 英文

答案分为十章,有部分习题没有答案,全英文复分析阿尔福斯(Ahlfors) 第三版答案

TMS_WebGMaps_1.9.8.0_Full_Source

TMS_WebGMaps_1.9.8.0_Full_Source 全源码 delphi cbuilder

Cmake使用教程

本篇博客介绍了cmake项目构建工具的安装和使用,以供大家很本人日常开发时进行参考。cmake在大型项目中非常吃香,一定要灵活应用。

Yu_Lijing的博客 4696

IDEA的使用指南

IDEA基于java的使用手册,可以最快速的上手,在使用中不断的丰富自己的使用技巧.

Cmake 使用教程

CMake是一个开源、跨平台的构建系统,主要用于软件的构建、测试和打包。CMake 使用平台无关的配置文件来控制软件的编译过程,并生成适用于不同编译器环境的项目文件。例如,它可以生成 Unix系统的MakefileWindows下 的 Visual Studio项目文件或Mac的Xcode工程文件,从而简化了跨平台和交叉编译的工作流程。CMake并不直接构建软件,而是产生标准的构建文件,然后使用这些文件在各自的构建环境中构建软件。CMake有以下几个特点:

2301_79881188的博客 1074

贝叶斯统计 [韦来生编]

贝叶斯(Bayes)统计是近几十年来迅速发展起来的数理统计的一个重要分支。贝叶斯方法与经典统计方法的主要不同之处是进行统计推断时除了利用样本信息外,还要利用参数的先验信息,因此可以提高统计推断或统计决策的效果。它在经济、金融、生物、医学、自然科学和社会科学等许多领域具有广泛的应用。贝叶斯方法的研究已渗透到了统计学的几乎所有领域。作者在给中国科学技术大学概率论与数理统计专业本科生开设的“数理统计”课程中有一章专门讲授“贝叶斯方法和统计决策理论”,近十年来也给中国科学技术大学概率统计专业研究生开设过几次“贝叶斯分析”课。本书是在对过去讲稿的内容作了适当的增减和调整的基础上完成的。  本书共分六章。第1章是绪论,介绍了贝叶斯统计的若干基本概念,同时对必要的数理统计的基础知识有重点地作了回顾。第二章介绍了确定先验分布的若干可供选择的方法。第三章介绍了几类常见统计模型参数的后验分布的主要结果和计算方法。第四章和第五章分别介绍了“贝叶斯统计推断”和“贝叶斯统计决策”的内容。第六章介绍了贝叶斯统计计算的若干方法,包括蒙特卡洛方法和马尔可夫链蒙特卡洛(MCMC)方法以及相关统计软件的简介。本书的每一章附右大量的例题和习题,书末附有常用的几个表格和部分习题解答供读者查用。  大约可在54学时内讲授本书的第1章至第六章的主要内容,教师可根据学时需要选讲本书第1章至第六章的部分内容。书中标“*”号的章节可略去不讲,留给读者作为阅读材料。第六章例题中的R代码和部分例题的数据文件等可从作者个人主页下载。  作者在编写本书的过程中参考了J.O.Berger教授的《统计决策论及贝叶斯分析》和茆诗松教授编写的《贝叶斯统计》等书中的一些内容,以及《贝叶斯分析》一书中由张伟平博士编写的有关贝叶斯统计计算的一些内容。在此表示衷心感谢。  本书编写准备过程中,中国科学技术大学统计与金融系的几个研究生帮助完成了本书部分中文的录入和排版,作者对他们的辛勤工作表示真诚的感谢。高等教育出版社为本书的出版给予了大力支持。在此一并致谢。

CMake入门教程PDF资源下载

CMake入门教程PDF资源下载 去发现同类优质开源项目:https://gitcode.com/ 本仓库提供了一份名为“CMake入门教程pdf”的资源文件,该文件是一份完整的CMake入门教程电子版。无论你是C++编程的初学者,还是希望深入了解CMake的高级用户,这份教程都能为你提供宝贵的指导和帮助。 资源描述 文件名称: CMake入门教程pdf 文件格式: PDF 内容简介: 详细介...

gitblog_06672的博客 406

CMake-Cookbook 使用教程

CMake-Cookbook 是一个开源项目,旨在通过一系列的示例和教程,帮助开发者理解和掌握 CMake 的使用。CMake 是一个跨平台的构建系统生成器,广泛用于 C++ 项目的构建管理。该项目由 xiaoweiChen 维护,提供了丰富的示例代码和详细的文档,适合各个层次的开发者学习。 ## 项目快速启动 ### 环境准备 在开始之前,请确保你的系统上已经安装了 CMake。你可以通过...

gitblog_00404的博客 636

使用sanitizers-cmake项目的教程

使用sanitizers-cmake项目的教程 1. 项目介绍 sanitizers-cmake 是一个用于在CMake项目中启用各种Sanitizers的CMake模块集合。Sanitizers是编译器提供的工具,用于检测内存错误、未定义行为等问题,帮助开发者提高代码质量。sanitizers-cmake 项目简化了在CMake项目中集成Sanitizers的过程,支持AddressSaniti...

gitblog_00161的博客 1354

CMake Python 分发项目教程

CMake Python 分发项目教程 1. 项目介绍 CMake Python 分发项目(cmake-python-distributions)旨在为 CMake 提供 Python 轮子(wheels),使得 CMake 可以在不同的平台上通过 Python 进行安装和使用。CMake 是一个开源的跨平台构建系统,用于控制软件编译过程,生成平台和编译器无关的配置文件,并生成原生的 makefi...

gitblog_01067的博客 781

Modern CMake for C++ 使用教程

Modern CMake for C++ 使用教程 项目介绍 《Modern CMake for C++》是由Packt Publishing出版的一本关于CMake的书籍,作者是Rafał Świdziński。本书旨在帮助C++开发者理解和使用现代CMake的最佳实践,从而更高效地管理和构建复杂的C++项目。项目源码托管在GitHub上,地址为:https://github.com/Packt...

gitblog_00606的博客 840

【亲测免费】 Extra CMake Modules 使用教程

Extra CMake Modules 使用教程 1. 项目介绍 Extra CMake Modules(ECM)是一个为 CMake 提供额外模块和脚本的软件包。ECM 扩展了 CMake 提供的模块,包括用于 find_package() 查找常见软件的模块,以及可以直接在 CMakeLists.txt 文件中使用的常见任务模块和用户必须在命令行上指定的工具链文件。此外,ECM 还提供了 KD...

gitblog_00951的博客 2085

Rust项目cmake-rs使用教程

Rust项目cmake-rs使用教程 项目介绍 cmake-rs 是一个 Rust 构建依赖项,用于运行 CMake 来构建本地库。这个 crate 提供了一些必要的样板代码和 shim 支持,以便运行系统的 CMake 命令。cmake-rs 项目由 Rust 社区维护,旨在简化在 Rust 项目中使用 CMake 的过程。 项目快速启动 安装 首先,确保你已经安装了 Rust 和 Cargo。...

gitblog_00521的博客 601

CMake 语言支持在 Visual Studio Code 中的使用教程

CMake 语言支持在 Visual Studio Code 中的使用教程 1、项目介绍 vs.language.cmake 是一个为 Visual Studio Code 提供 CMake 语言支持的开源项目。该项目主要提供 CMake 文件的语法高亮功能,帮助开发者更高效地编写和阅读 CMake 脚本。 2、项目快速启动 安装 打开 Visual Studio Code。 进入扩展市场,搜索...

gitblog_00973的博客 1160

Arduino-CMake-Toolchain 使用教程

Arduino-CMake-Toolchain 使用教程 项目介绍 Arduino-CMake-Toolchain 是一个开源项目,旨在为 Arduino 开发提供 CMake 工具链支持。通过这个项目,开发者可以使用 CMake 来管理 Arduino 项目的构建过程,从而更高效地进行跨平台开发。该项目支持多种 Arduino 板型,并且可以与常见的 IDE 和编辑器集成,提供更加灵活的开发环境...

gitblog_00820的博客 524
上一篇: CMake命令和重要指令
下一篇: C++11 bind函数
code_peak
博客等级 码龄5年 403粉丝 67原创
评论
成就一亿技术人!
拼手气红包6.0元
还能输入1000个字符
 
 条评论被折叠 查看
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付:10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值