自动检测http和https的RemoteObject-优快云博客

本文链接：https://blog.youkuaiyun.com/iteye_15147/article/details/82472128

本文介绍了一个Flex应用程序中用于封装远程对象调用的类——RemoteObjectWrapper。该类通过配置目的地、安全通道使用情况及URL来初始化远程对象实例，并能够根据应用环境选择合适的通信通道。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >


package 
{
	import util.BrowserUtil;
	import mx.controls.Alert;
	import mx.messaging.Channel;
	import mx.messaging.ChannelSet;
	import mx.messaging.channels.AMFChannel;
	import mx.messaging.channels.SecureAMFChannel;
	import mx.rpc.remoting.mxml.RemoteObject;

	public class RemoteObjectWrapper
	{
		private var _remote:RemoteObject;
		private var _destination:String;
		private var _url:String;
		private var _useSecureAMFChannel:Boolean=false;

		public function RemoteObjectWrapper(destination:String,useSecureAMFChannel:Boolean=false,url:String=null)
		{
			this._destination=destination;
			this._useSecureAMFChannel=useSecureAMFChannel;
			this._url=url;
		}

		public function get newInstance():RemoteObject{
			this._remote=new RemoteObject(_destination);
			_remote.channelSet=new ChannelSet();
			var channel:Channel=newChannel();
			_remote.channelSet.channels=[channel];
			_remote.requestTimeout=7200;
			return _remote;
		}

		private function newChannel():Channel{
			var channel:Channel;
			if(this._url==null || this._url.length==0){
				var browserUtil:BrowserUtil=BrowserUtil.getInstance();
				if(this._useSecureAMFChannel || browserUtil.isHttpsURL){
					channel=new SecureAMFChannel();
					channel.url="/"+browserUtil.contextRoot+"/messagebroker/amfsecure";
				}else{
					channel=new AMFChannel();
					channel.url="/"+browserUtil.contextRoot+"/messagebroker/amf";
				}
			}else{
				if(this._useSecureAMFChannel || this._url.indexOf("https")>-1 || this._url.indexOf("amfsecure")>-1){
					channel=new SecureAMFChannel();
					channel.url=_url;
				}else if(this._url.indexOf("http")>-1 || this._url.indexOf("amf")>-1){
					channel=new AMFChannel();
					channel.url=_url;
				}
			}
			return channel;
		}

	}
}