切线空间法线

最新推荐文章于 2024-10-16 10:15:03 发布

原创最新推荐文章于 2024-10-16 10:15:03 发布 · 617 阅读

0 ·

CC 4.0 BY-SA版权

本文介绍了一个用于Unity引擎的自定义Shader示例，该Shader使用切线空间法线贴图实现光照效果。通过解析代码，读者可以了解到如何在Unity中设置属性、创建子着色器以及编写顶点和片段着色器来实现高级光照效果。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Test/TangentNormalShader"
{
Properties
{
_MainTex("main",2D) = "white"{}
_Bump("Bump",2D) = "white"{}
_Color("Color",Color) = (1,1,1,1)
_Specular("Specular",Color) = (1,1,1,1)
_BumpScale("Scale",float) = 1
_Gloss("Gloss",Range(1,20)) = 5
}

SubShader
{
Pass
{
Tags{"LightMode" = "ForwardBase"}
CGPROGRAM

#pragma vertex vert
#pragma fragment frag

#include "Lighting.cginc"
#include "UnityCG.cginc"

sampler2D _MainTex;
sampler2D _Bump;
float4 _MainTex_ST;
float4 _Bump_ST;
fixed4 _Color;
fixed4 _Specular;
float _BumpScale;
float _Gloss;

struct a2v
{
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 tangent : TANGENT;
float4 texcoord : TEXCOORD0;
};

struct v2f
{
float4 pos : SV_POSITION;
float4 uv : TEXCOORD0;
float3 lightDir : TEXCOORD1;
float3 viewDir : TEXCOORD2;
};

v2f vert(a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
//计算纹理坐标
o.uv.xy = TRANSFORM_TEX(v.texcoord,_MainTex);
o.uv.zw = TRANSFORM_TEX(v.texcoord,_Bump);

//转换切线空间
TANGENT_SPACE_ROTATION;

o.lightDir = mul(rotation,ObjSpaceLightDir(v.vertex));
o.viewDir = mul(rotation,ObjSpaceViewDir(v.vertex));

return o;
}

fixed4 frag(v2f o) :SV_Target
{
//切线空间计算信息
float3 lightDir = normalize(o.lightDir);
float3 viewDir = normalize(o.viewDir);

fixed4 packedNormal = tex2D(_Bump,o.uv.zw);
fixed3 tangentNormal =UnpackNormal(packedNormal);
tangentNormal.xy *= _BumpScale;
tangentNormal.z = sqrt(1 - saturate(dot(tangentNormal.xy,tangentNormal.xy)));

//tex2D(纹理名,UV坐标)
float3 albedo = tex2D(_MainTex,o.uv.xy).rgb * _Color.rgb;
//环境光
float3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
//漫返射
float3 diffuse = _LightColor0.rgb * albedo * saturate(dot(tangentNormal,lightDir));

float3 halfDir = normalize(lightDir+viewDir);

//高光反射
float3 reflectColor = _LightColor0.rgb * _Specular * pow(saturate(dot(tangentNormal,halfDir)),_Gloss);

float3 finalColor = reflectColor + diffuse + ambient;
return fixed4(finalColor,1);
}

ENDCG
}
}
}