AS3碰撞检测类

最新推荐文章于 2015-01-08 14:42:36 发布

version10

最新推荐文章于 2015-01-08 14:42:36 发布

阅读量315

点赞数

CC 4.0 BY-SA版权

分类专栏： AS3程序基础文章标签： Flash 游戏 Adobe

本文链接：https://blog.youkuaiyun.com/version10/article/details/83851498

AS3程序基础专栏收录该内容

2 篇文章

订阅专栏

本文介绍了一种在Adobe Flash的ActionScript 3 (AS3) 中实现更精确碰撞检测的方法。通过自定义的HitTest类，该方法能够有效地检测不规则形状之间的碰撞，适用于游戏开发和其他交互式应用。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

众所周知，Adobe有一群懒散的工程师，所以adobe给as3提供的一些工具方法也就很具有欺骗性，今天我要给大家提供的是一个非常常用的功能。
碰撞检测，无论是游戏还是什么，都是很常见的，flash.display包下面的Display类中有个hitTestObject()的一个方法，简言之，这个东西检测矩形元件检测还不错，但是有多少图形是标准的矩形呢？所以今天我要给大家推荐一个很好的碰撞检测类：

package {

	import flash.display.BitmapData;
	import flash.display.BlendMode;
	import flash.display.DisplayObject;
	import flash.display.Sprite;
	import flash.geom.ColorTransform;
	import flash.geom.Matrix;
	import flash.geom.Point;
	import flash.geom.Rectangle;

	public class HitTest
	{

		public static function complexHitTestObject( target1:DisplayObject, target2:DisplayObject,  accurracy:Number = 1 ):Boolean
		{
			trace(complexIntersectionRectangle( target1, target2, accurracy ).width);

			return (complexIntersectionRectangle( target1, target2, accurracy ).width != 0);
		}

		public static function intersectionRectangle( target1:DisplayObject, target2:DisplayObject ):Rectangle
		{

			if( !target1.root || !target2.root || !target1.hitTestObject( target2 ) ) return new Rectangle();


			var bounds1:Rectangle = target1.getBounds( target1.root );
			var bounds2:Rectangle = target2.getBounds( target2.root );


			var intersection:Rectangle = new Rectangle();
			intersection.x   = Math.max( bounds1.x, bounds2.x );
			intersection.y    = Math.max( bounds1.y, bounds2.y);
			intersection.width      = Math.min( ( bounds1.x + bounds1.width ) - intersection.x, ( bounds2.x + bounds2.width ) - intersection.x );
			intersection.height = Math.min( ( bounds1.y + bounds1.height ) - intersection.y, ( bounds2.y + bounds2.height ) - intersection.y );

			return intersection;
		}

		public static function complexIntersectionRectangle( target1:DisplayObject, target2:DisplayObject, accurracy:Number = 1 ):Rectangle
		{                     
			if( accurracy <= 0 ) throw new Error( "ArgumentError: Error #5001: Invalid value for accurracy", 5001 );


			if( !target1.hitTestObject( target2 ) ) return new Rectangle();

			var hitRectangle:Rectangle = intersectionRectangle( target1, target2 );

			if( hitRectangle.width * accurracy <1 || hitRectangle.height * accurracy <1 ) return new Rectangle();

			var bitmapData:BitmapData = new BitmapData( hitRectangle.width * accurracy, hitRectangle.height * accurracy, false, 0x000000 ); 


			bitmapData.draw( target1, HitTest.getDrawMatrix( target1, hitRectangle, accurracy ), new ColorTransform( 1, 1, 1, 1, 255, -255, -255, 255 ) );

			bitmapData.draw( target2, HitTest.getDrawMatrix( target2, hitRectangle, accurracy ), new ColorTransform( 1, 1, 1, 1, 255, 255, 255, 255 ), BlendMode.DIFFERENCE );


			var intersection:Rectangle = bitmapData.getColorBoundsRect( 0xFFFFFFFF,0xFF00FFFF );

			bitmapData.dispose();


			if( accurracy != 1 )
			{
				intersection.x /= accurracy;
				intersection.y /= accurracy;
				intersection.width /= accurracy;
				intersection.height /= accurracy;
			}

			intersection.x += hitRectangle.x;
			intersection.y +=( hitRectangle.y);

			return intersection;
		}


		protected static function getDrawMatrix( target:DisplayObject, hitRectangle:Rectangle, accurracy:Number ):Matrix
		{
			var localToGlobal:Point;;
			var matrix:Matrix;

			var rootConcatenatedMatrix:Matrix = target.root.transform.concatenatedMatrix;

			localToGlobal = target.localToGlobal( new Point( ) );
			matrix = target.transform.concatenatedMatrix;
			matrix.tx = localToGlobal.x - hitRectangle.x;
			matrix.ty = localToGlobal.y - hitRectangle.y;

			matrix.a = matrix.a / rootConcatenatedMatrix.a;
			matrix.d = matrix.d / rootConcatenatedMatrix.d;
			if( accurracy != 1 ) matrix.scale( accurracy, accurracy );

			return matrix;
		}

	}

}