[MSSQL]求某段时间内某一星期日期的天数

最新推荐文章于 2023-06-09 14:01:36 发布

厦门德仔

最新推荐文章于 2023-06-09 14:01:36 发布

阅读量1.4k

点赞数

分类专栏： MSSQL 文章标签： function fun 测试

MSSQL 专栏收录该内容

307 篇文章 ¥99.90 ¥299.90

订阅专栏

超级会员免费看

这是一个SQL函数，用于计算在给定的日期范围内指定星期的天数。函数名为FUN_GetDaysOfWeek，接收开始日期、结束日期和星期编号作为参数，返回该星期在日期区间内的天数。例如，给定2011年3月1日至2011年5月31日，查询星期日的天数，函数返回结果为13天。

/*
**********************************************
Program ID: FUN_GetDaysOfWeek
Purpose : 求某段时间内某一星期日期的天数
Author : Jesse
Date : 2011.02.19
**********************************************
*/
go
Create Function dbo.FUN_GetDaysOfWeek( 
@DateS smalldatetime,--开始时间
@DateE smalldatetime,--结束
@WeekValue int) --星期的某一天：-周日、-周一...7-周六
Returns nvarchar(100)
As
Begin
declare
@sResult nvarchar(100), --结果描述
@nResult int, --结果天数
@nWeekValue int, --起始日期是星期几(1-周日、-周一...7-周六)
@nDays int, --时间段内的天数
@nBeforeDays int, --起始日期到第一次相符日期的天数
@sWeekName varchar(20), --所求日期的星期名称
@tmpDate smalldatetime
set @WeekValue=@WeekValue % 7
if @WeekValue=0 
set @WeekValue=7
--如果起始日期大于终止日期，则对换
if @DateS>@DateE
select @tmpDate=@DateE,@DateE=@DateS,@DateS=@tmpDate
--取得起始日期的星期数，与设置无关(1-周日、-周一...7-周六)
select @nWeekValue=(Datepart(dw,@DateS)+(@@Datefirst %7))%7
if @nWeekValue=0
set @nWeekValue=7
set @sWeekName=DateName(dw,DateAdd(d,@WeekValue-@nWeekValue,@DateS))
if @WeekValue>=@nWeekValue
set @nBeforeDays=@WeekValue-@nWeekValue
else
set @nBeforeDays=7-abs(@WeekValue-@nWeekValue)
--取得时间段内的天数
select @nDays=Datediff(d,@DateS,@DateE)+1
if @nDays<@nBeforeDays
select @nResult=0
else
select @nResult=ceiling((@nDays-@nBeforeDays)/7.0)
set @sResult=N'日期区间：'+ convert(varchar(10),@DateS,120)+ N' 到' +convert(varchar(10),@DateE,120) +' 之间'
+@sWeekName +N' 共有'+cast(@nResult as varchar(100))+N' 天'
Return @sResult
end 
go
--测试示例
select dbo.FUN_GetDaysOfWeek('2011-03-01','2011-05-31',1)
--运行结果
/*
日期区间：2011-03-01 到2011-05-31 之间Sunday 共有13 天
*/