贪心 纪念品分组（NOIP2007）

SSL 1060
P1094 纪念品分组
题目描述
元旦快到了，校学生会让乐乐负责新年晚会的纪念品发放工作。为使得参加晚会的同学所获得的纪念品价值相对均衡，他要把购来的纪念品根据价格进行分组，但每组最多只能包括两件纪念品， 并且每组纪念品的价格之和不能超过一个给定的整数。为了保证在尽量短的时间内发完所有纪念品，乐乐希望分组的数目最少。
　　你的任务是写一个程序，找出所有分组方案中分组数最少的一种，输出最少的分组数目。

var
  w,n:longint;
  a:array[1..30000]of longint;
procedure init;
var
  i:longint;
begin
  readln(w);
  readln(n);
  for i:=1 to n do readln(a[i]);
end;

procedure quicksort(low,high:longint);
var
  i,j,mid,temp:longint;
begin
  i:=low;j:=high;mid:=a[(low+high)div 2];
  repeat
   while a[i]>mid do inc(i);
   while a[j]<mid do dec(j);
   if i<=j then
    begin
      temp:=a[i];a[i]:=a[j];a[j]:=temp;
      inc(i);dec(j);
    end;
  until i>j;
  if i<high then quicksort(i,high);
  if low<j then quicksort(low,j);
end;

procedure main;
var
  i,s,j:longint;
begin
  j:=n;
  s:=0;
  for i:=1 to n do
   if i<=j then
    begin
      if (a[i]+a[j]<=w)and(i<>j) then begin inc(s); dec(j); end
       else inc(s);
    end
    else break;
  writeln(s);
end;

begin
  init;
  quicksort(1,n);
  main;
end.

这道题印象最深，因为在石龙二中（本来要读石二的= =）做过，所以记得特别清楚。
首先排成一个有序的序列。
一个十分鲜明的判断：价值最高的纪念品加上价值最低的纪念品，就算这样都不能匹配成规定值内的组合，那配上其他肯定也不行。
易错点：有时候已经完成配合的小价值纪念品最终也会被搜索到，但已修复。

典型又经典，从未被超越的贪心入门题。