ASP学习笔记二

最新推荐文章于 2018-08-01 14:37:15 发布
最新推荐文章于 2018-08-01 14:37:15 发布
阅读量979 收藏 1
点赞数
分类专栏： Web 文章标签： asp
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.youkuaiyun.com/llwszjj/article/details/17040645
版权

ASP Cookie

什么是 Cookie?

cookie 常用来对用户进行识别。cookie 是一种服务器留在用户电脑中的小文件。每当同一台电脑通过浏览器请求页面时，这台电脑也会发送 cookie。通过 ASP，您能够创建并取回 cookie 的值。

如何创建 cookie?

"Response.Cookies" 命令用于创建 cookie。

注意：Response.Cookies 命令必须位于 <html> 标签之前。

在下面的例子中，我们会创建一个名为 "firstname" 的 cookie，并向其赋值 "Alex"：

<%
Response.Cookies("firstname")="Alex"
%>

向 cookie 分配属性也是可以的，比如设置 cookie 的失效时间：

<%
Response.Cookies("firstname")="Alex" 
Response.Cookies("firstname").Expires=#May 10,2020#
%>

如何取回 cookie 的值？

"Request.Cookies" 命令用于取回 cookie 的值。

在下面的例子中，我们取回了名为 "firstname" 的 cookie 的值，并把值显示到了页面上：

<%
fname=Request.Cookies("firstname")
response.write("Firstname=" & fname)
%>

输出：

Firstname=Alex

带有键的 cookie

如果一个 cookie 包含多个值的一个集合，我们就可以说 cookie 拥有键（Keys）。

在下面的例子中，我们会创建一个名为 "user" 的 cookie 集。"user" cookie 拥有包含用户信息的键：

<%
Response.Cookies("user")("firstname")="John"
Response.Cookies("user")("lastname")="Adams"
Response.Cookies("user")("country")="UK"
Response.Cookies("user")("age")="25"
%>

读取所有的 cookie

请阅读下面的代码：

<%
Response.Cookies("firstname")="Alex"
Response.Cookies("user")("firstname")="John"
Response.Cookies("user")("lastname")="Adams"
Response.Cookies("user")("country")="UK"
Response.Cookies("user")("age")="25"
%>

假设您的服务器将所有的这些 cookie 传给了某个用户。

现在，我们需要读取这些 cookie。下面的例子向您展示如何做到这一点（请注意，下面的代码会使用 HasKeys 检查 cookie 是否拥有键）：

<html>
<body>

<%
dim x,y

 for each x in Request.Cookies
  response.write("<p>")
  if Request.Cookies(x).HasKeys then
    for each y in Request.Cookies(x)
      response.write(x & ":" & y & "=" & Request.Cookies(x)(y))
      response.write("<br />")
    next
  else
    Response.Write(x & "=" & Request.Cookies(x) & "<br />")
  end if
  response.write "</p>"
next
%>

</body>
</html>

输出：

firstname=Alex

user:firstname=John
user:lastname=Adams
user:country=UK
user:age=25

如何应对不支持 cookie 的浏览器？

如果您的应用程序需要和不支持 cookie 的浏览器打交道，那么您不得不使用其他的办法在您的应用程序中的页面之间传递信息。这里有两种办法：

1. 向 URL 添加参数

您可以向 URL 添加参数：

<a href="welcome.asp?fname=John&lname=Adams">
Go to Welcome Page
</a>

然后在类似于下面这个 "welcome.asp" 文件中取回这些值：

<%
fname=Request.querystring("fname")
lname=Request.querystring("lname")
response.write("<p>Hello " & fname & " " & lname & "!</p>")
response.write("<p>Welcome to my Web site!</p>")
%>

2. 使用表单

您还可以使用表单。当用户点击提交按钮时，表单会把用户输入的数据提交给 "welcome.asp" ：

<form method="post" action="welcome.asp">
First Name:  <input type="text" name="fname" value="">
Last Name: <input type="text" name="lname" value="">
<input type="submit" value="Submit">
</form>

然后在 "welcome.asp" 文件中取回这些值，就像这样：

<%
fname=Request.form("fname")
lname=Request.form("lname")
response.write("<p>Hello " & fname & " " & lname & "!</p>")
response.write("<p>Welcome to my Web site!</p>")
%>

ASP Session 对象

