bat——实现电脑开机自动登录解锁屏

最新推荐文章于 2025-02-20 16:51:54 发布

多喝奶茶嗷

最新推荐文章于 2025-02-20 16:51:54 发布

阅读量1k

点赞数 12

文章标签： git

本文链接：https://blog.youkuaiyun.com/jin719/article/details/145214251

版权

一、常用语法

1、echo：输出字符串

echo hello world

2、@echo off：只打印结果，不显示回显

@echo off

set param1=hello

set param2=world

echo %param1%%param2%ok

3、rem：用于注释，bat脚本运行的时候就不会执行该行语句

rem echo 这里不执行

4、cd：进入指定文件夹

cd D:\Test

5、chcp 65001：解决中文乱码问题

chcp 65001

echo Cc你好

二、实战

1、实现自动拉代码

@echo off
chcp 65001

REM  切换到工程目录
d:
cd D:\AutoTest

REM 打印当前目录
echo 当前目录：%cd%

REM 检查是否为Git仓库
git status >nul 2>&1
if %errorlevel% neq 0 (
        echo 当前目录不是一个Git仓库
        pause
        exit /b 1
)

REM  清除所有本地未提交的更改
git reset HEAD
git checkout .
git clean -fd

REM 切换到dev分支并拉取最新代码
git checkout dev
git pull

REM 提示操作完成
echo 最新代码已拉取完成
exit /b 0

2、实现电脑开机自动登录解锁屏

@echo off
mode con cols=50 lines=6
color a

:: 自动登录用户名
set username=Administrator

:: 用户密码
set passwd=123456



:: 从此行开始，下面的内容请不要作任何修改！！！
:: =====================================================================================

goto start

:autologin
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v AutoAdminLogon /t REG_SZ /d 1 /f >nul
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v DefaultUserName /t REG_SZ /d %username% /f >nul
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v DefaultPassword /t REG_SZ /d %passwd% /f >nul
echo.&echo.
echo 已设置自动登录,按任意键退出。
pause >nul
goto :eof

:cancel
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v AutoAdminLogon /t REG_SZ /d 0 /f >nul
echo.&echo.
echo 已取消自动登录,按任意键退出。
pause >nul
goto :eof

:start
cls
echo.&echo.
echo      1，设置自动登录     2，取消自动登录
echo.
choice /c 12 /n

if ERRORLEVEL 2 goto cancel
if ERRORLEVEL 1 goto autologin
goto start