利用再归制作树

利用再归来画一个Flash树（tree）。参照结城浩先生的《programmer's math》完成。

1.先打开Flash CS3,建立一个ActionScript File。内容如下：
package {
    import flash.display.Sprite;
   
    public class Tree extends Sprite {
        private static const LEVEL:Number = 12.0;
        private var down:Boolean = false;
        private var angle:Number = 0.0;
        private var posx:Number = 0.0;
        private var posy:Number = 0.0;
       
        public function Tree() {
            setxy(800 / 2.0, 600 * 5.0 / 6.0);
            pendown();
            drawtree(LEVEL);
        }
       
        private function makecolor(n:Number):uint {
            var a:int = n * 255;
            return (a << 16) + (a << 8) + a;
        }
       
        public function setcolor(color:uint, alpha:Number=1.0):void {
            graphics.lineStyle(0, color, alpha);
        }
       
        public function pendown():void { down = true; }
       
        public function penup():void { down = false; }
       
        //
        public function setxy(x:Number, y:Number):void {
            posx = x;
            posy = y;
            if (down) {
                graphics.lineTo(x, y);
            } else {
                graphics.moveTo(x, y);
            }
        }
       
        public function forward(length:Number):void {
            setxy(posx + length * Math.sin(angle), posy - length * Math.cos(angle));
        }
        public function back(length:Number):void { forward(-length); }
        public function right(a:Number):void { angle += a * Math.PI / 180; }
        public function left(a:Number):void { right(-a); }

        public function drawtree(n:Number):void {
            if (n > 0) {
                var level:Number = (LEVEL - n) / LEVEL;
                left(18);
                pendown();
                setcolor(makecolor(level), 1-level);
                forward(n * 6.0);
                drawtree(n - 1);
                penup();
                back(n * 6.0);
                right(18);

                right(18);
                pendown();
                setcolor(makecolor(level), 1-level);
                forward(n * 6.0);
                drawtree(n - 1);
                penup();
                back(n * 6.0);
                left(18);
            }
        }
    }
}

2.新建一个元件，并设置它的Linkage和上面的类绑定。

3.第一Frame内容：
var a:Tree = new Tree();
addChild(a);