字幕换色

按下Esc，字幕换色，其实是玩的9h中断的把戏，不过功底不深，我看来是仅仅在原来的int9中断的基础上画蛇添足了一笔:

 

assume cs:codesg,ss:stacksg

stacksg segment
    db 128 dup (0)
stacksg ends

codesg segment
main:        mov ax,stacksg
        mov ss,ax
        mov sp,128

        push cs
        pop ds
        mov ax,0
        mov es,ax
        mov si,offset int9
        mov di,204h
        mov cx,offset int9_end-offset int9
        cld
        rep movsb
        
        ;把9号中断向量保存起来，注意这里借助栈 替代了寄存器
        push es:[9*4]
        pop es:[200h]
        push es:[9*4+2]
        pop es:[202h]

        cli            ;这里在设置新的中断向量，中途不允许cpu处理其他中断
        mov word ptr es:[9*4],204h        ;所以这里提供if=0  类似线程的锁？
        mov word ptr es:[9*4+2],0
        sti

        mov ax,4c00H
        int 21H

int9:        push ax
        push bx
        push cx
        push es

        in al,60h
        pushf
        call dword ptr cs:[200h]        ;揭露出call的实质，如call proc 其实是把offset proc的地址加载入cs:IP

        cmp al,1
        jne int9_ret
        mov ax,0b800H
        mov es,ax
        mov bx,1
        mov cx,2000
int9_s:        inc byte ptr es:[bx]
        add bx,2
        loop int9_s

int9_ret:                         pop es
        pop cx
        pop bx
        pop ax
        iret
int9_end:                         nop

codesg ends
end main

 有几个要点:

1.在设置新的中断向量过程中，很有可能这个时候发生了9h中断，这样就会call int9中断程序，现在问题是新的中断程序地址还没有设置完成，比如才刚刚设置偏移地址，正准备设置段地址时候，突发中断，调用中断程序，但是在新的中断向量表中IP是新地址，CS是旧地址，这样程序肯定出错。所以我们要用cli屏蔽掉其他的中断信息。

2.这段程序不可能进行调试，原因也基于上，当进入到设置新中断向量表时，这个时候第一步设置cli，第二步设置偏移地址，此时按下t 做下一步单步调试，按下t后产生了中断，调用int9中断程序，但此时我们才设置了偏移地址，那么在中断向量表中获取的中断程序仅仅是偏移地址是正确的，段地址错误，引发程序错误。

3.屏幕显示问题。在win32下，屏幕显示可能有问题，比如无法显示等等，最好用command命令执行程序，而不要用cmd。另外这里面也牵涉到一个问题，上面的程序我后来细看发现对中断向量表修改后，程序并没有改回来，到下次重新打开一个command窗口后发现中断向量表又改回来了。后来细想，不知是不是windows提供的dos虚拟环境的缘故。

3.注意call调用实质，以及int中断实质，见注释