Session 对象用于存储用户的信息。存储于 session 对象中的变量持有单一用户的信息，并且对于一个应用程序中的所有页面都是可用的。

Session 对象

当您操作某个应用程序时，您打开它，做些改变，然后将它关闭。这很像一次对话（Session）。计算机知道您是谁。它清楚您在何时打开和关闭应用程序。但是在因特网上有一个问题：由于 HTTP 地址无法存留状态，web 服务器并不知道您是谁以及您做了什么。

ASP 通过为每位用户创建一个唯一的 cookie 的方式解决了这个问题。cookie 被传送至客户端，它含有可识别用户的信息。这种接口被称作 Session 对象。

Session 对象用于存储关于用户的信息，或者为一个用户的 session 更改设置。存储于 session 对象中的变量存有单一用户的信息，并且对于应用程序中的所有页面都是可用的。存储于 session 对象中的信息通常是 name、id 以及参数。服务器会为每个新的用户创建一个新的 Session，并在 session 到期时撤销掉这个 Session 对象。

Session 何时开始？

Session 开始于：

  • 当某个新用户请求了一个 ASP 文件，并且 Global.asa 文件引用了 Session_OnStart 子程序时；
  • 当某个值存储在 Session 变量中时；
  • 当某个用户请求了一个 ASP 文件，并且 Global.asa 使用 <object> 标签通过 session 的 scope 来例示某个对象时；

Session 何时结束?

假如用户没有在规定的时间内在应用程序中请求或者刷新页面，session 就会结束。默认值为 20 分钟。

如果您希望将超时的时间间隔设置得更长或更短，可以设置 Timeout 属性。

下面的例子设置了 5 分钟的超时时间间隔：

<%
Session.Timeout=5
%>

要立即结束 session，可使用 Abandon 方法：

<%
Session.Abandon
%>

注意：使用 session 时主要的问题是它们该在何时结束。我们不会知道用户最近的请求是否是最后的请求。因此我们不清楚该让 session“ 存活”多久。为某个空闲的 session 等待太久会耗尽服务器的资源。然而假如 session 被过早地删除，那么用户就不得不一遍又一遍地重新开始，这是因为服务器已经删除了所有的信息。寻找合适的超时间隔时间是很困难的。

提示：如果您正在使用 session 变量，请不要在其中存储大量的数据。

存储和取回 session 变量

Session 对象最大的优点是可在其中存储变量，以供后续的网页读取，其应用范围是很广的。

下面的例子把 "Donald Duck" 赋值给名为 username 的 session 变量，并把 "50" 赋值给名为 age 的 session 变量：

<%
Session("username")="Donald Duck"
Session("age")=50
%>

一旦值被存入 session 变量，它就能被 ASP 应用程序中的任何页面使用：

Welcome <%Response.Write(Session("username"))%>

上面这行程序返回的结果是: "Welcome Donald Duck"。

也可以在 session 对象中保存用户参数，然后通过访问这些参数来决定向用户返回什么页面。

下面的例子规定，假如用户使用低显示器分辨率，则返回纯文本版本的页面：

<%If Session("screenres")="low" Then%> 
  This is the text version of the page
<%Else%> 
  This is the multimedia version of the page
<%End If%>

移除 session 变量

contents 集合包含所有的 session 变量。

可通过 remove 方法来移除 session 变量。

在下面的例子中，假如 session 变量 "age" 的值小于 18，则移除 session 变量 "sale"：

<%
If Session.Contents("age")<18 then 
  Session.Contents.Remove("sale")
End If 
%>

如需移除 session 中的所有变量，请使用 RemoveAll 方法：

<%
Session.Contents.RemoveAll()
%>

遍历 contents 集合

contents 集合包含所有的 session 变量。可通过遍历 contents 集合，来查看其中存储的变量：

<%
Session("username")="Donald Duck"
Session("age")=50

dim i
For Each i in Session.Contents
  Response.Write(i & "<br />")
Next
%>

结果：

username
age

如果需要了解 contents 集合中的项目数量，可使用 count 属性：

<%
dim i
dim j
j=Session.Contents.Count
Response.Write("Session variables: " & j)
For i=1 to j
  Response.Write(Session.Contents(i) & "<br />")
Next
%>

结果：

Session variables: 2
Donald Duck
50

遍历 StaticObjects 集合

