Qt Quick States

相关的类型

AnchorChanges	指定如何更改处于状态中的项的锚点
ParentChange	指定如何在状态更改中重新生成项
PropertyChanges	描述状态的新属性绑定或值
State	定义对象和属性的配置
StateChangeScript	指定如何在某个状态下运行脚本
StateGroup	为非item类型提供内置状态支持

许多用户界面设计是由状态驱动的;接口的配置根据当前状态的不同而不同。例如，交通信号将根据其状态配置其旗子或信号灯。当信号处于停止状态时，红灯亮，黄灯和绿灯灭。在警告状态下，黄灯是亮的，而其他灯是关的。

在QML中，状态是在State类型中定义的一组属性配置。不同的配置可以，例如:

> 显示一些UI组件，隐藏其他组件

> 向用户呈现不同的可用操作

> 启动、停止或暂停动画

> 在新状态中执行一些所需的脚本

> 更改特定项的属性值

> 显示不同的视图或屏幕

所有基于item的对象都有state属性，并且可以通过向项的state属性添加新的state对象来指定其他状态。组件中的每个状态都有一个唯一的名称，默认为空字符串。若要更改项的当前状态，请将state属性设置为状态的名称。

非item对象可以通过StateGroup类型使用状态。

Creating States

要创建状态，请向项的states属性添加state对象，该属性保存该项的状态列表。

警告信号组件可能有两种状态，正常状态(NORMAL)和触发状态(CRITICAL)。假设在NORMAL状态下，信号的颜色应该是绿色，警告标志是down。同时，在CRITICAL状态下，颜色应该是红色，警告标志是up。我们可以使用State类型和使用PropertyChanges类型的颜色和标志配置来建模状态。

Rectangle {
    id: signal
    width: 200; height: 200
    state: "NORMAL"

    states: [
        State {
            name: "NORMAL"
            PropertyChanges { target: signal; color: "green"}
            PropertyChanges { target: flag; state: "FLAG_DOWN"}
        },
        State {
            name: "CRITICAL"
            PropertyChanges { target: signal; color: "red"}
            PropertyChanges { target: flag; state: "FLAG_UP"}
        }
    ]
}

PropertyChanges类型将更改对象属性的值。对象通过它们的id被引用。组件外部的对象也使用id属性进行引用，例如外部标志对象的属性更改。

此外，可以通过将state属性与适当的信号状态分配来更改状态。状态开关可以是MouseArea类型，当信号接收到鼠标点击时，它会分配不同的状态。

Rectangle {
    id: signalswitch
    width: 75; height: 75
    color: "blue"

    MouseArea {
        anchors.fill: parent
        onClicked: {
            if (signal.state == "NORMAL")
                signal.state = "CRITICAL"
            else
                signal.state = "NORMAL"
        }
    }
}

State类型并不局限于对属性值执行修改。它还可以:

> 运行StateChangeScript脚本

> 通过PropertyChanges为对象重写已经存在的信号句柄

> 通过ParentChange改变对象的父对象

> 使用AnchorChanges修改锚点值

The Default State

每个基于Item的组件都有一个state属性和一个默认状态。默认状态是空字符串("")，它包含项目的所有初始属性值。默认状态对于在状态更改之前管理属性值很有用。将state属性设置为空字符串将加载默认状态。

The when Property

为方便起见，State类型有一个when属性，该属性可以绑定到表达式，以便在绑定表达式的计算结果为true时更改状态。当表达式的计算结果为false时，when属性将状态恢复到默认状态。

Rectangle {
    id: bell
    width: 75; height: 75
    color: "yellow"

    states: State {
                name: "RINGING"
                when: (signal.state == "CRITICAL")
                PropertyChanges {target: speaker; play: "RING!"}
            }
}

铃声组件将改变到振铃状态，无论何时signal.state 是 CRITICAL。

Animating State Changes

状态变化导致值的突变。Transition类型允许在状态更改期间进行更平滑的更改。在过渡中，动画和插值行为是可以定义的。动画和过渡这篇文章有更多关于创建状态动画的信息。

动画示例演示了如何声明一组基本状态，并在它们之间应用动画转换。

使用带状态的Qt快速行为解释了使用行为来动画状态更改时的一个常见问题。