ASP中实现的类似URLEncode的编码函数及对应解码函数

最新推荐文章于 2024-03-15 11:21:00 发布

lg_lin

最新推荐文章于 2024-03-15 11:21:00 发布

阅读量1.1k

点赞数

分类专栏： asp 文章标签： asp function hex

asp 专栏收录该内容

81 篇文章

订阅专栏

本文介绍了一种在ASP环境中实现的URL编码和解码函数，通过这些函数可以将特殊字符转换为适用于URL的形式，并能将其还原。编码函数会检查每个字符，将特定字符替换为百分号加上其十六进制ASCII值。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

ASP中实现的类似URLEncode的编码函数及对应解码函数

<%
'Coding.inc.asp

Function Encode(Str)
Dim Count, Pos, Ch, Code
Dim SweetCh

'SweetCh中表示不需要进行编码的字符
SweetCh = "ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789abcdefghijklmnopqrstuvwxyz_{}[]()"
Encode = ""

Count = Len(Str)
Pos = 1
Do While Pos<=Count
  Ch = Mid(Str, Pos, 1)

  Code = Asc(Ch)
  If Code>=0 And Code<256 Then  '汉字不予处理
   If Ch<>"%" Then
    If InStr(SweetCh, Ch)=0 Then
     Ch = "%" & Right("0" & Hex(Code), 2)
    End If
   Else
    Ch = "%25"
   End If
  End If

  Encode = Encode & Ch
  Pos = Pos + 1
Loop
End Function

Function Decode(Str)
Dim Count, Pos, Ch, Code

Decode = ""

Count = Len(Str)
Pos = 1
Do While Pos<=Count
  Ch = Mid(Str, Pos, 1)
  If Ch="%" Then
   If Pos+2<=Count Then
    Ch = Chr((InStr("0123456789ABCDEF", UCase(Mid(Str, Pos+1, 1)))-1) * 16 + InStr("0123456789ABCDEF",UCase(Mid(Str, Pos+2, 1))) - 1)
   Else
    '编码串不正确
    Ch = ""
   End If
   Pos = Pos + 2
  End If
  Decode = Decode & Ch
  Pos = Pos + 1
Loop
End Function
%>