判断FTP文件夹是否存在并自动上传本地文件。

最近由于公司需要上午某个时间下午某个时间把文件夹里的内容上传到ftp的文件夹里手工上传有些墨迹就想写个脚本顺便学习下
1：把本地的一个固定文件夹的内容上传到FTP某个文件夹的2018XXXX文件夹内
2：如果没有这个文件夹就创建
3：上传文件至2018XXXX
由于我用的是windows操作系统 就想到了批处理 判断ftp下文件夹是否存在现在只想到获取到ftp目录下的文件列表名，然后用for语句 匹配2018XXXX （如果有更好的方法欢迎留言）再重新连接FTP并上传文件。
代码如下

@echo off&&setlocal enabledelayedexpansion
set dirname=%date:~0,4%%date:~5,2%%date:~8,2%
set "a=0"
set ftpname=autoftp.cfg
set ip=192.168.1.1
set user=test
set passwd=test
set inputpath=/
set lpath=D:\test
echo open !ip!>%ftpname%
echo !user!>>%ftpname%
echo !passwd!>>%ftpname%
echo cd !inputpath!>>%ftpname%
echo dir>>%ftpname%
echo quit>>%ftpname%
ftp -s:"%ftpname%">ftp.log
echo 第一次获取目录名称结束
echo ==============开始判断文件夹是否存在===========
for /f "delims=" %%i in (ftp.log) do (
set "filename=%%i"
set "b=!filename:~-9,8!"
if "!dirname!"=="!b!" (set a=1) 
)
if "!a!"=="1" (
echo open !ip!>%ftpname%
echo !user!>>%ftpname%
echo !passwd!>>%ftpname%
echo cd !inputpath!>>%ftpname%
echo =============文件夹存在进入该文件夹================
echo cd %dirname%>>%ftpname%
echo lcd !lpath!>>%ftpname%
dir !lpath! /b >putname.txt
for /f "delims=" %%a in (putname.txt) do (
set "putname=%%a"
echo put !putname!>>%ftpname%
)
echo quit>>%ftpname%
echo on
ftp -s:"%ftpname%">ftp.log) else (
echo open !ip!>%ftpname%
echo !user!>>%ftpname%
echo !passwd!>>%ftpname%
echo ===============文件不存在创建并进入该文件夹==================
echo cd !inputpath!>>%ftpname%
echo mkdir %dirname%>>%ftpname%
echo cd %dirname%>>%ftpname%
echo lcd !lpath!>>%ftpname%
dir !lpath! /b >putname.txt
for /f "delims=" %%b in (putname.txt) do (
set "putname=%%b"
echo put !putname!>>%ftpname%
)
echo quit>>%ftpname%
echo on
ftp -s:"%ftpname%">ftp.log
)
echo 上传完成
start ftp.log
pause
exit

使用说明：
1：根据需要设置ip user passwd inputpath lpath 变量
2：创建的文件夹格式为 xxxxxxxx “如：20181120”
3：判断文件名的变量是set “b=!filename:~-9,8!” 可根据需要修改匹配文件名（xxxxxxxx固定日期格式）可参考字符截取*https://blog.youkuaiyun.com/xcntime/article/details/51690874
4：有的FTP不支持mput 所以用了dir /b 获取本地文件名再put上传。
4：传输的过程可在log日志中查看
5：传输的过程显示还研究欢迎大佬留言。
6：有关于 FTP上文件夹的判断，有更好方式欢迎留言。