Mplus数据分析:随机截距交叉之后的做法和如何加协变量,写给粉丝

Mplus—随机截距交叉滞后模型(Random Intercepts Cross-Lagged Panel Model, RI-CLPM) 介绍随机截距交叉滞后模型(Random Intercepts Cross-Lagged Panel Model, RI-CLPM)的相关知识,例如模型内容、Mplus语法及对应网址等。 阅读详情
AI摘要

本文详细介绍了如何使用Mplus软件进行随机截距交叉滞后模型的构建,包括添加协变量和进行多组比较。首先解释了Mplus的默认设定,并展示了如何设定模型以改变这些设定。接着,演示了如何控制协变量在显变量和随机截距水平的影响。最后,讲解了如何进行多组比较,以检验不同群体间的路径系数差异。通过具体的代码示例,帮助读者理解和应用这些统计方法。

记得之前有写过如何用R做随机截距交叉滞后,有些粉丝完全是R小白,还是希望我用mplus做,今天就给大家写写如何用mplus做随机截距交叉滞后。

做之前我们需要知道一些Mplus的默认的设定:

  • observed and latent exogenous variables are correlated, and
  • residuals of observed and latent outcome variables (which do not predict anything) in a path model are correlated.

这些设定可以帮助我们更容易地设定结构方程模型,但是在做随机截距交叉滞后模型的时候我们需要变化一下,此时需要在语法中加上ANALYSIS: MODEL = NOCOV;

用mplus做随机截距交叉滞后需要规定4个部分:

  1. 因素间部分,就是随机截距,用BY来设置,写出RIx BY x1@1 x2@1 ...这样的形式,其中@1表示固定为1的意思,这个是做随机效应交叉滞后的默认操作
  2. 因素内部分的内在波动,也是用BY来设定,写出wx1 BY x1; wx2 BY x2; ....这样的形式,同时需要将误差方差固定为0
  3. 交叉滞后部分,写出wx2 ON wx1 wy1; wx3 ON wx2 wy2; ....这样的形式
  4. 内外共变部分,因素内写出wx1 WITH wy1; wx2 WITH wy2;....这样的形式;因素外写出RIx WITH RIy的形式。

所以一个基本的随机截距交叉滞后的代码就是如下:

MODEL:      ! 随机截距
            RIx BY x1@1 x2@1 x3@1 x4@1 x5@1;
            RIy BY y1@1 y2@1 y3@1 y4@1 y5@1;
    
            ! 因素内
            wx1 BY x1@1; 
            wx2 BY x2@1;
            wx3 BY x3@1; 
            wx4 BY x4@1; 
            wx5 BY x5@1;
            
            wy1 BY y1@1; 
            wy2 BY y2@1;
            wy3 BY y3@1; 
            wy4 BY y4@1; 
            wy5 BY y5@1;
    
            ! 误差方差为0
            x1-y5@0;
    
            ! 交叉滞后
            wx2 wy2 ON wx1 wy1;
            wx3 wy3 ON wx2 wy2;
            wx4 wy4 ON wx3 wy3;
            wx5 wy5 ON wx4 wy4;
    
            ! 随机截距相关
            RIx WITH RIy;
    
            !组内相关
            wx1 WITH wy1;
            wx2 WITH wy2;
            wx3 WITH wy3; 
            wx4 WITH wy4;
            wx5 WITH wy5; 

加协变量

一般情况下我们在重复测量之前都会收集一般人口学特征等等协变量,在做分析的时候我们也会有控制协变量的需求,此处我们是有两个选择,一个是把协变量在显变量水平(左图),另外一个是将协变量控制在随机截距水平(右图):

控制在显变量水平的意思就是说我这些变量对模型的作用都是对每一波测量都有的,在协变量不变的情况下来从整体上拟合我们的模型,比如我现在有一个协变量Z我就可以写出代码如下:

MODEL:      ! 随机截距
            RIx BY x1@1 x2@1 x3@1 x4@1 x5@1;
            RIy BY y1@1 y2@1 y3@1 y4@1 y5@1;

            RIx WITH RIy;

            wx1 BY x1@1; 
            wx2 BY x2@1;
            wx3 BY x3@1; 
            wx4 BY x4@1;
            wx5 BY x5@1;

            wy1 BY y1@1; 
            wy2 BY y2@1;
            wy3 BY y3@1; 
            wy4 BY y4@1;
            wy5 BY y5@1;

         
            x1-y5@0;

            ! 协变量添加
            x1-x5 ON z1 (s1);
            y1-y5 ON z1 (s2);

            wx2 wy2 ON wx1 wy1;
            wx3 wy3 ON wx2 wy2;
            wx4 wy4 ON wx3 wy3;
            wx5 wy5 ON wx4 wy4;

            wx1 WITH wy1;
           
            wx2 WITH wy2;
            wx3 WITH wy3; 
            wx4 WITH wy4; 
            wx5 WITH wy5;

