2D Player脚本

extends Area2D

signal hit # 声明一个名为hit的信号

@export var speed = 400 # 角色移动速度
var screen_size # 游戏窗口尺寸

func _ready():
    screen_size = get_viewport_rect().size
    hide() # 游戏开始隐藏角色

func _process(delta):
    var velocity = Vector2.ZERO # 角色的移动向量
    if Input.is_action_pressed("move_right"):
        velocity.x += 1
    if Input.is_action_pressed("move_left"):
        velocity.x -= 1
    if Input.is_action_pressed("move_down"):
        velocity.y += 1
    if Input.is_action_pressed("move_up"):
        velocity.y -= 1
    
    if velocity.length() > 0:
        velocity = velocity.normalized() * speed
        $AnimatedSprite2D.play()
    else:
        $AnimatedSprite2D.stop()
    
    position += velocity * delta
    position.x = clamp(position.x, 0, screen_size.x)
    position.y = clamp(position.y, 0, screen_size.y)
    
    if velocity.x != 0:
        $AnimatedSprite2D.animation = "walk"
        $AnimatedSprite2D.flip_v = false
        $AnimatedSprite2D.flip_h = velocity.x < 0
    elif velocity.y != 0:
        $AnimatedSprite2D.animation = "up"
        $AnimatedSprite2D.flip_v = velocity.y > 0
        


func _on_body_entered(body):
    hide() # 被击中时隐藏Player
    hit.emit()
    $CollisionShape2D.set_deferred("disabled", true) # 被击中后禁用碰撞
    
func start(pos):
    position = pos
    show()
    $CollisionShape2D.disabled = false