ABAP ALV行、列、单元格颜色

原创 已于 2023-10-18 09:42:58 修改 · 3.2k 阅读 · 13 ·
CC 4.0 BY-SA版权
by_Jshi
文章标签：

#开发语言 #程序人生 #经验分享

于 2023-08-04 10:48:21 首次发布
本文介绍了如何在ABAP开发中使用ALV（AdvancedListViewer）为特定数据分配颜色，包括列颜色、行颜色和单元格颜色的设置方法，通过示例代码演示了如何在ALV表格中实现颜色区分功能。

前言

有些需求会对其ALV特殊的数据进行标注（颜色展示），这样更有利于区分特殊的数据，视觉效果比较好，下面小例子来介绍ALV展示行、列、单元格颜色的实现方法。

一、介绍

    1.ALV列颜色：

         1.1.列颜色主要由FIELDCAT来进行颜色分配。

        如：fieldname = 'CARRID'  emphasize = 'C510'   

              " 字段名称为'CARRID'

              " C->color 5->颜色7个标准颜色 1->反转颜色开启 0->增强颜色关闭

    2.ALV行颜色：

          2.1.在ALV展示数据的内表中，添加一个char型4位的字段（CLR），用来记录颜色代码；

          2.2.GS_LAYOUT-INFO_FNAME      = 'CLR'.            "行颜色设置

          2.3.最后循环ALV数据内表给对应的行CLR赋值颜色代码

    3.ALV单元格颜色：

          3.1单元格颜色跟单元格可编辑很像；  

          3.2在ALV展示数据的内表中，添加cell_color 类型为lvc_t_scol ，用来记录颜色代码，需要设置，颜色的字段名（单元格颜色结构赋值、FNAME、COLOR-COL、COLOR-INT、COLOR-INV）放入对应的cell_color 中；

          3.3.GS_LAYOUT-CTAB_FNAME      = 'CELL_COLOR'。

二、使用步骤

1.代码

代码如下（示例）：

*&---------------------------------------------------------------------*
*& 程 序 名：YTEST_001
*& 程序描述：ABAP ALV行、列、单元格颜色
*& 创 建 者：小涵
*& 创建日期：2023/08/04
*&---------------------------------------------------------------------*
*& 版本     修改者(公司)     日期         修改描述
*& 1.0.0    XXXX           YYYYMMDD      创建程序
*&---------------------------------------------------------------------*
REPORT ytest_001.

*&---------------------------------------------------------------------*
* TYPES
*&---------------------------------------------------------------------*
TABLES:sflight.
TYPES:
  BEGIN OF ty_alv,
    carrid     TYPE sflight-carrid,     " 航线代码
    fldate     TYPE sflight-fldate,     " 航班日期
    price      TYPE sflight-price,      " 航空运费
    planetype  TYPE sflight-planetype,  " 飞机类型
    paymentsum TYPE sflight-paymentsum, " 当前预定总数
    cell_color TYPE lvc_t_scol,         " 单元格颜色
    clr        TYPE char4,              " 列颜色：颜色代码分配用
  END OF ty_alv,
  tt_alv TYPE STANDARD TABLE OF ty_alv.

*&---------------------------------------------------------------------*
* CONSTANTS
*&---------------------------------------------------------------------*
CONSTANTS:
  BEGIN OF c_ucomm,
    action01 TYPE sy-ucomm VALUE '&ZALL',text01 TYPE text VALUE '全选    ',
    action02 TYPE sy-ucomm VALUE '&ZSAL',text02 TYPE text VALUE '取消全选',
  END OF c_ucomm,

  BEGIN OF c_fcat,
    name01 TYPE fieldname VALUE 'CARRID     ',text01 TYPE fieldtext VALUE '航线代码',
    name02 TYPE fieldname VALUE 'FLDATE     ',text02 TYPE fieldtext VALUE '航班日期',
    name03 TYPE fieldname VALUE 'PRICE      ',text03 TYPE fieldtext VALUE '航空运费',
    name04 TYPE fieldname VALUE 'PLANETYPE  ',text04 TYPE fieldtext VALUE '飞机类型',
    name05 TYPE fieldname VALUE 'PAYMENTSUM ',text05 TYPE fieldtext VALUE '当前预定总数',
  END OF c_fcat.

