flex 读条

最新推荐文章于 2024-06-12 11:38:23 发布

原创最新推荐文章于 2024-06-12 11:38:23 发布 · 426 阅读

0 ·

CC 4.0 BY-SA版权

富客户端专栏收录该内容

2 篇文章

订阅专栏

本文介绍了一种在Flash中实现自定义加载进度条的方法。通过重写预加载器并监听加载事件，可以在加载过程中显示进度信息。代码示例展示了如何加载外部SWF文件并实时更新文本字段中的加载进度。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

mxml

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
			   xmlns:s="library://ns.adobe.com/flex/spark"
			   xmlns:mx="library://ns.adobe.com/flex/mx"
			   width="1000" height="800" minWidth="1000" minHeight="800" initialize="init()"
			   preloader="LoadingProgressBar">

LoadingProgressBar.as

package  
{    
	import flash.display.*;
	import flash.events.*;
	import flash.net.*;
	import flash.text.TextField;
	import flash.text.TextFormat;
	
	import mx.events.FlexEvent;
	import mx.preloaders.DownloadProgressBar;    
	public class LoadingProgressBar extends DownloadProgressBar    
	{    
		private var logo:Loader;    
		private var txt:TextField;    
		private var _preloader:Sprite;    
		public function LoadingProgressBar()    
		{    
			logo = new Loader();    
			logo.load(new URLRequest("assets/swf/loading.swf"));  
			addChild(logo);    
			var style:TextFormat = new TextFormat(null,null,0xFFFFFF,null,null,null,null,null,"center");    
			txt = new TextField();    
			txt.defaultTextFormat = style;    
			txt.width = 200;    
			txt.selectable = false;    
			txt.height = 20;    
			addChild(txt);    
			super();    
		}    
		//最重要的代码就在这里..重写preloader,让swf执行加载的时候~进行你希望的操作~     
		override public function set preloader(value:Sprite):void  
		{    
			_preloader = value    
			//四个侦听~分别是 加载进度 / 加载完毕 / 初始化进度 / 初始化完毕     
			_preloader.addEventListener(ProgressEvent.PROGRESS,load_progress);    
			_preloader.addEventListener(Event.COMPLETE,load_complete);    
			_preloader.addEventListener(FlexEvent.INIT_PROGRESS,init_progress);    
			_preloader.addEventListener(FlexEvent.INIT_COMPLETE,init_complete);    
			stage.addEventListener(Event.RESIZE,resize);    
			resize(null);    
		}    
		private function remove():void{    
			_preloader.removeEventListener(ProgressEvent.PROGRESS,load_progress);    
			_preloader.removeEventListener(Event.COMPLETE,load_complete);    
			_preloader.removeEventListener(FlexEvent.INIT_PROGRESS,init_progress);    
			_preloader.removeEventListener(FlexEvent.INIT_COMPLETE,init_complete);    
			stage.removeEventListener(Event.RESIZE,resize);    
		}    
		private function resize(e:Event):void{
			logo.x=0;
			logo.y=0;
			txt.x = (stage.stageWidth - 200)/2;    
			txt.y = logo.y + 40+5;    
			graphics.clear();    
			graphics.beginFill(0x333333);    
			graphics.drawRect(0,0,stage.stageWidth,stage.stageHeight);    
			graphics.endFill();    
		}    
		private function load_progress(e:ProgressEvent):void{    
			txt.text = "正在加载..."+int(e.bytesLoaded/e.bytesTotal*100)+"%";    
		}    
		private function load_complete(e:Event):void{    
			txt.text = "加载完毕!";
		}    
		private function init_progress(e:FlexEvent):void{    
			txt.text = "正在初始化...";  
		}    
		private function init_complete(e:FlexEvent):void{    
			txt.text = "初始化完毕!";  
			remove();  
			//最后这个地方需要dpe一个Event.COMPLETE事件..表示加载完毕让swf继续操作~     
			dispatchEvent(new Event(Event.COMPLETE));    
		}    
	}    
}