控制在放在随机截距的意思就是说这个显变量是影响了个体差异进而影响整个模型,这个是在探究between-difference的影响的时候用的,此时我们的代码如下:

MODEL:      
            RIx BY x1@1 x2@1 x3@1 x4@1 x5@1;
            RIy BY y1@1 y2@1 y3@1 y4@1 y5@1;

           
            RIx WITH RIy;

            wx1 BY x1@1; 
            wx2 BY x2@1;
            wx3 BY x3@1; 
            wx4 BY x4@1;
            wx5 BY x5@1;

            wy1 BY y1@1; 
            wy2 BY y2@1;
            wy3 BY y3@1; 
            wy4 BY y4@1;
            wy5 BY y5@1;

            x1-y5@0;

            ! 协变量添加语法
            RIx RIy ON z1;


            wx2 wy2 ON wx1 wy1;
            wx3 wy3 ON wx2 wy2;
            wx4 wy4 ON wx3 wy3;
            wx5 wy5 ON wx4 wy4;


            wx1 WITH wy1;
           
            wx2 WITH wy2;
            wx3 WITH wy3; 
            wx4 WITH wy4; 
            wx5 WITH wy5;

运行上面的代码我们的带协变量的随机截距交叉滞后就出来了,然后我们点击view diagram还可以看自动生成的路径图

自己生成的就是乱糟糟一团,然后点击图中的各个节点都是可以调整的,下图是给一个同学做的多个显变量的随机截距交叉滞后模型,模型中控制了两个协变量sex和degree,然后下图就是mplus自动生成的模型图,调整调整还是能看的,这个模型是将协变量控制在显变量水平的:

多组比较建模

多组比较的意思就是看看路径系数或者载荷,在某个变量的组间是不是一样,内在原理是将模型分组拟合,然后比较固定两组路径相等的模型拟合优度和两组自由估计的优度之间的差异,如果路径相等的模型并没有显著差于自由估计的模型就可以认为组间无差异,常见的应用就是在量表的跨文化调试中,比如你想看看英文和中文的量表有没有差异,你就可以尝试进行多组比较建模:

Multigroup models test separate models in two or more discrete groups. Equality constraints across groups are used to conduct nested tests using likelihood ratio comparisons between a model with certain parameters constrained to be equal and a model with those same parameters freely estimated (allowed to differ) across the groups. For example, one can investigate whether means, predictive paths, or loadings differ across two nationalities.

做多组比较的时候,我们也需要修改一些mplus的默认设定,在默认设定中,显变量的截距在组间是等价的;潜变量的均值是自由估计的,我们在做多组比较模型的时候需要估计的参数其实变多了,所以我们需要将显变量的截距自由估计和将潜变量的均值固定从而释放更多的自由度。

如果我们要依照某个变量比如说group这个变量进行多组比较,我就可以在variable参数中加上grouping,写出代码如下,如果我们想直接比较某两个参数,我们可以用model test语法,然后结果中就会输出系数的组间检验,比如下面的代码就是在比较两组间随机截距的相关是不是一样:

VARIABLE:   NAMES = x1-x5 y1-y5 GROUP;
            GROUPING = GROUP (1=G1 2=G2);

MODEL:      ! 随机截距部分
            RIx BY x1@1 x2@1 x3@1 x4@1 x5@1;
            RIy BY y1@1 y2@1 y3@1 y4@1 y5@1;
    
            ! 测量误差
            wx1 BY x1@1; 
            wx2 BY x2@1;
            wx3 BY x3@1; 
            wx4 BY x4@1; 
            wx5 BY x5@1;
            
            wy1 BY y1@1; 
            wy2 BY y2@1;
            wy3 BY y3@1; 
            wy4 BY y4@1; 
            wy5 BY y5@1;
    
            
            x1-y5@0;
    
            ! 交叉滞后系数
            wx2 wy2 ON wx1 wy1;
            wx3 wy3 ON wx2 wy2;
            wx4 wy4 ON wx3 wy3;
            wx5 wy5 ON wx4 wy4;
    
            ! 随机截距共变
            RIx WITH RIy(a);
    
            ! 同一波次的相关
            wx1 WITH wy1;
            wx2 WITH wy2;
            wx3 WITH wy3; 
            wx4 WITH wy4;
            wx5 WITH wy5;
  MODEL G2:  
               RIx WITH RIy(b);