*&---------------------------------------------------------------------*
* DEFIEN ALV
*&---------------------------------------------------------------------*
DATA:go_container TYPE REF TO cl_gui_docking_container,
     go_grid      TYPE REF TO cl_gui_alv_grid,
     gt_exclude   TYPE ui_functions,
     gt_fieldcat  TYPE lvc_t_fcat,
     gs_layout    TYPE lvc_s_layo,
     gs_variant   TYPE disvariant,
     gv_save,
     ok_code      TYPE sy-ucomm,
     save_code    TYPE sy-ucomm.

*&---------------------------------------------------------------------*
* GLOBAL INTERNAL TABLES
*&---------------------------------------------------------------------*
DATA:
  gt_out TYPE tt_alv.

*&---------------------------------------------------------------------*
* GLOBAL MACROS
*&---------------------------------------------------------------------*
DEFINE macro_fcat.
  ls_fieldcat-fieldname = &1.
  ls_fieldcat-reptext   = &2.
  APPEND ls_fieldcat TO ct_fieldcat.
  CLEAR ls_fieldcat.
END-OF-DEFINITION.

*&---------------------------------------------------------------------*
* SELECTION-SCREEN
*&---------------------------------------------------------------------*
SELECTION-SCREEN BEGIN OF BLOCK b01 WITH FRAME TITLE TEXT-001.
SELECT-OPTIONS:
  s_carrid FOR sflight-carrid.
SELECTION-SCREEN END OF BLOCK b01.

*&----------------------------------------------------------------------
*& INITIALIZATION.
*&----------------------------------------------------------------------
INITIALIZATION.
* 初始化
  PERFORM frm_initial_data.

*&----------------------------------------------------------------------
*& AT SELECTION-SCREEN OUTPUT
*&----------------------------------------------------------------------
AT SELECTION-SCREEN OUTPUT.

*&----------------------------------------------------------------------
*& AT SELECTION-SCREEN
*&----------------------------------------------------------------------
AT SELECTION-SCREEN.

*&----------------------------------------------------------------------
*& START-OF-SELECTION
*&----------------------------------------------------------------------
START-OF-SELECTION.
* 数据处理
  PERFORM frm_get_data.
  PERFORM frm_show_alv.

*&---------------------------------------------------------------------*
*& Form FRM_INITIAL_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_initial_data .

  CLEAR gt_out.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_GET_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_get_data .

  SELECT *
    FROM sflight
    WHERE carrid IN @s_carrid
    INTO CORRESPONDING FIELDS OF TABLE @gt_out
    UP TO 20 ROWS.

  LOOP AT gt_out ASSIGNING FIELD-SYMBOL(<fs_alv>).

*   行颜色 红色
    IF <fs_alv>-fldate = '20230925'.
      <fs_alv>-clr    = 'C610'.
    ENDIF.

*   单元格颜色
    IF <fs_alv>-fldate = '20230725'.
      "航班日期为20230725的单元格变成黄色。
      APPEND INITIAL LINE TO <fs_alv>-cell_color ASSIGNING FIELD-SYMBOL(<fs_color>).
      <fs_color>-fname      = 'FLDATE'.
      <fs_color>-color-col  =  3.
      <fs_color>-color-int  =  1.
      <fs_color>-color-inv  =  0.
    ENDIF.

  ENDLOOP.


ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_SHOW_ALV
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_show_alv .

  CALL SCREEN 9000.

