[yocto]bsp层中manchine下的conf文件解析

manchine下的conf文件变量

以beaglebone-yocto.conf为例，poky/meta-yocto-bsp/conf/machine

• PREFERRED_PROVIDER_virtual/xserver
  • PREFERRED_PROVIDER 如果多个配方提供相同的项目，这个变量决定哪个配方是首选，从而提供该项目
  • 即提供 "virtual/xserver "的配方是 "xserver-xorg"
• XSERVER
  • 应该安装的软件包，以便为机器提供一个X服务器和驱动程序
• MACHINE_EXTRA_RRECOMMENDS
  • 依赖于机器的软件包的列表
  • 非必须，不存在安装不会失败；但是完整功能的镜像需要依赖这些包
• EXTRA_IMAGEDEPENDS
  • 构建的配方不提供安装到根文件系统中的软件包，但构建镜像依赖于配方；镜像build需要，但是不被安装到根文件系统中
  • 在这种情况下，必须为镜像构建U-Boot配方
• DEFAULTTUNE
  • 机器使用调整功能来优化机器、CPU和应用程序的性能；这些特性统称为 “tuning features”
  • include tune-cortexa8.inc类似
• IMAGE_FSTYPES
  • 创建根文件系统时使用的格式
• EXTRA_IMAGECMD
  • 为镜像创建命令指定附加选项
• WKS_FILE
  • 用来创建分区镜像的Wic kickstart文件的位置
• IMAGE_INSTALL
  • 通过image class(image.bbclass)指定要安装到镜像中的包
• do_image_wic[depends]
  • 在构建过程中构建的一个任务
  • 在这个例子中，该任务依赖于特定的工具，以便在构建Wic映像时创建sysroot
• SERIAL_CONSOLES
  -定义了一个串行控制台（TTY），以便使用getty来启用
• PREFERRED_PROVIDER_virtual/kernel
  • 当找到一个以上的提供者时，指定提供virtual/kernel的配方
• PREFERRED_VERSION_linux-yocto
  • 定义用于构建内核的配方的版本
• KERNEL_IMAGETYPE
  • 为设备建立的内核的类型
• KERNEL_DEVICETREE
  • 生成的Linux内核设备树（即*.dtb）文件的名称
• KERNEL_EXTRA_ARGS
  • 额外的make命令行参数，系统在编译内核时传递的参数
• SPL_BINARY
  • 定义了二级程序加载器（SPL）的二进制类型
• UBOOT_*
  • 定义了建立U-Boot映像所需的各种U-Boot配置
• UBOOT_SUFFIX
  • 指向生成的U-Boot扩展
• UBOOT_MACHINE
  • 指定构建U-Boot镜像时在make命令行中传递的值
• UBOOT_ENTRYPOINT*
  • 指定U-Boot镜像的入口点
• UBOOT_LOADADDRESS
  • 指定U-Boot映像的加载地址
• MACHINE_FEATURES
  • 指定硬件设备(BeagleBone)设备能够支持的硬件特性列表
• IMAGE_BOOT_FILES
  • 使用Wic工具与bootimg-partition或bootimg-efi源插件准备镜像时，安装到设备启动分区的文件
• code

  #@TYPE: Machine
  #@NAME: Beaglebone-yocto machine
  #@DESCRIPTION: Reference machine configuration for http://beagleboard.org/bone and http://beagleboard.org/black boards
  
  PREFERRED_PROVIDER_virtual/xserver ?= "xserver-xorg"
  XSERVER ?= "xserver-xorg \
              xf86-video-modesetting \
             "
  
  MACHINE_EXTRA_RRECOMMENDS = "kernel-modules kernel-devicetree"
  
  EXTRA_IMAGEDEPENDS += "u-boot"
  
  DEFAULTTUNE ?= "cortexa8hf-neon"
  include conf/machine/include/arm/armv7a/tune-cortexa8.inc
  
  IMAGE_FSTYPES += "tar.bz2 jffs2 wic wic.bmap"
  EXTRA_IMAGECMD:jffs2 = "-lnp "
  WKS_FILE ?= "beaglebone-yocto.wks"
  IMAGE_INSTALL:append = " kernel-devicetree kernel-image-zimage"
  do_image_wic[depends] += "mtools-native:do_populate_sysroot dosfstools-native:do_populate_sysroot"
  
  SERIAL_CONSOLES ?= "115200;ttyS0 115200;ttyO0"
  SERIAL_CONSOLES_CHECK = "${SERIAL_CONSOLES}"
  
  PREFERRED_PROVIDER_virtual/kernel ?= "linux-yocto"
  PREFERRED_VERSION_linux-yocto ?= "5.0%"
  
  KERNEL_IMAGETYPE = "zImage"
  KERNEL_DEVICETREE = "am335x-bone.dtb am335x-boneblack.dtb am335x-bonegreen.dtb"
  KERNEL_EXTRA_ARGS += "LOADADDR=${UBOOT_ENTRYPOINT}"
  
  SPL_BINARY = "MLO"
  UBOOT_SUFFIX = "img"
  UBOOT_MACHINE = "am335x_evm_defconfig"
  UBOOT_ENTRYPOINT = "0x80008000"
  UBOOT_LOADADDRESS = "0x80008000"
  
  MACHINE_FEATURES = "usbgadget usbhost vfat alsa"
  
  IMAGE_BOOT_FILES ?= "u-boot.${UBOOT_SUFFIX} MLO zImage am335x-bone.dtb am335x-boneblack.dtb am335x-bonegreen.dtb"