Unity 之通过自定义协议从浏览器启动本地应用程序

内容将会持续更新，有错误的地方欢迎指正，谢谢!
 

Unity 之通过自定义协议从浏览器启动本地应用程序      

---

TechX 坚持将创新的科技带给世界！ 拥有更好的学习体验 —— 不断努力，不断进步，不断探索

TechX —— 心探索、心进取！ 助力快速掌握 自定义协议 启动程序 为初学者节省宝贵的学习时间，避免困惑！

前言：

  当今，Web 应用程序已经成为我们日常生活和工作中不可或缺的一部分。然而，有时我们可能需要从 Web 浏览器直接启动本地安装的应用程序，以处理特定的任务或数据。这时候，自定义协议就显得尤为重要和便捷。

自定义协议允许我们定义一种新的 URL 方案，使得浏览器能够识别并直接与本地应用程序进行通信。这种技术不仅提升了用户体验，还增强了 Web 应用程序与本地环境的集成能力，使得用户可以更高效地完成工作任务。

在本文中，我们将探讨如何设置和利用自定义协议来处理特定的 URL，以便从浏览器中打开本地应用程序。我们将介绍如何注册和处理自定义协议，并演示如何在浏览器中触发本地应用程序的启动，以实现无缝的跨平台集成和工作流程优化。

---

---

一、注册自定义协议

自定义协议（Custom Protocol）是一种在操作系统级别定义的URL协议，可以让特定的URL模式触发特定的应用程序。通过自定义协议，你可以在浏览器中点击一个链接，然后启动一个本地应用程序。这在开发需要从网页启动本地应用的场景中非常有用，比如启动Unity生成的.exe文件。

@echo off
cd /d %~dp0

@REM echo "%cd%"

:: 创建一个注册表文件并写入头部信息
echo Windows Registry Editor Version 5.00 >regist.reg

:: 创建主键 PrimaryKey，用于自定义协议
echo [HKEY_CLASSES_ROOT\PrimaryKey] >>regist.reg

:: 指定这是一个 URL 协议
echo "URL Protocol"="" >>regist.reg

:: 设置协议的描述
echo @="Primary Key Protocol" >>regist.reg

:: 创建子键 DefaultIcon，用于设置协议的图标
echo [HKEY_CLASSES_ROOT\PrimaryKey\DefaultIcon] >>regist.reg

:: 使用当前目录下的 YourUnityGame.exe 作为图标
echo @="%cd:\=\\%\\YourUnityGame.exe,1" >>regist.reg

:: 创建子键 shell
echo [HKEY_CLASSES_ROOT\PrimaryKey\shell] >>regist.reg

:: 创建子键 shell\open
echo [HKEY_CLASSES_ROOT\PrimaryKey\shell\open] >>regist.reg

:: 创建子键 shell\open\command
echo [HKEY_CLASSES_ROOT\PrimaryKey\shell\open\command] >>regist.reg

:: 设置当协议被调用时执行的命令，将当前目录路径转义，并将第一个参数传递给 YourUnityGame.exe
echo @="\"%cd:\=\\%\\YourUnityGame.exe\" \"%%1\"" >>regist.reg

:: 静默地导入注册表文件
regedit /s regist.reg

:: 删除临时生成的注册表文件
del regist.reg

:: 输出注册成功的提示信息
echo 注册成功

:: 暂停批处理脚本的执行，等待用户按下任意键继续
pause

PrimaryKey为注册表文件中的主键，可以根据你的需要自行填写

YourUnityGame为你的程序名称

创建一个批处理文件