从 C51+uCos-II 近距离了解操作系统任务切换原理

本文深入剖析uCOS-II实时操作系统中任务切换的原理与流程,详细介绍了硬件上下文的概念,包括寄存器状态和堆栈管理。文章还探讨了uCOS-II如何利用任务控制块(TCB)保存和恢复任务状态,以及通过模拟中断实现任务切换的具体步骤。

摘要生成于 C知道 ,由 DeepSeek-R1 满血版支持, 前往体验 >

前言

从 C51+uCos-II 简单介绍下任务切换的原理
方便大家更形象的理解多任务怎么切换

为后续写 x86+Linux 任务切换做铺垫练手吧

参考资料如下:
uCos-II 源码
《单片机原理与应用及 C51 编程技术》
《C51》
《基于单片机 8051 的嵌入式开发指南》

硬件上下文及中断返回

首先了解下硬件上下文以中函数调用,中断调用及返回

C51 硬件上下文

所谓硬件上下文吧,可以简单理解为 CPU 核心硬件寄存器,因为硬件是不同任务共用的,所以针对不同的任务,总会有一部分寄存器配置是
不一样的,这些不一样的需要各个任务自己保存好,针对 C51 呢,其硬件上下文有如下部分:

在这里插入图片描述

A(ACC):  8 位累加寄存器
B: 工作寄存器,为乘法和除尘指令设置,可作中间寄存器
PSW: 程序状态寄存器
PC: 存放 CPU 要执行的下一条指令的地址
SP: 堆栈寄存器 
DPTR(DPH+DPL): 为 16 位数据指针寄存器
R0-R7: 通用寄存器

这就是硬件上下文简单介绍

函数调用及返回

函数调用寄存器传参规则
在这里插入图片描述

函数返回寄存器传参规则:
在这里插入图片描述

中断调用规则:
在这里插入图片描述

1. 在函数被调用时,将 A,B,DPH,DPL,PSW 保护在堆栈上
2. 如果工作寄存器未说明为 using 属性,所有的工作寄存器保护在堆栈上
3. 保护的 SFR 和寄存器在函数退出时恢复
4. 函数以 RETI 结束

实现任务切换主要是通过软件设置堆栈,模拟中断完成实现的。

任务上下文

针对 uCos 任务用一个任务控制块表示

typedef struct os_tcb {
    OS_STK        *OSTCBStkPtr;        /* 指向任务栈的栈顶                           */

	。。。
} OS_TCB;

上面乍看乱糟糟的一堆,相关的也就是,实际上用来保存硬件上下文的就是第一个参数

OS_STK        *OSTCBStkPtr;        /* 指向任务栈的栈顶                           */

任务初始化堆栈就是在这里保存的,顺序如下:

*        : 任务栈结构示意图(杨屹)
*
*                                    ---------- -
*                  用户栈最高地址---->|        | |
*                                    ---------- |
*                                    |   ...  | 仿真堆栈空间
*----------                          ---------- | 每任务一个
*|OSTCBCur|               ?C_XBP---->|        | | KEIL自动处理
*----------                          ---------- -
*    |                               |空闲间隔|
*    |     -----------------------   ----------                           ----------
*    \---->|OSTCBCur->OSTCBStkPtr|   |?C_XBP低|                    SP---->|        |
*          -----------------------   ----------                           ----------
*                     |              |?C_XBP高|                           |        |
*                     |              ---------- -                         ----------
*                     |              |        | |                         |   .    |
*                     |              ---------- |                         |   .    |
*                     |              |        | |                         |   .    |
*                     |              ---------- |                         ----------
*                     |              |   .    |长度                       |        | +1
*                     |              |   .    | |                         ----------
*                     |              |   .    | |             OSStack---->|        | 0
*                     |              ---------- |                         ----------
*                     |              |函数地址| |          OSStkStart---->| 不关心 | -1  低地址
*                     |              ---------- -                         ----------
*                     \------------->|  长度  | 低地址                   系统硬件堆栈
*                                    ----------
*                                     用户堆栈                        长度=SP-OSStkStart
*********************************************************************************************************
void *OSTaskStkInit(void(*task)(void *pd), void *ppdata, void *ptos, INT16U opt) REENTRANT
{
	OS_STK *stk;
	ppdata=ppdata;
	opt	  =opt;						/* opt没被用到,保留此语句防止警告产生 			*/
	stk	  =(OS_STK *)ptos;			/* 任务堆栈最低有效地址 						*/
	*stk++=15;						/* 任务堆栈长度 								*/
	*stk++=(INT16U)task & 0xFF;		/* 任务代码地址低8位 							*/
	*stk++=(INT16U)task >> 8;		/* 任务代码地址高8位 							*/
	/* 处理器是按特定的顺序将寄存器存入堆栈的,所以用户在将寄存器存入堆栈的时候也要依照这一顺序 */
	*stk++=0x00;					/* PSW 											*/
	*stk++=0x0A;					/* ACC 											*/
	*stk++=0x0B;					/* B 											*/
	*stk++=0x00;					/* DPL 											*/
	*stk++=0x00;					/* DPH 											*/
	*stk++=0x00;					/* R0 											*/
	*stk++=0x01;					/* R1 											*/
	*stk++=0x02;					/* R2 											*/
	*stk++=0x03;					/* R3 											*/	
	*stk++=0x04;					/* R4 											*/
	*stk++=0x05;					/* R5 											*/
	*stk++=0x06;					/* R6 											*/
	*stk++=0x07;					/* R7 											*/
	
	/* 不用保存 SP,任务切换时根据用户堆栈长度计算得出 								*/
	*stk++=(INT16U)(ptos+MAX_STK_SIZE) >> 8;	/* ?C_XBP 仿真堆栈指针高8位 		*/
	*stk++=(INT16U)(ptos+MAX_STK_SIZE) & 0xFF;	/* ?C_XBP 仿真堆栈低8位 			*/
	return ((void *)ptos);	/* 返回最低地址,这里不用弹出栈顶指针是为了提高计算效率 */
}