可通过循环 StaticObjects 集合，来查看存储在 session 对象中所有对象的值：

<%
dim i
For Each i in Session.StaticObjects
  Response.Write(i & "<br />")
Next
%>

ASP Application 对象


在一起协同工作以完成某项任务的一组 ASP 文件称作应用程序（application）。ASP 中的 Application 对象用于将这些文件捆绑在一起。

Application 对象

web 上的一个应用程序可以是一组 ASP 文件。这些 ASP 文件一起协同工作来完成某项任务。ASP 中的 Application 对象用来把这些文件捆绑在一起。

Application 对象用于存储和访问来自任何页面的变量，类似于 session 对象。不同之处在于，所有的用户分享一个 Application 对象，而 session 对象和用户的关系是一一对应的。

Application 对象存有会被应用程序中的许多页面使用的信息（比如数据库连接信息）。这意味着可以从任何的页面访问这些信息。同时也意味着你可在一个地点改变这些信息，然后这些改变会自动反映在所有的页面上。

存储和取回 Application 变量

Application 变量可被应用程序中的任何页面访问和改变。

可以像这样在 "Global.asa" 中创建 Application 变量：

<script language="vbscript" runat="server">

Sub Application_OnStart
application("vartime")=""
application("users")=1
End Sub

</script>

在上面的例子中，我们创建了两个 Application 变量："vartime" 和 "users"。

可以像这样访问 Application 变量的值：

There are 
<%
Response.Write(Application("users"))
%> 
active connections.

遍历 Contents 集合

Contents 集合包含着所有的 application 变量。我们可以通过对 contents 集合进行遍历，来查看其中存储的变量：

<%
dim i
For Each i in Application.Contents
  Response.Write(i & "<br />")
Next
%>

如果你不清楚 contents 集中的项目数量，可使用 count 属性：

<%
dim i
dim j
j=Application.Contents.Count
For i=1 to j
  Response.Write(Application.Contents(i) & "<br />")
Next
%>

遍历 StaticObjects 集合

可通过循环 StaticObjects 集合，来查看所有存储于 Application 对象中的对象的值：

<%
dim i
For Each i in Application.StaticObjects
  Response.Write(i & "<br />")
Next
%>

锁定和解锁

我们可以使用 "Lock" 方法来锁定应用程序。当应用程序锁定后，用户们就无法改变 Application 变量了（除了正在访问 Application 变量的用户）。我们也可使用 "Unlock" 方法来对应用程序进行解锁。这个方法会移除对 Application 变量的锁定：

<%
Application.Lock
  'do some application object operations
Application.Unlock
%>

ASP 文件引用

#include 指令用于在多重页面上创建需重复使用的函数、页眉、页脚或者其他元素等。

#include 指令

通过使用 #include 指令，我们可以在服务器执行 ASP 文件之前，把另一个ASP文件插入这个文件中。#include 命令用于在多个页面上创建需要重复使用的函数、页眉、页脚或者其他元素等。

如何使用 #include 指令

这里有一个名为 "mypage.asp" 的文件:

<html> 
<body> 
<h2>Words of Wisdom:</h2>
<p><!--#include file="wisdom.inc"--></p> 
<h2>The time is:</h2>
<p><!--#include file="time.inc"--></p>
</body> 
</html>

这是 "wisdom.inc" 文件:

"One should never increase, beyond what is necessary,
the number of entities required to explain anything."

这是 "time.inc" 文件:

<%
Response.Write(Time)
%>

在浏览器中查看的源代码应该类似这样：

<html>
<body>
<h2>Words of Wisdom:</h2>
<p>"One should never increase, beyond what is necessary,
the number of entities required to explain anything."</p>
<h2>The time is:</h2>
<p>11:33:42 AM</p>
</body>
</html>

Including 文件的语法：

如需在 ASP 中引用文件，请把 #include 命令置于注释标签之中：

<!--#include virtual="somefilename"-->

或者：

<!--#include file ="somefilename"-->

关键词 Virtual

关键词 virtual 指示路径以虚拟目录开始。

如果 "header.inc" 文件位于虚拟目录 /html 中，下面这行代码会插入文件 "header.inc" 中的内容：

<!-- #include virtual ="/html/header.inc" -->

关键词 File

关键词 File 指示一个相对的路径。相对路径起始于含有引用文件的目录。

