关于简易数控床，步进电机X_Y轴移动

本文章想介绍的是x和y轴各两个42步进电机，和两路L298N驱动模块吗，使用Arduino Mega 2560作为主控，至于其他的期间介绍这里不多介绍，接下来简单介绍一下使用的算法：
步进电机移动采用的是：BresenHam 画线算法
算法核心可以参考下面这位博主的：
【计算机图形学】画线算法——Bresenham算法(任意斜率)_bresenham算法原理-优快云博客
接下来废话不多说了，我也要去学习了，直接上代码：
 

#include <SoftwareSerial.h>

const int steps_per_cm = 100; // 每厘米所需的步数，假设每步移动0.01cm
int step_pins_x[4] = {4, 5, 6, 7}; // x轴步进电机接口
int step_pins_y[4] = {8, 9, 10, 11}; // y轴步进电机接口
byte step_sequence[4] = {0x03, 0x06, 0x0c, 0x09}; // 双四拍字表 AB-BC-CD-DA

int pointer_x = 0, pointer_y = 0;
double x = 0, y = 0; // 当前坐标
double target_x = 0, target_y = 0; // 目标坐标

SoftwareSerial bluetooth(12, 13); // RX, TX

void setup() {
  Serial.begin(9600);
  bluetooth.begin(9600);
  for (int i = 0; i < 4; i++) {
    pinMode(step_pins_x[i], OUTPUT);
    pinMode(step_pins_y[i], OUTPUT);
  }
}

void loop() {
  if (bluetooth.available()) {
    String input = bluetooth.readStringUntil('\n'); // 读取一行数据
    parseInput(input); // 解析坐标
    move_to(target_x, target_y); // 移动到目标坐标
  }
  if(Serial.available()){
    String input = Serial.readStringUntil('\n'); // 读取一行数据
    parseInput(input); // 解析坐标
    move_to(target_x, target_y); // 移动到目标坐标
  }
}

void move_to(double x_target, double y_target) {
  double delta_x = x_target - x;
  double delta_y = y_target - y;
  int steps_x = abs(delta_x) * steps_per_cm;
  int steps_y = abs(delta_y) * steps_per_cm;
  
  int x0 = x * steps_per_cm;
  int y0 = y * steps_per_cm;
  int x1 = x_target * steps_per_cm;
  int y1 = y_target * steps_per_cm;
  int dx = abs(x1 - x0);
  int dy = abs(y1 - y0);
  int sx = x0 < x1 ? 1 : -1;
  int sy = y0 < y1 ? 1 : -1;
  int err = dx - dy;

  while (x0 != x1 || y0 != y1) {
    int e2 = err * 2;
    if (e2 > -dy) {
      err -= dy;
      x0 += sx;
      move_step_x(sx);
    }
    if (e2 < dx) {
      err += dx;
      y0 += sy;
      move_step_y(sy);
    }
    delay(3); // 控制步进电机速度
  }

  // 更新当前位置
  x = x_target;
  y = y_target;
  Serial.print("Moved to: ");
  Serial.print(x);
  Serial.print(", ");
  Serial.println(y);
}

void move_step_x(int direction) {
  pointer_x = (pointer_x + direction + 4) % 4;
  for (int i = 0; i < 4; i++) {
    digitalWrite(step_pins_x[i], bitRead(step_sequence[pointer_x], 3 - i));
  }
}

void move_step_y(int direction) {
  pointer_y = (pointer_y + direction + 4) % 4;
  for (int i = 0; i < 4; i++) {
    digitalWrite(step_pins_y[i], bitRead(step_sequence[pointer_y], 3 - i));
  }
}

void parseInput(String input) {
  // 移除括号
  // input.remove(0, 1); // 移除开头的'('
  // input.remove(input.length() - 1, 1); // 移除结尾的')'

  // 查找逗号的位置
  int commaIndex = input.indexOf(',');
  Serial.println(commaIndex);
  // 检查逗号是否找到
  if (commaIndex == -1) {
    Serial.println("输入错误");
    return;
  }

  // 分割字符串
  String xStr = input.substring(0, commaIndex);
  String yStr = input.substring(commaIndex + 1);

  // 转换为数字
  target_x = xStr.toDouble();
  target_y = yStr.toDouble();

  Serial.print("Parsed target coordinates: ");
  Serial.print(target_x);
  Serial.print(", ");
  Serial.println(target_y);
}