注意:这里的 ?C_XBP 是用于 C51 的仿真堆栈的,用于函数重载用的,因为默认 C51 函数不支持重载

在这里插入图片描述
在这里插入图片描述

切换代码流程

总体上流程就是
1. 任务 1 硬件上下文保存到任务1的任务控制块 OS_TCB 中
2. 将任务 2 的任务控制块中的堆栈恢复到硬件堆栈中,并模拟成中断返回前堆栈格式
3. 通过 RETI 模拟中断返回,弹出包含任务 2 的硬件堆栈,实现跳转到 任务 2 执行

在这里插入图片描述

相关变量解释

OSStkStart: 硬件堆栈地址
OSTCBCur: 当前运行要被切出的任务
OSTCBHighRdy: 当前要被切入的任务

换入代码流程

任务切换一般发生在 OSTimeDly() 函数中,调用流程为:

OSTimeDly (INT16U ticks)
	OS_Sched();
		OS_TASK_SW(); 
			#define OS_TASK_SW()	OSCtxSw() /* 任务级的任务切换宏 				*/
				OSCtxSw:    ; 汇编实现的芯片相关的任务切换宏

软件上分四步:
1. PUSHALL: 当前硬件寄存器先保存到硬件堆栈中
2. 调用 OSIntCtxSw_in: 将要硬件堆栈保存到换出的任务堆栈中
3. 调用 OSCtxSw_in: 将换入的任务堆栈恢复到硬件堆栈中
4. 调用 RETI 出硬件堆栈,完成任务切换

OSCtxSw:  

        USING 0  
        PUSHALL     ; 所有当前硬件寄存器压入硬件系统堆栈
        