model test:
    a = b;

上面的代码的意思就是在运行上面的代码就可以出多组比较的结果了:

结果中会有系数比较的结果,说明两组间我们的系数(随机截距的相关)是有显著差异的:

以上就是今天给大家分享的在随机截距交叉滞后中控制协变量以及如何做组间系数比较,希望对大家有所启发。

上面的所有操作都是可以在R语言中进行的,不过有做这个模型需求的大多数同学还是用mplus多,所以出了一期mplus,希望可以帮助到大家。之后会给大家写R的操作。

小结

今天给大家写了随机截距交叉滞后的mplus做法,包括如何添加协变量,以及如何进行多组比较,希望对大家有启发,感谢大家耐心看完,自己的文章都写的很细,代码都在原文中,希望大家都可以自己做一做,请转发本文到朋友圈后私信回复“数据链接”获取所有数据和本人收集的学习资料。如果对您有用请先收藏,再点赞分享。

也欢迎大家的意见和建议,大家想了解什么统计方法都可以在文章下留言,说不定我看见了就会给你写教程哦,另欢迎私信。

Mplus—多组随机截距交叉滞后模型(The multiple group RI-CLPM)/多组比较/多组分析 随机截距交叉滞后模型进行多组比较/多组分析的Mplus语句。 阅读详情

相关推荐

Mplus—纳入协变量的随机截距交叉滞后模型(RI-CLPM)语法

纳入时变和时不变协变量的随机截距交叉滞后模型(RI-CLPM)语法。

m0_54401011的博客 1909

交叉滞后面板分析(Cross-Lagged Panel Analysis, CLPA)

交叉滞后面板分析(Cross-Lagged Panel Analysis, CLPA)是一种统计方法,它在面板数据分析中用来研究变量之间的动态关系。这种分析方法特别适用于研究时间序列数据和横截面数据的结合体,即面板数据,其中数据集包含了多个个体在多个时间点的观测值。交叉滞后面板分析的目的是检验变量之间的因果关系,特别是当这些变量之间可能存在相互影响时。通过分析不同时间点的变量值,可以确定一个变量的变化是否在时间上先于另一个变量的变化,从而推断出可能的因果关系。

weixin_43156294的博客 4762

Mplus—随机截距交叉滞后模型(RI-CLPM)语法

随机截距交叉滞后模型RI-CLPM的Mplus语法。

m0_54401011的博客 2536

交叉滞后模型

欲了解大学新生一般自我效能感是否影响生活满意度,抽取大学新生样本:在开学第一个月对其同时施测‘一般自我效能感量表’和‘生活满意度问卷’,间隔两个月后,再次施测。如上述,我们主要关注其交叉滞后关系的系数估计和显著性,即可推断出两个变量的因果关系,三年级对暴力性电视节目的爱好对十三年级的攻击性具显著影响力,则为青少年攻击性形成的果。纵向追踪研究获得的多次数据进行分析以便确定哪个变量影响哪个变量,也就是确定变量之间因果关系的一种分析方法。既可研究A对B的影响,又可研究B对A的影响;如下,导入数据至AMOS板块。

weixin_55181917的博客 7552

Mplus—交叉滞后面板模型(Cross-Lagged Panel Model, CLPM)

本文介绍交叉滞后模型相关知识,以及显变量模型与潜变量模型在Mplus中的语法。

m0_54401011的博客 1万+

mplus 软件_多水平数据分析:R、Mplus和 HLM 应用对比

点亮小星星科研路上我们一起前行!当数据存在嵌套结构,或者多个水平如学校-班级-个人;企业-团队-个体;个体-多个时间点。通常的single level 分析,因违反观察及误差的独立性假定,更容易犯一类错误。我们需要multilevel。拿一个网上的段子来说,同样是九年义务教育,凭什么别人就那么优秀?以优秀程度来做结果变量,这种差异显然每个人和每个人是不一样(低水平),也可能一部分是不...

weixin_39688856的博客 3500