假设文件位于 html 文件夹的子文件夹 headers 中，下面这段代码可引用 "header.inc" 文件的内容：

<!-- #include file ="headers\header.inc" -->

注意：被引用文件的路径是相对于引用文件的。假如包含 #include 声明的文件不在 html 目录中，这个声明就不会起效。

您也可以使用关键词 file 和语法 (..\) 来引用上级目录中的文件。

提示和注释

在上面的一节中，我们使用 ".inc" 来作为被引用文件的后缀。注意：假如用户尝试直接浏览 INC 文件，这个文件中内容就会暴露。假如被引用的文件中的内容涉及机密，那么最好还是使用 "asp" 作为后缀。ASP 文件中的源代码被编译后是不可见的。被引用的文件也可引用其他文件，同时一个 ASP 文件可以对同一个文件引用多次。

重要事项：在脚本执行前，被引用的文件就会被处理和插入。

下面的代码无法执行，这是由于 ASP 会在为变量赋值之前执行 #include 命令：

<%
fname="header.inc"
%>
<!--#include file="<%=fname%>"-->

不能在脚本分隔符之间包含文件引用：

<%
For i = 1 To n
  <!--#include file="count.inc"-->
Next
%>

但是这段脚本可以工作：

<% For i = 1 to n %>
<!--#include file="count.inc" -->
<% Next %>

ASP Global.asa 文件


Global.asa 文件是一个可选的文件，它可包含可被 ASP 应用程序中每个页面访问的对象、变量以及方法的声明。

Global.asa 文件

Global.asa 文件是一个可选的文件，它可包含可被 ASP 应用程序中每个页面访问的对象、变量以及方法的声明。所有合法的浏览器脚本都能在 Global.asa 中使用。

Global.asa 文件可包含下列内容：

  • Application 事件
  • Session 事件
  • <object> 声明
  • TypeLibrary 声明
  • #include 指令

注释：Global.asa 文件须存放于 ASP 应用程序的根目录中，且每个应用程序只能有一个 Global.asa 文件。

Global.asa 中的事件

在 Global.asa 中，我们可以告知 application 和 session 对象在启动和结束时做什么事情。完成这项任务的代码被放置在事件操作器中。Global.asa 文件能包含四种类型的事件：

Application_OnStart - 此事件会在首位用户从 ASP 应用程序调用第一个页面时发生。此事件会在 web 服务器重起或者 Global.asa 文件被编辑之后发生。"Session_OnStart" 事件会在此事件发生之后立即发生。

Session_OnStart - 此事件会在每当新用户请求他或她的在 ASP 应用程序中的首个页面时发生。

Session_OnEnd - 此事件会在每当用户结束 session 时发生。在规定的时间（默认的事件为 20 分钟）内如果没有页面被请求，session 就会结束。

Application_OnEnd - 此事件会在最后一位用户结束其 session 之后发生。典型的情况是，此事件会在 Web 服务器停止时发生。此子程序用于在应用程序停止后清除设置，比如删除记录或者向文本文件写信息。

Global.asa 文件可能类似这样：

<script language="vbscript" runat="server">

sub Application_OnStart
  'some code
end sub

sub Application_OnEnd
  'some code
end sub

sub Session_OnStart
  'some code
end sub

sub Session_OnEnd
  'some code
end sub

</script>

注释：由于无法使用 ASP 的脚本分隔符 (<% 和 %>) 在 Global.asa 文件中插入脚本，我们需使用 HTML 的 <script> 元素。

<object> 声明

可通过使用 <object> 标签在 Global.asa 文件中创建带有 session 或者 application 作用域的对象。

注释：<object> 标签应位于 <script> 标签之外。

语法：

<object runat="server" scope="scope" id="id"
{progid="progID"|classid="classID"}>
....
</object>
参数 描述
scope 设置对象的作用域（作用范围）（Session 或者 Application）。
id 为对象指定一个唯一的 id。
ProgID

与 ClassID 关联的 id。ProgID 的格式是：[Vendor.]Component[.Version]。

ProgID 或 ClassID 必需被指定。

ClassID

为 COM 类对象指定唯一的 id。

ProgID 或 ClassID 必需被指定。

实例

第一个实例创建了一个名为 "MyAd" 且使用 ProgID 参数的 session 作用域对象：