ENDFORM.
*&---------------------------------------------------------------------*
*& Module STATUS_9000 OUTPUT
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
MODULE status_9000 OUTPUT.

  DATA:lv_title TYPE string.
  CLEAR lv_title.

  lv_title = 'ABAP ALV行、列、单元格颜色'.

  SET PF-STATUS '9000'.               " 定义gui状态
  SET TITLEBAR '9000'  WITH lv_title. " 定义gui标题

ENDMODULE.
*&---------------------------------------------------------------------*
*& Module ALV_DES OUTPUT
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
MODULE alv_des OUTPUT.

  DATA:lt_sort TYPE lvc_t_sort.

  IF go_grid IS INITIAL .
    CREATE OBJECT go_container
      EXPORTING
        repid     = sy-repid
        dynnr     = '9000'
        extension = 2050
        side      = cl_gui_docking_container=>property_floating.
    CREATE OBJECT go_grid
      EXPORTING
        i_parent = go_container.

*   获取字段目录
    PERFORM prepare_field_catalog CHANGING gt_fieldcat .

*   获取样式
    PERFORM prepare_layout CHANGING gs_layout .

*   锚定ALV变式标记
    CLEAR gs_variant.
    gs_variant = sy-repid.
    gv_save = 'A'.
    gs_variant-report = |{ sy-repid }{ sy-dynnr }|.

*-----显示ALV-------------------------------------------
    PERFORM frm_alv_display USING gt_out.
  ELSE .
*----------------------------刷新ALV----------------------
    " 刷新ALV
    PERFORM frm_refresh_alv.
  ENDIF .

ENDMODULE.
*&---------------------------------------------------------------------*
*&      Form  PREPARE_LAYOUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->PS_LAYOUT  text
*----------------------------------------------------------------------*
FORM prepare_layout
  CHANGING ps_layout TYPE lvc_s_layo.

  ps_layout-cwidth_opt      = 'X'.               " 优化行宽度
  ps_layout-zebra           = 'X'.               " 斑马纹
  ps_layout-sel_mode        = 'D'.               " 选择方式
  ps_layout-box_fname       = 'SEL'.             " 指定行选择字段
  gs_layout-info_fname      = 'CLR'.             " 行颜色设置
  gs_layout-ctab_fname      = 'CELL_COLOR'.      " 单元格颜色设置

ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_ALV_DISPLAY
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*&      --> GT_OUT
*&---------------------------------------------------------------------*
FORM frm_alv_display
  USING pt_table.

  CALL METHOD go_grid->set_table_for_first_display
    EXPORTING
      is_layout            = gs_layout
      it_toolbar_excluding = gt_exclude
      is_variant           = gs_variant
      i_save               = gv_save
    CHANGING
      it_outtab            = pt_table
      it_fieldcatalog      = gt_fieldcat.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_REFRESH_ALV
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_refresh_alv .

  DATA:ls_stable TYPE lvc_s_stbl.
  "刷新ALV
  ls_stable-row = 'X'.
  ls_stable-col = 'X'.
  CALL METHOD go_grid->refresh_table_display
    EXPORTING
      is_stable = ls_stable.

ENDFORM.
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_9000  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE user_command_9000 INPUT.
  save_code = ok_code.
  CLEAR ok_code.
  CASE save_code.
*   定义返回按钮
    WHEN 'BACK'.
      LEAVE TO SCREEN 0.
    WHEN 'EXIT' OR 'EXIT2'.
      LEAVE PROGRAM.
    WHEN 'SAVE'.
    WHEN OTHERS.
      CALL METHOD go_grid->set_function_code
        CHANGING
          c_ucomm = save_code.
  ENDCASE.