Mplus中RI-CLPM模型构建与协变量处理实战指南

结构方程模型(SEM)是社会科学与心理学研究中分析变量间关系的核心方法,其原理在于通过潜变量与观测变量的设定,检验理论模型的拟合度。在纵向追踪研究中,传统交叉滞后模型(CLPM)因无法分离个体特质与状态波动而受到局限,其技术价值在于为动态关系提供初步证据。随机截距交叉滞后模型(RI-CLPM)在此基础上引入随机截距,有效剥离了时间不变的稳定特质,使状态层面的因果推断更为纯净可靠。该模型适用于研究如压力与抑郁、学业投入与成绩等变量间随时间相互影响的机制。本文将聚焦于RI-CLPM在Mplus软件中的具体实现,

weixin_33739523的博客 407

R数据分析:潜在转化分析LTA的做法和解释(一)

之前给大家写了很多潜在类别分析的教程Mplus教程:如何做潜在类别分析LCAR数据分析:用R语言做潜类别分析LCAMplus数据分析:潜在类别分析(LCA)流程(详细版)R数据分析:再写潜在类别分析LCA的做法与解释,今天继续给大家拓展一步。 今天要介绍的就是潜在转换分析,这个东西就是LCA的纵向版本。是一个专门用来研究质变的统计技巧。有一句话叫做量变起质变,你怎么知道质变到底发生没有?就用潜在转换分析。 Latent transition analysis is an extension of...

Codewar的博客 7704

Mplus—简介及主要命令语句

Mplus的安装、界面介绍及主要命令语句。

m0_54401011的博客 9544

R数据分析:交叉滞后模型基础与实例解析

最近问纵向数据分析的同学贼多,像潜增长,GEE,多水平,之前都有写,今天偷空出个简易的交叉滞后教程哈,大家只要遇到像causal models,cross- lagged panel models,linear panel models 和autoregres-sive cross- lagged models 这些,都要反应过来他们都是一个东西,都叫面板模型,统一的数据特点就是把变量纵向测量很多波,然后想探讨变量间的关系,最简单的情形就是两波的时候啦,如下图: 我们看着这个图,可以自然而然地写出

Codewar的博客 1万+

文献解读:纵向数据的测量不变性和交叉滞后模型(二)

接着之前的文章文献解读:纵向数据的测量不变性和交叉滞后模型(一) 我们今天继续文献解读,上次说到了我们通过验证性因子分析已经得到我们的数据是符合构形不变性的,我们可以继续检验测量不变性的下一个水平单位等值(Metric invariance)。 单位等值(Metric invariance)设定 上篇文章已经讲了,单位等值这个水平要求测量因子与条目之间的关系——因子负荷(factor loading)是相等的,所以我们需要在之前模型的基础上再将所有不同时间相同因子的载荷设置为一样,代码如下: me

Codewar的博客 5267

mplus使用注意-grouping和数据直接分组结果不用

mplus使用

czchenzhou的博客 673

MplusAutomation:MplusAutomation软件包利用R语言的灵活性,使用由Muthen和Muthen(www.statmodel.com)开发的功能强大的潜在变量建模程序Mplus自动执行潜在变量模型的估计和解释。 具体来说,MplusAutomation提供了用于创建相关模型组,运行模型批处理以及提取和制表模型参数以及拟合统计量的例程。

Mplus自动化 MplusAutomation软件包利用R语言的灵活性,使用由Muthén和Muthén( )开发的功能强大的潜在变量建模程序Mplus自动执行潜在变量模型的估计和解释。 具体来说, MplusAutomation提供了用于创建相关模型组,运行模型批处理以及提取和制表模型参数和拟合统计量的例程。 安装 您可以通过运行以下MplusAutomation直接从安装最新版本的MplusAutomation install.packages("MplusAutomation") 另外,如果您想试用最新的MplusAutomation开发代码,则可以使用Hadley Wickham的devtools软件包直接从github安装。 如果尚未安装devtools ,请先安装它,然后再安装MplusAutomation 。 #install.packages("devtools")

mplus 画图 需要 java,Android自定义View 实现水波纹动画引导效果

一、实现效果图二、实现代码1.自定义viewpackage com.czhappy.showintroduce.view;import android.content.Context;import android.graphics.Bitmap;import android.graphics.Canvas;import android.graphics.Color;import android.g...

weixin_39775354的博客 570

mplus 8 用户手册 Chapter18 输出、保存数据和绘图命令.pdf

