bat文件浅析（三）

最新推荐文章于 2022-11-23 14:30:52 发布

小伙子wp

最新推荐文章于 2022-11-23 14:30:52 发布

阅读量1.1k

点赞数

CC 4.0 BY-SA版权

分类专栏： bat 文章标签： bat

本文链接：https://blog.youkuaiyun.com/w2865673691/article/details/19249517

bat 专栏收录该内容

4 篇文章

订阅专栏

本文详细介绍了Windows批处理文件中的组合命令（&、&&、||）、set命令的应用，包括字符串处理技巧，如替换、分割、合并及长度计算。还探讨了setlocal与变量延迟的原理及其在批处理中的重要性，提供了实例演示。

组合命令&/&&/||

&语法：第一条命令 & 第二条命令 [& 第三条命令...]

这个符号允许在一行中使用2个以上不同的命令，当第一个命令执行失败了，也不影响后边的命令执行。这里&两边的命令是顺序执行的，从前往后执行。

&&语法：第一条命令 && 第二条命令 [&& 第三条命令...]

用这种方法可以同时执行多条命令，当碰到执行出错的命令后将不执行后面的命令，如果一直没有出错则一直执行完所有命令
这个命令和上边的类似，但区别是，第一个命令失败时，后边的命令也不会执行

||语法：第一条命令 || 第二条命令 [|| 第三条命令...]

用这种方法可以同时执行多条命令，当一条命令失败后才执行第二条命令，当碰到执行正确的命令后将不执行后面的命令，如果没有出现正确的命令则一直执行完所有命令；

C:\Users\Administrator>echo hello0 && echo hello1
hello0
hello1

C:\Users\Administrator>echo hello0 || echo hello1
hello0

之所以介绍这个，是因为后面有用到&的地方，于是就一起先介绍了。

set命令

C:\Users\ASUS>help set

显示、设置或删除 cmd.exe环境变量。

 

SET [variable=[string]]

 

  variable  指定环境变量名。

  string    指定要指派给变量的一系列字符串。

 

要显示当前环境变量，键入不带参数的 SET。

 

如果命令扩展被启用，SET会如下改变:

 

可仅用一个变量激活 SET命令，等号或值不显示所有前缀匹配SET 命令已使用的名称的所有变量的值。例如:

 

    SET P

 

会显示所有以字母 P打头的变量

 

如果在当前环境中找不到该变量名称，SET命令将把 ERRORLEVEL设置成 1。

 

SET 命令不允许变量名含有等号。

 

在 SET 命令中添加了两个新命令行开关:

 

    SET /A expression

    SET /Pvariable=[promptString]

 

/A 命令行开关指定等号右边的字符串为被评估的数字表达式。该表评估器很简单并以递减的优先权顺序支持下列操作:

    ()                  -分组

    ! ~ -               -一元运算符

    * / %               -算数运算符

    + -                 -算数运算符

    << >>               -逻辑移位

                       -按位“与”

    ^                   -按位“异”

    |                   -按位“或”

    = *= /= %= += -=    -赋值

      &= ^= |= <<=>>=

    ,                   -表达式分隔符

 

如果您使用任何逻辑或取余操作符，您需要将表达式字符串用引号扩起来。在表达式中的任何非数字字符串键作为环境变量名称，这些环境变量名称的值已在使用前转换成数字。如果指定了一个环境变量名称，但未在当前环境中定义，那么值将被定为零。这使您可以使用环境变量值做计算而不用键入那些 %符号来得到它们的值。如果SET /A 在命令脚本外的命令行执行的，那么它显示该表达式的最后值。该分配的操作符在分配的操作符左边需要一个环境变量名称。除十六进制有 0x前缀，八进制有 0 前缀的，数字值为十进位数字。因此，0x12与 18 和 022相同。请注意八进制公式可能很容易搞混: 08和 09 是无效的数字因为 8和 9 不是有效的八进制位数。(& )

 

/P 命令行开关允许将变量数值设成用户输入的一行输入。读取输入行之前，显示指定的 promptString。promptString可以是空的。

 

环境变量替换已如下增强:

 

    %PATH:str1=str2%

 

会扩展 PATH环境变量，用 "str2" 代替扩展结果中的每个 "str1"要有效地从扩展结果中删除所有的 "str1"，"str2"可以是空的。"str1" 可以以星号打头；在这种情况下，"str1"会从扩展结果的开始到 str1 剩余部分第一次出现的地方，都一直保持相配。

 