OSIntCtxSw_in:
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;获得硬件堆栈长度和起始地址,任务栈结构示意图(OS_CPU_C.C)
        ;; R5: 硬件堆栈长度
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        MOV  A,SP
        CLR  C	;进位标志位Cy清零
        SUBB A,#OSStkStart	;A <- A-OSStkStart-Cy
        MOV  R5,A     ;获得硬件堆栈长度        
    
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; DPTR: 指向当前需要被切出的任务
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;OSTCBCur ==> DPTR  获得当前TCB指针
        MOV  R0,#LOW (OSTCBCur) ;获得OSTCBCur指针低地址,指针占3B。+0类型 +1高8位数据 +2低8位数据
        INC  R0			;指向地址的高8位
        MOV  DPH,@R0	;全局变量OSTCBCur在IDATA中
        INC  R0			;指向地址的低8位
        MOV  DPL,@R0
        ;此时 DPL,DPH 中存放的是系统当前任务控制块的地址

        ;OS_TCB结构的第一个数据项
    		;typedef struct os_tcb {
    		;OS_STK        *OSTCBStkPtr;        /* 指向任务栈的栈顶                           */
    		;指针占3B。+0类型 +1高8位数据 +2低8位数据
    		
        ;OSTCBCur->OSTCBStkPtr ==> DPTR  获得用户堆栈指针
        INC  DPTR        ;指针占3B。+0类型 +1高8位数据 +2低8位数据
        MOVX A,@DPTR     ;OSTCBStkPtr是void指针
        MOV  R0,A
        INC  DPTR
        MOVX A,@DPTR
        MOV  R1,A
        MOV  DPH,R0
        MOV  DPL,R1
        ;此时 DPL,DPH 中存放的是系统当前任务的用户堆栈结构        
     	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;保存硬件堆栈长度用户堆栈中
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        MOV  A,R5
        MOVX @DPTR,A

        MOV  R0,#OSStkStart	;指向硬件堆栈起始地址

        
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; R0: 硬件堆栈 
        ;; DPTR: 要被切出的任务堆栈
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; 将硬件堆栈保存到软件堆栈中,顺序参考 PUSHALL
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        INC  DPTR
        INC  R0
        MOV  A,@R0
        MOVX @DPTR,A
        DJNZ R5,save_stack
        
        ;保存仿真堆栈指针?C_XBP
        INC  DPTR
        MOV  A,?C_XBP	;?C_XBP 仿真堆栈指针高8位
        MOVX @DPTR,A
        INC  DPTR
        MOV  A,?C_XBP+1	;?C_XBP 仿真堆栈指针低8位
        MOVX @DPTR,A        
    
        ;调用 Hook 程序
        LCALL _?OSTaskSwHook


        ; R0: 当前任务
        ; R1: 要换入的任务
        
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;全局变量修改: OSTCBCur = OSTCBHighRdy
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        MOV  R0,#OSTCBCur
		MOV  R1,#OSTCBHighRdy
		MOV  A,@R1
        MOV  @R0,A
        
        INC  R0
		INC  R1
		MOV  A,@R1
        MOV  @R0,A
        
        INC  R0
		INC  R1
		MOV  A,@R1
        MOV  @R0,A
              
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;全局变量修改: OSPrioCur = OSPrioHighRdy 使用这两个变量主要目的是为了使指针比较变为字节比较,以便节省时间
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        MOV  R0,#OSPrioCur
		MOV  R1,#OSPrioHighRdy
		MOV  A,@R1
        MOV  @R0,A
        
        LJMP OSCtxSw_in
        
OSCtxSw_in:
		;/*  取得最高优先级任务的堆栈地址*/
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; DPTR = 要换入的任务堆栈
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        MOV  R0,#LOW (OSTCBHighRdy)	;获得OSTCBHighRdy指针低地址,指针占3B。+0类型 +1高8位数据 +2低8位数据
        INC  R0
        MOV  DPH,@R0    ;全局变量OSTCBHighRdy在IDATA中
        INC  R0
        MOV  DPL,@R0
    	;此处 DPL,DPH 中存放的是当前就绪优先级的 TCB 指针

    	
        ;OSTCBHighRdy->OSTCBStkPtr ==> DPTR 获得用户堆栈指针
        INC  DPTR		;指针占3B。+0类型 +1高8位数据 +2低8位数据
        MOVX A,@DPTR	;OSTCBStkPtr是void指针
        MOV  R0,A
        INC  DPTR
        MOVX A,@DPTR
        MOV  R1,A
        MOV  DPH,R0
        MOV  DPL,R1
    	;此处 DPL,DPH 中存放的最高优先级任务(即要换入的任务)的用户堆栈指针 

        ; DPTR: 指向要换入的用户堆栈
    	
        ;*UserStkPtr ==> R5 用户堆栈起始地址内容(即用户堆栈长度放在此处)   
        MOVX A,@DPTR	;用户堆栈中是 unsigned char 类型数据
        MOV  R5,A		;R5 = 用户堆栈长度
    
        ;获取硬件堆栈地址
        MOV  R0,#OSStkStart;OSStkStart 是系统堆栈的起始地址

        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ; DPTR: 指向要换入的用户堆栈 
        ; R0: 指向硬件堆栈 
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

restore_stack:

    	;系统中的堆栈的入栈顺序是自己做的一个。。。。。
    	;具体的堆栈顺序在 POPALL,PUSHALL中
    	
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; 将用户堆栈复恢复到硬件堆栈中
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        
        INC  DPTR
        INC  R0
        MOVX A,@DPTR
        MOV  @R0,A
        DJNZ R5,restore_stack
    
        ; 因为是通过 R0 模拟 SP 访问的硬件堆栈,此时 R0 指向硬件堆栈堆栈顶了, 51 是堆栈是向上长的
        ; 这里是同步 SP 到栈顶?
        MOV  SP,R0
    
        ;恢复仿真堆栈指针 ?C_XBP        
        INC  DPTR
        MOVX A,@DPTR
        MOV  ?C_XBP,A	;?C_XBP 仿真堆栈指针高8位
        INC  DPTR
        MOVX A,@DPTR
        MOV  ?C_XBP+1,A	;?C_XBP 仿真堆栈指针低8位
  
        POPALL		;这句的任务是将系统堆栈恢复到各个寄存器中去了
        SETB EA		;开中断
        RETI		;从堆栈中弹出断点地址并装入PC中,使CPU回到原来主程序的断点处继续运行
c51智能卡cos操作系统源代码-keil uv2。 COS的全称是Chip Operating System(片内操作系统),它一般是紧紧围绕着它所服务的智能卡的特点而开发的。由于不可避免地受到了智能卡内微处理器芯片的性能及内存容量的影响,因此,COS在很大程度上不同于我们通常所能见到的微机上的操作系统(例如DOS、UNIX等)。   首先,COS是一个专用系统而不是通用系统。即:一种COS一般都只能应用于特定的某种(或者是某些)智能卡,不同卡内的COS一般是不相同的。因为COS一般都是根据某种智能卡的特点及其应用范围而特定设计开发的,尽管它们在所实际完成的功能上可能大部分都遵循着同一个国际标准。其次,与那些常见的微机上的操作系统相比较而言,COS在本质上更加接近于临控程序、而不是一个通常所谓的真正意义上的操作系统,这一点至少在目前看来仍是如此。因为在当前阶段,COS所需要解决的主要还是对外部的命令如何进行处理、响应的问题,这其中一般并不涉及到共享、并发的管理及处理,而且就智能卡在目前的应用情况而盲,并发和共享的工作也确实是不需要曲。COS在设计时一般都是紧密结合智能卡内存储器分区的情况,按照国际标准(ISO/IEC7816系列标准)中所规定的一些功能进行设计、开发。但是由于目前智能卡的发展速度很快,而国际标准的制定周期相对比较长一些,因而造成了当前的智能卡国际标准还不太完善的情况,据此,许多厂家又各自都对自己开发的COS作了一引起扩充。   就目前而言,还没有任何一家公司的COS产品能形成一种工业标准。因此本文将主要结合现有的(指l994年以前)国际标准,重点讲述COS的基本原理以及基本功能,在其中适当地列举它们在某些产品中的实现方式作为例子。   COS的主要功能是控制智能卡同外界的信息交换,管理智能卡内的存储器并在卡内部完成各种命令的处理。其中,与外界进行信息交换是COS最基本的要求。在交换过程中,COS所遵循的信息交换协议目前包括两类:异步字符传输的T=0协议以及异步分组传输的T=l协议。这两种信息交换协议的具体内容和实现机制在IS0/IEC78l6-3和IS0/IEC7816-3A3标准中作了规定;而COS所应完成的管理和控制的基中功能则是在 ISO/IEC78l6-4标准中作出规定的。在该国际标准中,还对智能卡的数据结构以及COS的基本命令集作出了较为详细的说明。至于IS0/IEC78l6-l和2,则是对智能卡的物理参数、外形尺寸作了规定,它们与COS的关系不是很密切。   COS的体系   依赖于上一节中所描述的智能卡的硬件环境,可以设计出各种各样的COS。但是,所有的COS都必须能够解决至少三个问题,即:文件操作、鉴别与核实、安全机制。事实上,鉴别与核实和安全机制都属于智能卡的安全体系的范畴之中,所以,智能卡的COS中最重要的两方面就是文件与安全。但再具体地分析一下,则我们实际上可以把从读写设备(即接口设备IFD)发出命令到卡给出响应的一个完整过程划分为四个阶段,也可以说是四个功能模块:传送管理器(TM)、安全管理器(SM)、应用管理器(AM)和文件管理器(FM)。其中,传送管理器用于检查信息是否被正确地传送。这一部分主要和智能卡所采用的通信协议有关;安全管理器主要是对所传送的信息进行安全性的检查或处理,防止非法的窃听或侵入;应用管理器则用于判断所接收的命令执行的可能性;文件管理器通过核实命令的操作权限,最终完成对命令的处理。对于一个具体的COS命令而言,这四个阶段并不一定都是必须具备的,有些阶段可以省略,或者是并人另一阶段中;但一般来说,具备这四个阶段的COS是比较常见的。以下我们将按照这四个阶段对COS进行较为详细的论述。   在这里需要提起注意的是,智能卡中的“文件”概念与我们通常所说的“文件”是有区别的。尽管智能卡中的文件内存储的也是数据单元或记录,但它们都是与智能卡的具体应用直接相关的。一般而言,一个具体的应用必然要对应于智能卡中的一个文件,因此,智能卡中的文件不存在通常所谓的文件共享的情况。而且,这种文件不仅在逻辑广必须是完整的,在物理组织上也都是连续的。此外,智能卡中的文件尽管也可以拥有文件名,但对文件的标识依靠的是与卡中文件—一对应的文件标识符,而不是文件名。因为智能卡中的文件名是允许重复的,它在本质上只是文件的一种助记符,并不能完全代表整个文件。   传送管理(Transmission Manager)   传送管理主要是依据智能卡所使用的信息传输协议,对由读写设备发出的命令进行接收。同时,把对命令的响应按照传输协汉的格式发送出去。由此可见,这一部分主要和智能卡具体使用的通信协议有关,而且,所采用的通信协议越复杂,这一部分实现起来也就越困难、越复杂。   我们在前面提到过目
评论
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值