慕课面板数据分析与Stata应用—第二章-长面板估计方法总结

一、长面板只需使用固定效应，不用考虑其他的。

             若 扰动项存在：组间异方差、组内自相关、组间同期相关（截面相关），则选择估计方法1以及估计方法2进行处理

              1. LSDV：估计最稳健

              2.FGLL

              3.FGLS ：特殊的双向固定效应

二、假设不存在三大问题

基础操作

use mus08cigar.dta  //打开数据集
des    //查看数据
xtdes  //查看数据
xtset state year  //将数据设为面板数据格式
sum lnc lnp lnpmin lny  //描述性统计
twoway (scatter lnc lnp) (lfit lnc lnp)  //画出关键变量与被解释变量的散点图和回归直线
twoway (scatter lnc  lnpmin) (lfit lnc  lnpmin)  //画出关键变量与被解释变量的散点图和回归直线
twoway (scatter lnc lny) (lfit lnc lny)  //画出关键变量与被解释变量的散点图和回归直线
xtline lnc  //关键变量的时间序列图 
xtline lnp  //关键变量的时间序列图

直接使用LSDV估计

     

// LSDV 估计双向固定效应模型(不考虑自相关、异方差和截面相关三大问题)
tab state,gen(state)  //生成州虚拟变量
gen t=year-62  //生成时间趋势变量
reg lnc lnp lnpmin lny state2-state10 t  //LSDV估计
avplot lnp  //画出偏相关图
avplot lny  //画出偏相关图
est store ols

三、三大问题检验

3.1*组内自相关问题的检验*

findit xtserial  //安装xtserial命令
xtserial lnc lnp lnpmin lny state2-state10  t

3.2*组间异方差问题的检验*

ssc install xttest3  //安装xttest3命令
quietly xtreg lnc lnp lnpmin lny t,fe 
xttest3
quietly xtgls lnc lnp lnpmin lny state2-state10  t  //两个命令是等价的
xttest3
//注意 xttest3只能在xtreg,fe 或者 xtgls后使用

3.3*组间相关问题的检验*

ssc install xttest2  //安装xttest2命令
quietly xtreg lnc lnp lnpmin lny t,fe
xttest2
quietly xtgls lnc lnp lnpmin lny state2-state10  t  //两个命令是等价的
xttest2

四、报告输出结果

4.1*报告xtpcse的结果*

xtpcse lnc lnp lnpmin lny state2-state10  t,corr(ar1) hetonly  //处理了组内相关和组间异方差两大问题
est store ar1hetonly
xtpcse lnc lnp lnpmin lny state2-state10  t,corr(ar1)  //同时处理了组内相关、组间异方差和组间相关三大问题  
est store ar1
xtscc lnc lnp lnpmin lny state2-state10  t  //同时处理了组内相关、组间异方差和组间相关三大问题
est store sc
xtpcse lnc lnp lnpmin lny state2-state10  t,corr(psar1) hetonly  //当T与N差别不大时，选择选项psar1，处理了组内相关和组间异方差两大问题
est store psar1hetonly
xtpcse lnc lnp lnpmin lny state2-state10  t,corr(psar1)  //当T与N差别不大时，选择选项psar1，同时处理了组内相关、组间异方差和组间相关三大问题
est store psar1
esttab ols ar1hetonly ar1 sc psar1hetonly psar1 ,b(%9.2f) p mtitle(ols ar1hetonly ar1 sc psar1hetonly psar1) obslast star (* 0.1 ** 0.05 *** 0.01) compress nogap k(lnp lnpmin lny t) a  //结果比较
esttab ols ar1hetonly ar1 sc psar1hetonly psar1 using tab1.rtf,b(%9.2f) p mtitle(ols ar1hetonly ar1 sc psar1hetonly psar1) obslast star (* 0.1 ** 0.05 *** 0.01) compress nogap k(lnp lnpmin lny t) a  //结果输出到word
esttab ols ar1hetonly ar1 sc psar1hetonly psar1 using tab1.csv,b(%9.2f) p mtitle(ols ar1hetonly ar1 sc psar1hetonly psar1) obslast star (* 0.1 ** 0.05 *** 0.01) compress nogap k(lnp lnpmin lny t) a  //结果输出到excel

4.2*报告xtgls的结果*

xtgls lnc lnp lnpmin lny state2-state10  t,corr(ar1) panels(heteroskedastic)  //处理了组内相关和组间异方差两大问题
est store ar1hetero
xtgls lnc lnp lnpmin lny state2-state10  t,corr(ar1) panels(correlated)  //同时处理了组内相关、组间异方差和组间相关三大问题
est store ar1corr
xtgls lnc lnp lnpmin lny state2-state10  t,corr(psar1) panels(heteroskedastic)  //当T与N差别不大时，选择选项psar1，处理了组内相关和组间异方差两大问题
est store psar1hetero
xtgls lnc lnp lnpmin lny state2-state10  t,corr(psar1) panels(correlated)  ////当T与N差别不大时，选择选项psar1，同时处理了组内相关、组间异方差和组间相关三大问题
est store psar1corr
esttab ar1hetero ar1corr  psar1hetero psar1corr ,b(%9.2f) p mtitle(ar1hetero ar1corr  psar1hetero psar1corr) obslast star (* 0.1 ** 0.05 *** 0.01) compress nogap k(lnp lnpmin lny t) a  //结果比较
esttab ar1hetero ar1corr  psar1hetero psar1corr using tab2.rtf,b(%9.2f) p mtitle(ar1hetero ar1corr  psar1hetero psar1corr) obslast star (* 0.1 ** 0.05 *** 0.01) compress nogap k(lnp lnpmin lny t) a  //结果输出到word
esttab ar1hetero ar1corr  psar1hetero psar1corr sc using tab2.csv,b(%9.2f) p mtitle(ar1hetero ar1corr  psar1hetero psar1corr sc) obslast star (* 0.1 ** 0.05 *** 0.01) compress nogap k(lnp lnpmin lny t) a  //结果输出到excel

关于课堂中讲解的机制识别方法，可以参考《撰取之手、援助之手与中国税收超GDP增长》-经济研究-方,张

五、长短面板检验方法差别

对于组内自相关、组间异方差检验方法是一致的，xtserial、xttest3.

对于截面相关，长面板：xttest2、短面板：xtcsd。

PS：如果仅存在某一项问题，

例如组间异方差 使用xtgls，选择项panels（heteroskedastic）

组内自相关的命令使用xtgls、xtpcse、xtscc都可以 不懂的命令可以help！