<object runat="server" scope="session" id="MyAd" progid="MSWC.AdRotator">
</object>

第二个实例创建了名为 "MyConnection" 且使用 ClassID 参数的

<object runat="server" scope="application" id="MyConnection"
classid="Clsid:8AD3067A-B3FC-11CF-A560-00A0C9081C21">
</object>

在此 Global.asa 文件中声明的这些对象可被应用程序中的任何脚本使用。

GLOBAL.ASA:

<object runat="server" scope="session" id="MyAd" progid="MSWC.AdRotator">
</object>

您可以从 ASP 应用程序中的任意页面引用此 "MyAd" 对象：

某个 .ASP 文件:

<%=MyAd.GetAdvertisement("/banners/adrot.txt")%> 

TypeLibrary 声明

TypeLibrary （类型库）是一个容器，其中装有对应于 COM 对象的 DLL 文件。通过在 Global.asa 中包含对 TypeLibrary 的调用，可以访问 COM 对象的常量，同时 ASP 代码也能更好地报告错误。假如您的站点的应用程序依赖于已在类型库中声明过数据类型的 COM 对象，您可以在 Global.asa 中对类型库进行声明。

语法：

<!--METADATA TYPE="TypeLib"
file="filename"
uuid="typelibraryuuid"
version="versionnumber"
lcid="localeid"
-->
参数 描述
file 规定指向类型库的绝对路径。参数 file 或者 uuid，两者缺一不可。
uuid 规定了针对类型库的唯一的标识符。参数 file 或者 uuid，两者缺一不可。
version 可选。用于选择版本。假如没有找到指定的版本，将使用最接近的版本。
lcid 可选。用于类型库的地区标识符。

错误值

服务器会返回以下的错误消息之一：

错误 代码 描述
ASP 0222 Invalid type library specification
ASP 0223 Type library not found
ASP 0224 Type library cannot be loaded
ASP 0225 Type library cannot be wrapped

注释：METADATA 标签可位于 Global.asa 文件中的任何位置（在 <script> 标签的内外均可）。不过，我们还是推荐将 METADATA 标签放置于 Global.asa 文件的顶部。

限定

关于可以在 Global.asa 文件中引用的内容的限定：

你无法显示 Global.asa 文件中的文本。此文件无法显示信息。

你只能在 Application_OnStart 和 Application_OnEnd 子例程中使用 Server 和 Application 对象。在 Session_OnEnd 子例程中，你可以使用 Server、Application 和 Session 对象。在 Session_OnStart 子例程中，你可使用任何内建的对象。

如何使用子例程

Global.asa 常用于对变量进行初始化。

下面的例子展示如何检测访问者首次到达站点的确切时间。时间存储在名为 "started" 的 Session 对象中，并且 "started" 变量的值可被应用程序中的任何 ASP 页面访问：

<script language="vbscript" runat="server">
sub Session_OnStart
Session("started")=now()
end sub
</script>

Global.asa 也可用于控制页面访问。

下面的例子展示如何把每位新的访问者重定向到另一个页面，在这个例子中会定向到 "newpage.asp" 这个页面：

<script language="vbscript" runat="server">
sub Session_OnStart
Response.Redirect("newpage.asp")
end sub
</script>

我们还可以在 Global.asa 中包含函数。

在下面的例子中，当 Web 服务器启动时，Application_OnStart 子例程也会启动。随后，Application_OnStart 子例程会调用另一个名为 "getcustomers" 的子例程。"getcustomers" 子例程会打开一个数据库，然后从 "customers" 表中取回一个记录集。此记录集会赋值给一个数组，在不查询数据库的情况下，任何 ASP 页面都能够访问这个数组：

<script language="vbscript" runat="server">

sub Application_OnStart
getcustomers
end sub

sub getcustomers 
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs=conn.execute("select name from customers")
Application("customers")=rs.GetRows
rs.Close
conn.Close
end sub

</script>

Global.asa 实例

在这个例子中，我们要创建一个可计算当前访客的 Global.asa 文件。

Application_OnStart 设置当服务器启动时，Application 变量 "visitors" 的值为 0。

每当有新用户访问时，Session_OnStart 子例程就会给变量 "visitors" 加 1。

每当 Session_OnEnd 子例程被触发时，此子例程就会从变量 "visitors" 减 1。

