【PM复习】进入保护模式改进

     在前面的建立GDT的代码中，只是用db,dw直接来写二进制的数据，当我们要在GDT中添加很多描述符的时候，这样做就显得很晦涩难懂。在这里我们就建立1个宏，此宏以比较方便的方法来建立1个描述符，有3个入口参数，分别是段基址，段界限和段属性，代码如下：

Code:

1. ;%1 Base   
2. ;%2 Limit   
3. ;%3 Attr   
4. %macro  Descriptor 3   
5.     dw %2 & 0ffffh   
6.     dw %1 & 0ffffh   
7.     db (%1 >> 16) & 0ffh   
8.     db %3 & 0ffh   
9.     db ((%3 >> 8) & 0ffh) | ((%2 >> 16) & 0fh)   
10.     db (%1 >> 24) & 0ffh   
11. %endmacro  

     我们看到，就是把入口参数通过移位和逻辑操作符来分隔到合适的地方，对照着描述符的结构就可以很轻松地完成此工作。

     还有1个地方可以抽象，就是填充描述符的段基址的代码，如果要填充很多个描述符的段基址，那么重复的代码就会很多，可以选择用函数或者宏来实现，我们这里用宏来实现吧。入口地址有2个，一个是段描述符在实模式下的偏移，另一个是目标代码段的偏移，代码如下：

Code:

1. ;%1 Descriptor's Offset   
2. ;%2 Segment's Offset   
3. %macro  Fill_Descriptor 2   
4.     xor eax,eax   
5.     mov ax,cs   
6.     shl eax,4   
7.     add eax,%2   
8.     mov word [%1 + 2],ax   
9.     shr eax,16   
10.     mov byte [%1 + 4],al   
11.     mov byte [%1 + 7],ah   
12. %endmacro  

     这样我们的代码就可以简洁很多了，下面在上一节的基础上修改的代码：

Code:

1. ;%1 Base      
2. ;%2 Limit      
3. ;%3 Attr      
4. %macro  Descriptor 3      
5.     dw %2 & 0ffffh      
6.     dw %1 & 0ffffh      
7.     db (%1 >> 16) & 0ffh      
8.     db %3 & 0ffh      
9.     db ((%3 >> 8) & 0ffh) | ((%2 >> 16) & 0fh)      
10.     db (%1 >> 24) & 0ffh      
11. %endmacro     
12.   
13. ;%1 Descriptor's Offset      
14. ;%2 Segment's Offset      
15. %macro  Fill_Descriptor 2      
16.     xor eax,eax      
17.     mov ax,cs      
18.     shl eax,4      
19.     add eax,%2      
20.     mov word [%1 + 2],ax      
21.     shr eax,16      
22.     mov byte [%1 + 4],al      
23.     mov byte [%1 + 7],ah      
24. %endmacro     
25.   
26. org 0100h       
27. jmp LABEL_BEGIN       
28.       
29. [section .gdt]       
30. LABEL_DESC_DUMMY:       
31.     Descriptor  0,0,0     
32. LABEL_DESC_CODE32:    
33.     Descriptor  0,0ffffh,409ch      
34. LABEL_DESC_VIDEO:       
35.     Descriptor  0b8000h,0ffffh,4092h   
36.            
37. GDT_Len equ $ - LABEL_DESC_DUMMY       
38. GDT_Ptr:       
39.     dw  GDT_Len - 1       
40.     dd  0       
41.       
42. Selector_Code32 equ LABEL_DESC_CODE32 - LABEL_DESC_DUMMY       
43. Selector_Video  equ LABEL_DESC_VIDEO - LABEL_DESC_DUMMY       
44.       
45. [section .s16]       
46. [bits 16]       
47. LABEL_BEGIN:       
48.     mov ax,cs       
49.     mov ds,ax       
50.     mov es,ax       
51.            
52.     Fill_Descriptor LABEL_DESC_CODE32,LABEL_CODE32   
53.            
54.     xor eax,eax       
55.     mov ax,ds       
56.     shl eax,4       
57.     add eax,LABEL_DESC_DUMMY       
58.     mov dword [GDT_Ptr + 2],eax       
59.            
60.     lgdt    [GDT_Ptr]       
61.            
62.     cli       
63.            
64.     in  al,92h       
65.     or  al,00000010b       
66.     out 92h,al       
67.            
68.     mov eax,cr0       
69.     or  al,1       
70.     mov cr0,eax       
71.            
72.     jmp Selector_Code32:0       
73.       
74. [section .s32]       
75. [bits 32]       
76. LABEL_CODE32:       
77.     mov ax,Selector_Video       
78.     mov gs,ax       
79.     mov ah,0ch       
80.     mov al,'x'      
81.     mov [gs:80 * 10],ax       
82.     jmp $       

     运行结果与上一节相同。