pnputil 安装驱动实际运用-遍历当前文件夹下所有.inf文件并安装驱动

最新推荐文章于 2022-04-18 20:22:03 发布

Greless

最新推荐文章于 2022-04-18 20:22:03 发布

阅读量9.3k

点赞数

CC 4.0 BY-SA版权

分类专栏： # bat/cmd/批处理

本文链接：https://blog.youkuaiyun.com/greless/article/details/60959193

bat/cmd/批处理专栏收录该内容

6 篇文章

订阅专栏

本文介绍了一个批处理脚本，该脚本能够自动检测当前操作系统平台，并遍历指定文件夹下的所有.inf文件来安装对应的设备驱动程序。此外，还提供了一个用于提升权限的小脚本getadmin.vbs，确保整个安装过程在管理员权限下运行。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

微软官网介绍 https://technet.microsoft.com/zh-cn/library/ff550419

一、遍历当前文件夹下所有.inf文件并安装驱动

install.cmd

if "%PROCESSOR_ARCHITECTURE%" == "x86" ( 
	set OS_PLATFORM=x86
) else (
	set OS_PLATFORM=x64
)

::Run script as Admin
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if %ERRORLEVEL% EQU 0 (
	if exist "%temp%\getadmin.vbs" del /q "%temp%\getadmin.vbs"
) else (
	goto :Fun_UAC_Prompt
	if exist "%temp%\getadmin.vbs" del /q "%temp%\getadmin.vbs"
)

:START
@echo.
@echo Start install  drivers...
 cd /d %~dp0%OS_PLATFORM%
 
setlocal enabledelayedexpansion
for /f "delims=" %%b in ('dir /s /b ".\*.inf"') do (
	set INF_NAME=%%~nb
	set INF_PATH=%%~dpb
	echo cd /d !INF_PATH!
	cd /d !INF_PATH!
	echo pnputil -i -a !INF_NAME!.inf
	pnputil -i -a !INF_NAME!.inf
	timeout /t 3
)
xcopy /y %~dp0%OS_PLATFORM%\43430r0nvram.txt %WINDIR%\System32\Drivers\
goto :END

:ERROR
color 4f
@echo.
@echo ERROR
@echo.
pause>nul
goto :ERROR

:Fun_UAC_Prompt
if NOT "%~1"=="" set file= ""%~1""
(echo Set UAC = CreateObject("Shell.Application"^)
@echo UAC.ShellExecute "cmd.exe", "/c %~s0%file%", "", "runas", 1)> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /b 0

:END
@echo.
@echo Successfully installed  drivers
@echo.
timeout -t 2
exit

二、getadmin.vbs自动生成，目的是让脚本以管理员模式运行

Set UAC = CreateObject("Shell.Application")
UAC.ShellExecute "cmd.exe", "/c E:\8300_D~1\AP6212\INSTAL~1.CMD", "", "runas", 1