也可以为扩展名指定子字符串。

 

    %PATH:~10,5%

 

会扩展 PATH环境变量，然后只使用在扩展结果中从第 11 个(偏移量 10)字符开始的五个字符。如果没有指定长度，则采用默认值，即变量数值的余数。如果两个数字(偏移量和长度)都是负数，使用的数字则是环境变量数值长度加上指定的偏移量或长度。

 

    %PATH:~-10%

 

会提取 PATH变量的最后十个字符。

 

    %PATH:~0,-2%

 

会提取 PATH变量的所有字符，除了最后两个。

 

终于添加了延迟环境变量扩充的支持。该支持总是按默认值被停用，但也可以通过CMD.EXE的 /V 命令行开关而被启用/停用。请参阅 CMD /?

 

考虑到读取一行文本时所遇到的目前扩充的限制时，延迟环境变量扩充是很有用的，而不是执行的时候。以下例子说明直接变量扩充的问题:

 

    set VAR=before

    if "%VAR%" == "before"(

        set VAR=after

        if "%VAR%"== "after" @echo If you see this, it wor

    )

 

不会显示消息，因为在读到第一个 IF语句时，BOTH IF 语句中的 %VAR%会被代替；原因是: 它包含 IF的文体，IF 是一个复合语句。所以，复合语句中的 IF实际上是在比较 "before" 和"after"，这两者永远不会相等。同样，以下这个例子也不会达到预期效果:

 

    set LIST=

    for %i in (*) do setLIST=%LIST% %i

    echo %LIST%

 

原因是，它不会在目前的目录中建立一个文件列表，而只是将LIST变量设成找到的最后一个文件。这也是因为 %LIST% 在FOR 语句被读取时，只被扩充了一次；而且，那时的 LIST变量是空的。因此，我们真正执行的 FOR 循环是:

 

    for %i in (*) do set LIST=%i

 

这个循环继续将 LIST设成找到的最后一个文件。

 

延迟环境变量扩充允许您使用一个不同的字符(惊叹号)在执行时间扩充环境变量。如果延迟的变量扩充被启用，可以将上面例子写成以下所示，以达到预期效果:

 

    set VAR=before

    if "%VAR%" =="before" (

        set VAR=after

        if "!VAR!"== "after" @echo If you see this, it wor

    )

 

    set LIST=

    for %i in (*) do set LIST=!LIST!%i

    echo %LIST%

 

如果命令扩展被启用，有几个动态环境变量可以被扩展，但不会出现在 SET显示的变量列表中。每次变量数值被扩展时，这些变量数值都会被动态计算。如果用户用这些名称中任何一个定义变量，那个定义会替代下面描述的动态定义:

 

%CD% - 扩展到当前目录字符串。

 

%DATE% - 用跟 DATE命令同样的格式扩展到当前日期。

 

%TIME% - 用跟 TIME命令同样的格式扩展到当前时间。

 

%RANDOM% - 扩展到 0和 32767 之间的任意十进制数字。

 

%ERRORLEVEL% - 扩展到当前 ERRORLEVEL 数值。

 

%CMDEXTVERSION% - 扩展到当前命令处理器扩展版本号。

 

%CMDCMDLINE% - 扩展到调用命令处理器的原始命令行。

上面是set命令的帮助信息，后面的介绍都是基于此的提取。

下面是我打印的一部分环境变量

C:\Users\ASUS>set

ALLUSERSPROFILE=C:\ProgramData

ANDROID_HOME=D:\ProgramFiles\android-sdk-windows

APPDATA=C:\Users\ASUS\AppData\Roaming

asl.log=Destination=file

CLASS_PATH=.

CommonProgramFiles=C:\Program Files\CommonFiles

COMPUTERNAME=ASUS-PC

ComSpec=C:\Windows\system32\cmd.exe

FP_NO_HOST_CHECK=NO

HOMEDRIVE=C:

HOMEPATH=\Users\ASUS

JAVA_HOME=D:\Program Files\Java\jdk1.6.0_24

JBOSS_HOME=D:\jboss-6.0.0.Final

下面是我打印的path环境变量部分内容

C:\Users\ASUS>echo %path%

