Unity Shader学习记录(12) —— 透明度测试实现

透明度测试的原理

透明度测试:只要一个片元的透明度不满足条件(通常是小于某个闽值)，那么它对应的片元就会被舍弃。被舍弃的片元将不会再进行任何处理，也不会对颜色缓冲产生任何影响:否则，就会按照普通的不透明物体的处理方式来处理它。

通常，我们会在片元着色器中使用 clip 函数来进行透明度测试。clip 是 CG 中的一个函数它的定义如下。

函数: void clip(float4 x): void clip(float3 x): void clip(float2 x): void clip(float1 x); void clip(float x);

实现代码

Shader "MyShader/8-AlphaTest"
{
    Properties
    {
        _Color ("Color Tint", Color) = (1, 1, 1, 1)
	    _MainTex ("Main Tex", 2D) = "white" {}
        //透明度测试条件
        _Cutoff("Alpha Cutoff", Range(0,1) ) = 0.5 
    }
    SubShader
    {
        //渲染队列透明度测试 
        Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}

        Pass
        {
            Tags { "LightMode"="ForwardBase" }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed _Cutoff;

            struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;
			};

            struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float2 uv : TEXCOORD2;
			};

            v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				
				return o;
			}

            fixed4 frag(v2f i) : SV_Target {
                //归一化向量
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				
				fixed4 texColor = tex2D(_MainTex, i.uv);
				
				// 判断texColor.a - _Cutoff是否为负数，是则舍弃输出
				clip (texColor.a - _Cutoff);
				// Equal to 
//				if ((texColor.a - _Cutoff) < 0.0) {
//					discard;
//				}
				
				fixed3 albedo = texColor.rgb * _Color.rgb;
				//片元环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				//漫反射光
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
				
				return fixed4(ambient + diffuse, 1.0);
			}
			

         




            ENDCG
        }
    }
    FallBack "Transparent/Cutout/VertexLit"
}

透明度测试得到的透明效果很“极端”一-要么完全透明，要么完全不透明，它的效果往往像在一个不透明物体上挖了一个空洞。而且，得到的透明效果在边缘处往往参差不齐，有锯齿，这是因为在边界处纹理的透明度的变化精度问题。为了得到更加柔滑的透明效果，就可以使用透明度混合。