ENDMODULE.
*&---------------------------------------------------------------------*
*& Form PREPARE_FIELD_CATALOG
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*&      <-- GT_FIELDCAT
*&---------------------------------------------------------------------*
FORM prepare_field_catalog
  CHANGING ct_fieldcat TYPE lvc_t_fcat.

  DATA:
    ls_fieldcat TYPE lvc_s_fcat.

  macro_fcat:
    c_fcat-name01 c_fcat-text01,
    c_fcat-name02 c_fcat-text02,
    c_fcat-name03 c_fcat-text03,
    c_fcat-name04 c_fcat-text04.

* 列颜色->航线代码列 绿色
  LOOP AT ct_fieldcat ASSIGNING FIELD-SYMBOL(<fs_fieldcat>).

    IF <fs_fieldcat>-fieldname = 'CARRID'.
      <fs_fieldcat>-emphasize = 'C510'.
    ENDIF.

  ENDLOOP.

ENDFORM.

2.效果如下

总结

这个技巧其实很简单，理解具体的实现方法就很Nice!

ABAP - Function ALV 09 颜色设置（行、列、单元格）
HeathlX的博客
02-27 2798
【代码】ABAP - Function ALV 09 颜色设置（行、列、单元格）
ABAP ALV设置单元格颜色问题
月阴荒的博客
08-23 365
再计划日期小于当前日期，则变红色。
ABAP ALV 颜色设置（行，列，单元格）
weixin_30622107的博客
12-08 990
BCALV_EDIT_03 http://blog.sina.com.cn/s/blog_a87b19300102who3.html 关于ALV表格颜色，这种需求在项目中会经常用到。 列颜色 列的颜色很简单，在构成ALV字段的FIELDCAT内表中有一个字段是EMPHASIZE，将一个char型4位的颜色代码分配到FIELDCAT内表这个字段即可。 1 LW_F...
ALV2：ALV列、行、单元格颜色设置
12-25 4645
1）颜色含义1：海蓝；2：浅清；3：黄色；4：浅蓝；5：青色；6：红色；7：橙色。（1）首位为主颜色；（2）次位为辅助颜色；（3）末位为0时，表示首位数字表为表格的底色；末位为1时，则表示以1为底色，首位数字则表为表格字体的颜色；末位为其它颜色时，则表示底色为ALV的默认颜色；以上三条是本人大概总结出来的规律，本人发现的现象基本如上，但也不一定全部正确。其中C200
SAP ABAP ALV控件设置单元格颜色DEMO（ALV备忘五）
刘欣的优快云博客
03-12 3032
我们需要控制ALV控件单元格的颜色，满足复杂的需求，这是一个ABAP ALV 控件单元格颜色设置的DEMO。 DEMO运行的效果： 注意数据结构和逻辑：其实在数据表的每一行中，还要加入一张表，用来放这一行，多个列字段的颜色信息。 全部代码如下，以后再来详解： *&------------------------------------------------...
ABAP开发中ALV如何设置行/列/单元格的颜色
王小磊
03-07 7396
在ABAP开发过程中，有的时候,我们需要在 ALV 网格上绘上一些颜色.可以给特定的行，某个特定的列,某个特定的单元格绘制颜色. 如果某列被设置为关键列,这列的颜色将被自动绘制,而不需要我们额外的指定.，ALV的颜色是四位的如C710,第一位是固定死的C，第二位是颜色代码，可能值为1-7，代表颜色如下： 1：Gray-blue —>headers 2：Light gray —>L
SAP-ABAP合并单元格
09-13
这些函数模块允许开发者指定哪些行或列可以被合并，以及合并的方式。 例如，在ALV Grid Control中，可以使用“SET_ENTITY_PROPERTY”来设置实体属性，其中“MERGE”是一个常用的属性。通过设置这一属性，可以指定...
ABAP ALV 颜色行，列，单元格
指尖溯光的博客
03-28 1150
ABAP ALV 颜色行，列，单元格
ALV报表中对单元格的可编辑和颜色设置
fuyangshida的博客
05-30 556
对结构的STYLE 赋值CL_GUI_ALV_GRID=>MC_STYLE_ENABLED. "表示可编辑。对被选中行的FIELD_STYLE结构的FIELDNAME 赋值需要变成可编辑的字段。首先需要在程序定义的结构中增加 FIELD_STYLE 参考LVC_T_STYL。最后在GS_LAYOUT中指定STYLEFNAME。然后在程序中循环需要输出的内表,条件是被选中的行。然后对于满足条件,需要输出颜色的行。在需要输出的内表的结构中增加字段。
111.SAP ABAP - Function ALV - 列、行、单元格颜色 - 记录
坐忘了说画
10-29 2202
在数据展示方面，要求ALV的数据列、行、单元格通过颜色醒目显示（颜色展示），这样更有利于区分特殊的数据，视觉效果比较好，下面小例子来介绍ALV展示行、列、单元格颜色的实现方法。
ALV单个单元格的颜色设定
07-20
如何设定ALV单个单元格的颜色属性 1. 在需要显示的内表中添加新的字段，字段类型为lvc_t_scol 2. 根据条件设置颜色数据； 3. 设置layout-coltab_fieldname的数据指定显示颜色的字段.
ABAP ALV的颜色设定（单元格，行，列的颜色设定）
热门推荐
forever_crazy的专栏
11-04 1万+
abap中如果需要到对某个单元格，某行， 某列想要进行颜色设定的话，有一下几种简单的方面。 注：1：海蓝；2：浅清；3：黄色；4：浅蓝；5：青色；6：红色；7：橙色      （1）首位为主颜色；      （2）次位为辅助颜色；      （3）末位为0时，表示首位数字表为表格的底色；           末位为1时，则表示以1为底色，首位数字则表为表格字体的颜色；
ALV Color-颜色
Leo520liang的博客
05-11 1586
在ABAP ALV中，Color颜色设置是一种增强列表显示效果的重要手段，可以用来突出显示特定行、列或单元格，以吸引用户注意或传达数据的特定状态。颜色设置中有优先级顺序，他们是单元格->行->列，即若同时使用了上面的三种更改颜色的方法，则列的颜色会被行的颜色覆盖掉，而行的颜色又会被单元格的颜色覆盖掉，最终只会显示出单元格的颜色。如果这列被设置为关键列，就是gs_fieldcat-KEY = 'X' ，那么颜色设置就不会起作用。
SAP abap 实现ALV单元格的不同颜色
qq_42080586的博客
04-24 1165
有的用户要求把ALV的单元格颜色弄得花花绿绿，花里胡哨的，淦！那么这个时候，就该调用REUSE_ALV_GRID_DISPLAY函数了，如何设定单元格颜色，方法很简单，咱们直接看代码！ 执行，看看效果怎么样： ...
SAP ABAP AVL单元格颜色
小田的博客
04-03 473
4、这个CELLCOLOR 定义成一个纵深结构 放到T_MAIN里面，LVC_T_SCOL。1、最终ALV展示依靠这个BAPI:REUSE_ALV_GRID_DISPLAY_LVC。2、颜色控制会在参数 IS_LAYOUT_LVC参数里面的字段CTAB_FNAME。5、取数的时候根据字段条件设置颜色。
SAP ABAP ALV 颜色设置（行，列，单元格）
SAP李斌，本人承诺所有原创文章均不使用任何AI生成技术，请大家放心阅读。
12-27 5463
以 标准 Demo 程序为例，讲解 SAP ABAP ALV 颜色设置（行，列，单元格）。
【SAP】ABAP——ALV设置某一个单元格/整行的颜色
Mona_1220的博客
11-16 3575
当满足某些条件时，则某个字段的输出单元格显示为红色，当不满足时，则显示为原来的颜色。 DATA:BEGIN OF gs_out, matnr TYPE ekpo-matnr,"物料号 werks TYPE mardh-werks,"工厂 jszzt LIKE mardh-labst,"周转天 color TYPE lvc_t_scol,"单元格颜色 END OF gs_out....
ABAP SALV-颜色（列、行、单元格）
qq_33518131的博客
04-20 1012
在本篇文章中，将会介绍ABAP SALV中如何添加列颜色、行颜色以及单元格颜色
ABAP ALV和OOALV设置单元格颜色,编辑
Sunflower
03-06 2257
中设置你要想实现那一列的效果,要把它设置成可编辑的,对是设置整列可编辑的(后续要经过判断在设置具体到那个单元格可编辑)**需求:**我是想实现某个单元格可根据数据来判断是否是可以进行编辑的或要添加一个什么样的颜色.这个字段就是用来编辑这个单元格是否需要编辑的。的前一步进行实现具体单元格可编辑的效果.的前一步进行实现具体单元格/行的效果.中设置上面的那个字段.
abap alv单元格颜色
最新发布
07-16
<think>我们正在处理一个关于ABAP ALV设置单元格颜色的问题。根据用户提供的引用和问题，我们需要总结出设置单元格颜色的方法。 根据引用[2]和[3]，设置单元格颜色通常需要以下步骤： 1. 在显示ALV的内表结构中添加一个类型为`LVC_T_SCOL`的字段（通常命名为`CELLCOLOR`或`COLOR`）用于存储单元格颜色信息。 2. 在循环内表时，为需要设置颜色的单元格创建颜色结构（类型为`LVC_S_SCOL`），并填充颜色代码（颜色代码由三位组成：COL（颜色代码，1-7），INT（增强颜色，0或1），INV（反转颜色，0或1））。 同时指定要设置颜色的字段名（`FNAME`）。 3. 将颜色结构添加到内表行的颜色字段（即`CELLCOLOR`或`COLOR`）中（这是一个内表，因为一行可能有多个单元格设置颜色）。 4. 在ALV布局中，通过`I_LAYOUT-CELLTAB_FIELDNAME`（或`ctab_fieldname`）指定内表中颜色字段的名称。 另外，引用[4]提到，设置行颜色是通过在数据内表中添加一个4位CHAR类型的字段（例如`COLOR`），然后在布局中指定`INFO_FIELDNAME`（或`info_fname`）为该字段名。但是注意，行颜色和单元格颜色是不同的，行颜色是整行一个颜色，而单元格颜色可以分别设置。 用户问题明确要求设置单元格颜色，所以我们重点在单元格颜色。 步骤详细说明： 1. 定义内表结构，添加颜色字段： 例如： TYPES: BEGIN OF ty_data, matnr TYPE matnr, " 物料 werks TYPE werks_d, " 工厂 labst TYPE labst, " 库存 " ... 其他字段 cellcolor TYPE lvc_t_scol, " 单元格颜色表 END OF ty_data. 2 在循环内表时，为特定单元格添加颜色： LOOP AT gt_data ASSIGNING <fs_data>. IF <fs_data>-labst = 0. " 例如库存为0时，设置物料字段为红色 DATA(ls_color) = VALUE lvc_s_scol( fname = 'MATNR' " 要设置颜色的字段名 color-col = '6' " 红色，颜色代码：1-7，具体查色卡 color-int = 1 " 增强显示 color-inv = 0 " 不反转 nokeycol = 'X' " 忽略关键列颜色（可选） ). APPEND ls_color TO <fs_data>-cellcolor. ENDIF. ENDLOOP. 3 在ALV布局设置中指定单元格颜色字段： DATA: gs_layout TYPE lvc_s_layo. gs_layout-ctab_fname = 'CELLCOLOR'. " 这里填写内表中颜色字段的名称 4 调用ALV显示函数时传入布局。 注意：颜色代码通常使用1到7，具体颜色可能因主题而异，常见的如： 1：灰色，2：蓝色，3：黄色，4：粉红色，5：绿色，6：红色，7：橙色。 另外，引用[3]中有一个例子，设置周转天数字段为红色，当满足条件时。 根据以上步骤，我们可以编写一个示例代码。 下面提供一个完整的示例程序框架：</think>### ABAP ALV 设置单元格颜色的方法 在 ABAP ALV 中设置单元格颜色需要以下步骤： #### 1. **数据结构准备** 在显示 ALV 的内表中添加颜色字段，类型为 `LVC_T_SCOL`（存储单元格颜色表）： ```abap TYPES: BEGIN OF ty_data, matnr TYPE matnr, " 物料号 werks TYPE werks_d, " 工厂 labst TYPE labst, " 库存数量 color TYPE lvc_t_scol, " 单元格颜色表（关键字段） END OF ty_data. DATA: gt_data TYPE TABLE OF ty_data. ``` #### 2. **设置颜色逻辑** 在数据处理循环中，通过条件判断为单元格添加颜色： ```abap LOOP AT gt_data ASSIGNING FIELD-SYMBOL(<fs_data>). IF <fs_data>-labst = 0. " 库存为0时设置颜色 DATA(ls_color) = VALUE lvc_s_scol( fname = 'LABST' " 目标字段名 color-col = '6' " 颜色代码（6=红色） color-int = '1' " 增强显示（1=开启） color-inv = '0' " 不反转颜色 ). APPEND ls_color TO <fs_data>-color. " 添加到颜色表 ENDIF. ENDLOOP. ``` #### 3. **ALV 布局配置** 在布局参数中指定颜色字段名： ```abap DATA(gs_layout) = VALUE lvc_s_layo( ctab_fname = 'COLOR' " 指向内表的颜色字段 zebra = 'X' " 启用斑马纹 col_opt = 'X' " 自动优化列宽 ). ``` #### 4. **ALV 输出** 调用 ALV 函数时传入布局和字段目录： ```abap CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC' EXPORTING i_callback_program = sy-repid is_layout_lvc = gs_layout it_fieldcat_lvc = gt_fieldcat " 需提前构建字段目录 TABLES t_outtab = gt_data. ``` #### 📌 关键说明 1. **颜色代码**： - `COL`：基础色值（1=灰, 2=蓝, 3=黄, 4=粉, 5=绿, **6=红**, 7=橙） - `INT=1`：启用高亮增强 - `INV=0`：禁用颜色反转 2. **多单元格控制**： 同一行可向 `COLOR` 字段追加多条记录，实现多单元格染色： ```abap APPEND VALUE #( fname='MATNR' color-col=5 ) TO <fs_data>-color. " 物料号绿色 APPEND VALUE #( fname='WERKS' color-col=3 ) TO <fs_data>-color. " 工厂黄色 ``` 3. **字段名一致性**： `FNAME` 必须匹配字段目录中的字段名（区分大小写）[^2][^3]。 #### 效果示例 | 物料号 | 工厂 | 库存 | |--------|------|------| | M001 | 1001 | <span style="color:red">**0**</span> | <!-- 库存为0时红色 --> | M002 | 1002 | 150 | --- ### 相关问题 1. 如何设置整行背景色（非单元格）？ 2. ALV 颜色代码与标准色卡的对应关系是什么？ 3. 能否根据动态条件（如用户输入）改变单元格颜色？ 4. 如何清除已设置的 ALV 单元格颜色？ [^1]: SAP ALV 颜色控制包含行、列、单元格三个层级，需使用不同字段存储颜色信息。 [^2]: 单元格颜色必须通过类型 `LVC_T_SCOL` 的内表字段存储，布局中需用 `CTAB_FNAME` 绑定该字段。 [^3]: 颜色结构 `LVC_S_SCOL` 中的 `FNAME` 需严格匹配目标字段名，否则染色无效。 [^4]: 行颜色控制使用 `INFO_FNAME` + 4 位 CHAR 字段，与单元格染色机制不同。
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值