C:\Program Files\NVIDIACorporation\PhysX\Common;D:\Programs\android-ndk-r7;D:\oracle\product\11.2.0\dbhome_1\bin;C:\Windows\system32;C:\Windows;C:\Wi

ndows\System32\Wbem;C:\Windows\System32\WindowsPowerShell\v1.0\;C:\ProgramFiles\Common Files\Thunder Network\KanKan\Codecs;D:\Program Files\Java\jdk1

.6.0_24\bin;

字符串处理

1) 替换字符串

C:\Users\Administrator>echo %str%
%str%

C:\Users\Administrator>set str=0123456789   

C:\Users\Administrator>echo %str%
0123456789

C:\Users\Administrator>set str=%str:9=aa%  //替换

C:\Users\Administrator>echo %str%
012345678aa

C:\Users\Administrator>set str=%str:aa=bb%  //替换

C:\Users\Administrator>echo %str%
012345678bb

C:\Users\Administrator>set str=%str:bb=9%  //替换

C:\Users\Administrator>echo %str%
0123456789

C:\Users\Administrator>

2)分割字符串

其实上面set命令的帮助信息已经详细的说明了，现在再重新整理一下，格式如下：

%源字符串:~起始值,截取长度%

(起始值从0开始；截取长度是可选的，如果省略逗号和截取长度，将会从起始值截取到尾;截取长度如果是负数，表示截取到倒数第几个。)

C:\Users\Administrator>echo %str%  
0123456789

C:\Users\Administrator>echo %str:~1,5%  //从下标为1处开始截取长度为5的字符串
12345

C:\Users\Administrator>echo %str:~2%    //从下标为2处开始到结尾
23456789

C:\Users\Administrator>echo %str:~-3%   //后3位
789

C:\Users\Administrator>echo %str:~2,-3%  //从下标为2处开始到结尾，再去掉后2位
23456

C:\Users\Administrator>echo %str:~-2,-3%  //没有分割
ECHO 处于打开状态。

C:\Users\Administrator>

上面的字串分割格式，也可以用于其它地方，如目录路径："%cd:~0,10%"

3) 字符串合并

由于没有直接的字符串合并函数，只能用笨方法了。

C:\Users\Administrator>set str1=hello

C:\Users\Administrator>echo %str1%
hello

C:\Users\Administrator>set str2= world

C:\Users\Administrator>echo %str2%
 world

C:\Users\Administrator>str=%str1%%str2%
'str' 不是内部或外部命令，也不是可运行的程序
或批处理文件。

C:\Users\Administrator>set str=%str1%%str2%

C:\Users\Administrator>echo %str%
hello world

C:\Users\Administrator>

4) 计算字符串长度

没有现成的函数。如下test_length.cmd程序利用 goto形成循环，不断将字符串截短1，并记录截短的次数，到字符串变成空时的次数即长度。文件中有if语句，将在下一篇博文介绍。

@echo off

set testStr=This is a test string
:: 将 testStr复制到str，str是个临时字符串
set str=%testStr%

:: 标签，用于goto跳转
:next1
echo %str%  num=%num%
:: 判断str是不是空，如果不是则执行下边的语句
if not "%str%"=="" (
 set /a num+=1
 set "str=%str:~1%"
 :: 跳转到next1标签:这里利用goto和标签，构成循环结构
 goto next1
)

:: 当以上循环结构执行完毕时，会执行下边的语句
echo testStr=%testStr%
echo testStr的长度为：%num%

pause

运行结果：

This is a test string  num=
his is a test string  num=1
is is a test string  num=2
s is a test string  num=3
 is a test string  num=4
is a test string  num=5
s a test string  num=6
 a test string  num=7
a test string  num=8
 test string  num=9
test string  num=10
est string  num=11
st string  num=12
t string  num=13
 string  num=14
string  num=15
tring  num=16
ring  num=17
ing  num=18
ng  num=19
g  num=20
  num=21
testStr=This is a test string
testStr的长度为：21
请按任意键继续. . .

5) 截取字符串时，需要传递参数

直接 echo%args:~%num%,-5%没办法想要的字符串，正确做法如下test3_0.cmd:

@echo off

setlocal enabledelayedexpansion
set str=hello world , I am WangPeng.
set num=2

echo str=%str%
echo num=%num%

