window系统启动、关闭、重启nginx服务

Nginx启动命令（傻瓜式CMD界面）

一、启动界面如下：

二、具体脚本如下：

@ECHO OFF
SET NGINX_PATH=E:
SET NGINX_DIR=E:\Software Tools\nginx-1.18.0\
chcp 65001
cls
:menu
ECHO. ***************************************************************************
ECHO. ***************************************************************************
ECHO. *************************** nginx 进程list ********************************
tasklist|findstr /i "nginx.exe"
ECHO.
ECHO. * * * * * * * * *     Nginx 管理程序    * * * * * * * * *
ECHO. *                                                                         *
ECHO. *        1: 启动Nginx   2: 关闭Nginx   3: 重启Nginx   4: 退 出 BAT        *
ECHO. *                                                                         *
ECHO. * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 
ECHO. ***************************************************************************
ECHO. ***************************************************************************
ECHO.

ECHO.请输入下一步操作的序号：
set /p ID=
	IF "%id%"=="1" GOTO start
	IF "%id%"=="2" GOTO stop
	IF "%id%"=="3" GOTO restart
	IF "%id%"=="4" EXIT
PAUSE
:start
	call :startNginx
	GOTO menu
:stop
	call :shutdownNginx
	GOTO menu
:restart
	call :shutdownNginx
	call :startNginx
	GOTO menu

:startNginx
    ECHO. 
    IF NOT EXIST "%NGINX_DIR%nginx.exe" ECHO "%NGINX_DIR%nginx.exe"不存在 
 
    %NGINX_PATH% 
 
    cd "%NGINX_DIR%" 
 
    IF EXIST "%NGINX_DIR%nginx.exe" (
        start "" nginx.exe
    )
    ECHO.启动Nginx成功，运行中...
    goto :eof 
	
:shutdownNginx
    ECHO. 
    taskkill /F /IM nginx.exe > nul
    ECHO.已关闭所有 nginx 进程
    goto :eof

三、修改NGINX_PATH和NGINX_DIR目录

NGINX_PATH：当前所在盘符，如：E：
NGINX_DIR：nginx具体安装路径，如：E:\Software Tools\nginx-1.18.0\