Global.asa 文件：

<script language="vbscript" runat="server">

Sub Application_OnStart
Application("visitors")=0
End Sub

Sub Session_OnStart
Application.Lock
Application("visitors")=Application("visitors")+1
Application.UnLock
End Sub

Sub Session_OnEnd
Application.Lock
Application("visitors")=Application("visitors")-1
Application.UnLock
End Sub

</script>

此 ASP 文件会显示当前用户的数目：

<html>
<head>
</head>
<body>
<p>There are <%response.write(Application("visitors"))%> online now!</p>
</body>
</html>

ASP学习的笔记
09-14
个人学习ASP时，记录的笔记，觉得比较有用
值得收藏的asp.net基础学习笔记
10-21
2. ASP.NET 的工作原理 ASP.NET 提供了一种在服务器端运行的动态网页技术。开发者可以使用 C#、VB.NET 等语言编写 .NET 代码，这些代码在服务器上运行并动态生成 HTML，然后发送给浏览器。值得注意的是，大部分复杂...
ASP学习笔记
wangfuli217的专栏
05-08 832
1、Application对象：可以使用Application使给定应用程序的所有用户共享信息。负责存储数据以供多个用户使用。2、Server对象：提供对服务器上的方法和属性进行访问，最常见的方法是创建ActiveX组件的实例(Server.CreateObject()).即：负责控制ASP的运行环境。3、Request对象：访问任何使用HTTP请求传递的信息：（1）post和get方法传递的参数
Asp.Net基础 概述
anyuzuo4911的博客
03-08 307
1.概论 浏览器-服务器 B/S 浏览的 浏览器和服务器之间的交互,形成上网B/S模式 对于HTML传到服务器 交给服务器软件(IIS) 服务器软件直接读取静态页面代码,然后返回浏览器 对于ASPX传达服务器 交给服务器软件(IIS) IIS发现自己处理不了aspx的文件,就去映射表根据后缀名里找到响应的处理程序(isapi,服务器扩展...
asp-net学习笔记.pdf
11-17
asp-net学习笔记.pdf
ASP.NET学习大总结+笔记
10-06
这份“ASP.NET学习大总结+笔记”涵盖了从基础概念到高级特性的全面知识，是学习和巩固ASP.NET技术的宝贵资料。 一、ASP.NET简介 ASP.NET是服务器端的编程模型，它允许开发人员使用多种编程语言（如C#、VB.NET）创建...
ASP.NET MVC学习笔记
10-29
ASP.NET MVC 1.0发布有段儿时间了，刚发布不久的时候试用了一下，做了一个简单的BBS，现在总结一些经验和小技巧和大家分享。
ASP学习笔记(平时整理的)
06-05
ASP学习笔记(平时整理的)!!!!绝对有用啊@@!!!
ASP 学习笔记
一个IT菜鸟的自白
11-19 1135
ASP 文件可包含文本、 HTML 标签和脚本。ASP 文件中的脚本可在服务器上执行。 在学习之前，应具备的知识： 在继续学习之前，您需要对以下知识有基本的了解： ·       HTML / XHTML ·       脚本语言，比如 JavaScript 或者 VBScript 如果希望学习上面的项目，请在我们的 首页 访问这些教程。 ASP 是什么？ ·       ASP
asp学习笔记
小石头的专栏
03-16 1190
adrotator控件可以快速的实现广告发布功能把代码里的关于adrotator的代码改成其中ads.xml是图片属性文件，内容如下   ~/index_logo.gif  http://www.sohu.com  sohu  Computers  80    ~/sina_logo2.gif  http://www.sina.com  sina  Computers  8
ASP 学习笔记整理
fushaoping2008的博客
08-01 548
在看高手写的asp代码中看到asp代码用with来表示对象,其asp结构形式 with …End with. 代码如下: &lt;% sql = “select * from table” set rs = server.createObject(“adodb.recordset”) with rs .open sql,foraspcn,1,1 if .eof or .bof the...
C#学习笔记：Winform与ASP.NET核心概念解析
"C# Winform 和 Asp.Net 学习笔记" 这篇学习笔记主要涵盖了C#编程语言在Winform和Asp.Net应用中的关键概念和技术。以下是对这些知识点的详细解释： 1. **Webcasts**: Webcasts是在线的音频或视频广播，可能是指...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值