oracle数据库用自定义函数导出数据为文件

最新推荐文章于 2024-08-15 11:27:44 发布

每日一禅

最新推荐文章于 2024-08-15 11:27:44 发布

阅读量719

点赞数

CC 4.0 BY-SA版权

本文链接：https://blog.youkuaiyun.com/qq_41688733/article/details/90109245

本文介绍了一个Oracle数据库中用于将查询结果导出为CSV格式文件的PL/SQL函数dump_csv。该函数接受SQL查询语句、分隔符、目录及文件名作为参数，通过解析SQL语句并执行查询，将结果逐行写入指定目录下的CSV文件中。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

create or replace function dump_csv( p_query     in varchar2,
                                      p_separator in varchar2
                                                    default ',',
                                      p_dir       in varchar2 ,
                                      p_filename  in varchar2 )
return number
AUTHID CURRENT_USER
is
    l_output        utl_file.file_type;
    l_theCursor     integer default dbms_sql.open_cursor;
    l_columnValue   varchar2(2000);
    l_status        integer;
    l_colCnt        number default 0;
    l_separator     varchar2(10) default '';
    l_cnt           number default 0;
begin
    l_output := utl_file.fopen( p_dir, p_filename, 'w',32767);

    dbms_sql.parse(  l_theCursor,  p_query, dbms_sql.native );

    for i in 1 .. 255 loop
        begin
            dbms_sql.define_column( l_theCursor, i,
                                    l_columnValue, 2000 );
            l_colCnt := i;
        exception
            when others then
                if ( sqlcode = -1007 ) then exit;
                else
                    raise;
                end if;
        end;
    end loop;

    dbms_sql.define_column( l_theCursor, 1, l_columnValue,
                            2000 );

    l_status := dbms_sql.execute(l_theCursor);

    loop
        exit when ( dbms_sql.fetch_rows(l_theCursor) <= 0 );
        l_separator := '';
        for i in 1 .. l_colCnt loop
            dbms_sql.column_value( l_theCursor, i,
                                   l_columnValue );
            utl_file.put( l_output, l_separator ||
                                    l_columnValue );
            l_separator := p_separator;
        end loop;
        utl_file.new_line( l_output );
        l_cnt := l_cnt+1;
    end loop;
    dbms_sql.close_cursor(l_theCursor);

    utl_file.fclose( l_output );
    return l_cnt;
end dump_csv;

用法：

select dump_csv(‘sql_text’,‘分隔符’,‘oracle directory’,‘输出的文件名’) from dual;
例子：
select dump_csv(‘select substr(msisdn,3,11),mo_content,to_char(mo_creat_date,’‘yyyy/mm/dd hh24:mi:ss’’),province
from t_mo_message a,t_blwx_mdn b
where substr(a.msisdn,3,7)=b.segment
and mo_content in (’‘SLB5’’,’‘SZY5’’,’‘SCK5’’,’‘SHQ5’’)
and to_char(mo_creat_date,’‘yyyymmdd’’)=’‘20190422’’’,’,’,‘AA’,‘blwx0423.txt’) from dual;