以下是版本 8 Mplus 用户指南的摘录。第 3 章 - 第 13 章包括 250 多个示例。这些示例还包含在 Mplus DVD 上以及生成数据的相应蒙特卡罗模拟设置中。 第一章:导言 第 2 章:开始使用 Mplus 第 3 章:回归和路径分析视图示例 第四章:探索性因素分析视图示例 第五章:确认因子分析和结构方程建模视图示例 第 6 章:生长建模、生存分析和 N=1 时间序列分析视图示例 第 7 章:具有横截面数据视图示例的混合建模 第 8 章:采用纵向数据视图示例的混合建模 第 9 章:具有复杂调查数据视图示例的多层建模 第10章:多层次混合建模视图示例 第11章:缺少数据建模和贝叶斯估计视图示例 第12章:蒙特卡洛模拟研究查看示例 第13章:示例:特殊功能 第14章:特殊建模问题 第 15 章:标题、数据、变量和定义命令 第16章:分析命令 第17章:MODEL命令 第 18 章:输出、保存数据和绘图命令 第19章:蒙特卡洛命令 第20章:Mplus语言摘要 引用/索引

基于深度学习的图像去雨(Opencv,Pytorch,Cnn)

最近做了一个图像去雨项目,使用的语言为Python,深度学习框架为Pytorch。去雨效果不错,具体请看效果视频!图像去雨(GAN,Opencv,Pytorch)

Czqqwer的博客 2617

深度学习之解决模型不收敛的问题

利用VGG16预训练模型微调网络时,遇到了模型不收敛的问题.记录一下! 第一次训练时参数设置如下: batch_size = 64 lr = 0.00001 n_cls = 8 max_steps =30000 得到的训练集和验证集的loss  和  accuracy 结果如下:         从这四张图中可以明显地看到,模型没有收敛,而且模型的震荡很厉害,所以,...

qq_32571391的博客 2万+

JA4 TLS指纹:反爬攻防下沉至网络层的实战指南

TLS指纹是识别客户端网络栈特征的基础安全概念,其原理源于对TLS 1.3/1.2握手阶段Client Hello明文字段的结构化提取与哈希编码。相比依赖JavaScript执行环境的传统浏览器指纹,TLS指纹具备更高稳定性与更低伪造性,技术价值在于绕过前端混淆、直击爬虫底层网络协议栈。典型应用场景包括电商风控、金融反欺诈及招聘平台数据防护,尤其适用于对抗高仿真无头浏览器与通用HTTP库爬虫。本文聚焦JA4这一工业级TLS指纹标准,深入解析其字段逻辑、Nginx原生集成方案及与JA4S/JA4X的纵深协同机

weixin_33675507的博客 867

面板数据,面板数据的三种基本模型(联合回归模型,变截距模型,变系数模型)

 建立面板数据模型要检验被解释变量的参数和是否对所有个体样本点和时间都是常数,即检验样本数据究竟属于哪一种面板数据模型形式,从而避免模型设定的偏差,改进参数估计的有效性。主要检验如下两个假设:  如果接受假设H2,则可以认为样本数据符合不变截距、不变系数模型。如果拒绝假设H2,则需检验假设H1。如果接受H1,则认为样本数据符合变截距、不变系数模型;反之,则认为样本数据符合变系数模型。...

小蜗牛的博客 5万+

【数字人实战】Windows系统下Fun-CosyVoice3-0.5B-2512本地部署的避坑指南与疑难解析

本文详细介绍了在Windows系统下本地部署Fun-CosyVoice3-0.5B-2512的避坑指南与疑难解析,包括Python环境准备、源码获取、依赖安装、模型下载与WebUI启动等关键步骤。特别针对Windows环境下的常见问题提供了实用解决方案,帮助开发者高效完成部署并充分利用其语音转换与多语言支持功能。

weixin_42521856的博客 377

Python头歌实验题目(2024版)

武汉理工大学头歌平台实验题目

2401_84152595的博客 2万+
上一篇: R数据分析:二分类因变量的混合效应,多水平logistics模型介绍
下一篇: R数据分析:什么是人群归因分数Population Attributable Fraction
评论 4
成就一亿技术人!
拼手气红包6.0元
还能输入1000个字符
 
 条评论被折叠 查看
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付:10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

公众号Codewar原创作者

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付:¥1
获取中
扫码支付

您的余额不足,请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值