@echo on
echo !str:~%num%,-5!

pause

运行结果：

str=hello world , I am WangPeng.
num=2

C:\Users\Administrator\Desktop>echo !str:~2,-5!
llo world , I am Wang

C:\Users\Administrator\Desktop>pause
请按任意键继续. . .

setlocal与变量延迟

0) 在没有开启变量延迟的情况下，某条命令行中的变量改变，必须到下一条命令才能体现。

另外例如for命令等，其后用一对圆括号闭合的所有语句也当作一行。

C:\Users\Administrator>set var=4

C:\Users\Administrator>set var=5 & echo %var%
4

C:\Users\Administrator>echo %var%
5

C:\Users\Administrator>

也可以对这种机制加以利用，如下的变量交换

C:\Users\Administrator>set var1=abc

C:\Users\Administrator>set var2=xxx

C:\Users\Administrator>echo var1=%var1%  var2=%var2%
var1=abc  var2=xxx

C:\Users\Administrator>set var1=%var2% & set var2=%var1%

C:\Users\Administrator>echo var1=%var1%  var2=%var2%
var1=xxx   var2=abc

C:\Users\Administrator>

可以看出交换变量无需像c或者Java之类的语言去设置中间缓存变量temp了

1) 启动批处理文件中环境变量的本地化。本地化将持续到出现匹配的endlocal命令或者到达批处理文件结尾为止。

C:\Users\Administrator>help setlocal
开始批处理文件中环境改动的本地化操作。在执行 SETLOCAL 之后
所做的环境改动只限于批处理文件。要还原原先的设置，必须执
行 ENDLOCAL。达到批处理文件结尾时，对于该批处理文件的每个
尚未执行的 SETLOCAL 命令，都会有一个隐含的 ENDLOCAL 被执行。

SETLOCAL

如果命令扩展被启用，SETLOCAL 会如下改变:

SETLOCAL 批命令现在可以接受可选参数:
        ENABLEEXTENSIONS / DISABLEEXTENSIONS
            启用或禁用命令处理器扩展。这些
            参数比 CMD /E:ON 或 /E:OFF
            开关有优先权。请参阅 CMD /? 获取详细信息。
        ENABLEDELAYEDEXPANSION / DISABLEDELAYEDEXPANSION
            启用或禁用延缓环境变量
            扩展。这些参数比 CMD
            /V:ON 或 /V:OFF 开关有优先权。请参阅 CMD /? 获取详细信息。
无论在 SETLOCAL 命令之前它们的设置是什么，这些修改会一直
保留到匹配的 ENDLOCAL 命令。

如果有一个参数，
SETLOCAL 命令将设置 ERRORLEVEL 的值。如果有两个有效参数中的一个，
该值则为零。
用下列技巧，您可以在批脚本中
使用这个来决定扩展是否可用:

    VERIFY OTHER 2>nul
    SETLOCAL ENABLEEXTENSIONS
    IF ERRORLEVEL 1 echo Unable to enable extensions

这个方法之所以有效，是因为在 CMD.EXE 的旧版本上，SETLOCAL
未设置 ERRORLEVEL 值。具有不正确参数的 VERIFY 命令将
ERRORLEVEL 值初始化成非零值。

2) 为了能够感知环境变量的动态变化，批处理设计了变量延迟。简单来说，在读取了一条完整的语句之后，不立即对该行的变量赋值，而会在某个单条语句执行之前再进行赋值，也就是说“延迟”了对变量的赋值。

下面写一个test3_1.cmd文件，内容如下

setlocal ENABLEDELAYEDEXPANSION

set var=4

set var=5 & echo !var!

pause

执行结果：

C:\Users\Administrator\Desktop>setlocal ENABLEDELAYEDEXPANSION

C:\Users\Administrator\Desktop>set var=4

C:\Users\Administrator\Desktop>set var=5   & echo !var!
5

C:\Users\Administrator\Desktop>pause
请按任意键继续. . .

变量延迟的启动语句是“setlocalenabledelayedexpansion”，并且变量要用一对叹号“!!”括起来

由于启动了变量延迟，所以批处理能够感知到动态变化，即不是先给该行变量赋值，而是在运行过程中给变量赋值，因此此时var的值就是5了

另外，启动变量延迟，“%”的变量还是不变

更多介绍请研读上面set命令帮助信息