Bresenham高效画线算法

最新推荐文章于 2020-04-29 00:47:42 发布

原创最新推荐文章于 2020-04-29 00:47:42 发布 · 1.4k 阅读

0 ·

CC 4.0 BY-SA版权

文章标签：

#算法 #integer #pascal #plot #语言

博客介绍了Bresenham高效画线算法，指出斜率相乘法画线计算耗时，而该算法计算点坐标只需加、减法。给出简化的伪Pascal语言描述算法，还说明了实际程序需修正以处理不同情况，并给出修正后的伪Pascal算法。

部署运行你感兴趣的模型镜像

Bresenham高效画线算法

    画线的算法不少，但要作到高速、简单并不容易。斜率相乘法是最简单的方法之一，但计算每个点均要花费不少时间用于乘、除法运算；下面介绍的是Bresenham's高效画线算法，对每个点的坐标计算只要加、减法就能完成。
    简化算法用伪Pascal语言描述如下：
procedure DrawLine(x1, y1, x2, y2: Integer);
var
x, y, DeltaX, DeltaY, HalfX, ErrorTerm, i: Integer;
begin
DeltaX := x2 - x1;
DeltaY := y2 - y1;
HalfX := (x2 - x1) shr 1;
ErrorTerm := 0;
x := x1;
y := y1;
for i:=0 to DeltaX do
begin
    Plot(X, Y);
    Inc(x);
    ErrorTerm := ErrorTerm + DeltaY;
    if ErrorTerm>HalfX then
    begin
      ErrorTerm := ErrorTerm - DeltaX;
      Inc(y);
    end;
end;
end;
    为方便阅读，上述程序作了简化。实际程序应略作修正，以分别处理DeltaX与DeltaY比较大小, 必要时交换起始、结束点等。
    修正后的的伪Pascal算法如下：
procedure DrawLine(x1, y1, x2, y2: Integer);
var
x, y, DeltaX, DeltaY, HalfCount, ErrorTerm, i, Flag: Integer;
begin
DeltaX := x2 - x1;
DeltaY := y2 - y1;

if Abs(DeltaY)<Abs(DeltaX) then
begin
    if DeltaX<0 then
    begin
      i := x1;    x1 := x2;       x2 := i;
      i := y1;    y1 := y2;       y2 := i;
      DeltaX := x2 - x1;
      DeltaY := y2 - y1;
    end;
    if DeltaY<0 then Flag := -1
      else Flag := 1;
    DeltaY := Abs(DeltaY);
    HalfCount := DeltaX shr 1;
    ErrorTerm := 0;
    x := x1;
    y := y1;
    for i:=0 to DeltaX do
    begin
      Plot(X, Y);
      Inc(x);
      ErrorTerm := ErrorTerm + DeltaY;
      if ErrorTerm>HalfCount then
      begin
        ErrorTerm := ErrorTerm - DeltaX;
        y := y + Flag;
      end;
    end;
end
else
begin
    if DeltaY<0 then
    begin
      i := x1;    x1 := x2;       x2 := i;
      i := y1;    y1 := y2;       y2 := i;
      DeltaX := x2 - x1;
      DeltaY := y2 - y1;
    end;
    if DeltaX<0 then Flag := -1
      else Flag := 1;
    DeltaX := Abs(DeltaX);
    HalfCount := DeltaY shr 1;
    ErrorTerm := 0;
    x := x1;
    y := y1;
    for i:=0 to DeltaY do
    begin
      Plot(X, Y);
      Inc(y);
      ErrorTerm := ErrorTerm + DeltaX;
      if ErrorTerm>HalfCount then
      begin
        ErrorTerm := ErrorTerm - DeltaY;
        x := x + Flag;
      end;
    end;
end;
end;