arm 中断重入

实现中断重入需要注意的事项，代码来说明。

irq_handler:

        /* Save interrupt context on the stack to allow nesting */
        SUB     lr, lr, #4     /*lr 保存前一个模式的（PC + 4）的值，所以保存时减去4*/
        STMFD   sp!, {lr}   /*压栈（中断模式栈）*/
        MRS     lr, SPSR
        STMFD   sp!, {r0, lr}   /*保存 SPSR、r0, 因为下一个中断来时会改变SPSR的值，

                                        *r0 下面会用到，所以保存这两寄存器的值

                                       */

        /* Write in the IVR to support Protect Mode */
        LDR     lr, =ADDR_INTERRUPT_VECTOR
        LDR     r0, [r14, #NO_INTER]    /*获取中断处理函数地址*/

        /* Branch to interrupt handler in Supervisor mode */
        MSR     CPSR_c, #ARM_MODE_SVC   /*开中断*/
        STMFD   sp!, {r1-r3, r12, lr}    /*保存SVC模式下 r1-r3, r12 lr 寄存器的值，SVC 和 IRQ 模式

                                                    *共用 r0-r12 寄存器，根据函数调用规则，r0-r3, r12是不用

                                                    *恢复的，所以要保存r0-r3,r12寄存器的值， 由于lr寄存器这

                                                    *两种模式不是共用，所以需要切换模式后才能保存。

                                                    */
        MOV     lr, pc
        BX      r0
        LDMIA   sp!, {r1-r3, r12, lr}
        MSR     CPSR_c, #ARM_MODE_IRQ | I_BIT    /*关中断*/

        /* Restore interrupt context and branch back to calling code */
        LDMFD    sp!, {r0, lr}
        MSR     SPSR_cxsf, lr
        LDMFD    sp!, {pc}^      /* "^" 恢复到前一个模式的PC值处执行*/