Unity Shader学习日记2(高光反射模型)

实现逐顶点的高光反射模型

前置知识点

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unity/Custom/01-Specular Vectex---Level" 
{
	Properties 
	{
 
		_Diffuse ("Diffuse",Color) = (1,1,1,1)
		_Specular("Specular",Color) = (1,1,1,1)
		_Gloss("Gloss",Range(0,256)) = 20
 
	}
	SubShader 
	{
		Pass
		{
			Tags { "LightMode"="ForwardBase" }
 
 
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"
 
			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v{
 
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			
			};
 
			struct v2f{
 
				float4 pos : SV_POSITION;
				fixed3 color : COLOR;
 
			};
 
			v2f vert(a2v v)
			{
				v2f o;
				//顶点信息转换至世界空间
				o.pos = UnityObjectToClipPos(v.vertex);
				//获取环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz; 
				//把顶点法线转换在世界坐标系中
				fixed3 normal_in_world = normalize(mul(v.normal, (float3x3) unity_WorldToObject));
				//获取入射光方向(光源方向)
				fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				//计算漫反射  = 漫反射系数 * 光源 * max(0, 表面法线*光源方向)
				fixed3 diffuse = _Diffuse.rgb * _LightColor0.rgb * saturate(dot(worldLight, normal_in_world));

				//计算反射角度 
				fixed3 reflectDir = normalize(reflect( -worldLight, normal_in_world));
				//获取视角方向
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);
				//计算高光反射 = 光源 * 高光反射系数 * pow(saturate(反射角度 * 视角方向) ,_Gloss)
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);

				o.color = ambient + diffuse +specular;
				return o;
			}
 
			fixed4 frag(v2f i) : SV_Target
			{
				return fixed4(i.color,1.0);	
			}
			ENDCG
 
		}
 
	}
	
	FallBack "Specular"
}

效果图

实现逐像素的高光反射模型

Shader "Unity/Custom/01-Specular Vectex---Level"
{
	Properties
	{

		_Diffuse("Diffuse",Color) = (1,1,1,1)
		_Specular("Specular",Color) = (1,1,1,1)
		_Gloss("Gloss",Range(0,256)) = 20

	}
		SubShader
	{
		Pass
		{
			Tags { "LightMode" = "ForwardBase" }


			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

			struct a2v {

				float4 vertex : POSITION;
				float3 normal : NORMAL;

			};

			struct v2f {

				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
			};

			v2f vert(a2v v)
			{
				v2f o;
				//顶点信息转换至世界空间
				o.pos = UnityObjectToClipPos(v.vertex);
				o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
				//转换法线的做法是 mul 的第一个参数是待转的值， 第二个参数是反过来的转换矩阵
				o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
	
				
				return o;
			}

			fixed4 frag(v2f i) : SV_Target
			{
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				//把顶点法线转换在世界坐标系中
				fixed3 normal_in_world = normalize(i.worldNormal);
				//获取入射光方向(光源方向)
				fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				//计算漫反射  = 漫反射系数 * 光源 * max(0, 表面法线*光源方向)
				fixed3 diffuse = _Diffuse.rgb * _LightColor0.rgb * saturate(dot(worldLight, normal_in_world) * 0.5 + 0.5);

				//计算反射角度 
				fixed3 reflectDir = normalize(reflect(-worldLight, normal_in_world));
				//获取视角方向
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz -i.worldPos.xyz);
				//计算高光反射 = 光源 * 高光反射系数 * pow(saturate(反射角度 * 视角方向) ,_Gloss)
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);

				return fixed4(ambient + diffuse + specular,1.0);
			}
			ENDCG

		}

	}

		FallBack "Specular"
}

效果图

经过几次代码编写，发现要熟练掌握shader光照模型对线性代数的基础知识要有一定了解，接下来回过头去补线性代数知识点。