将可执行jar包部署为windows服务

如何把可执行jar包部署为windows服务

网上有很多种把可执行jar包部署为windows服务的方法，本次要说的是使用Apache Commons Daemon来部署windows服务。

通过官方文档很容易掌握这种方法。

1 下载 Apache Commons Daemon

进入下载页面，默认是最新版本。如果想下载历史版本的程序，需要从archives…页面下载。
目录binaries文件中，可以找到包含存档的子目录，找到对应的windows目录下载相应版本的程序， Windows 版本以 zip 文件的形式提供。
以commons-daemon-1.1.0-bin-windows.zip为例。目录如同所示：

目录包含2个不同的可执行文件：

prunsrv.exe - 用于将应用程序作为服务运行的服务应用程序。
prunmgr.exe - 用于监视和配置已安装服务的 GUI 管理器应用程序。

根目录的prunsrv.exe是32为的，amd64文件夹的prunsrv.exe 是64 位的。

注意：部署的时候需要区分jdk版本（不是windows系统的版本），本地的jdk是32位，则需要用32的prunsrv.exe部署windows服务，否则虽然能部署服务，但是启动的时候会报错。

下面简述一下主要的步骤。

2 在 jvm 模式下使用 Procrun

class MyClass;
//服务启动方法
static void start(String [] args){
        // process service start function
    }
//服务停止方法
static void stop(String [] args){
        // process service stop function
    }
}

2.1 安装服务

要安装该服务，您需要使用 //IS 参数。

安装名为“TestService”的服务

prunsrv //IS//TestService --DisplayName="Test Service" \
        --Install=prunsrv.exe
        --Classpath MyClass.jar
		--StartMode jvm --StartClass MyClass --StartMethod start
		--StopMode  jvm --StopClass  MyClass --StopMethod  stop

注意：从版本 1.0.8 开始，支持命令的方式：command [ServiceName] (–StartClass MyClass )。之前版本需要使用–StartClass=MyClass格式。

实际使用的过程中可能还需要指定jdk和jvm。

2.2 删除服务

若要删除该服务，需要使用 //DS 参数。 如果服务正在运行，它将被停止，然后被删除。

删除名为“TestService”的服务

prunsrv //DS//TestService

2.3 服务管理

管理名为“TestService”

prunmgr //MR//TestService

以下为本地服务名untitled的服务管理界面截图

3 常见问题：

3.1 Failed creating java

官方文档上面说的是缺少msvcr71.dll，如果不是这种情况，那么就是没有制定JRE，JRE要使用bin目录下的JRE。

3.2 %1 不是有效的 Win32 应用程序。

jvm是32位的，但是部署服务的时候用的64的prunsrv.exe

3.3 Failed to start Java/FindClass com/rens/demo/MyClass failed

查看jar的manifest.mf是否有Main-Class，如果没有就是打包有问题。或者查看部署服务的时候制定的StartClass是否正确。

3.4 Error occurred during initialization of VM/Could not reserve enough space for 2097152KB object heap

32位jvm内存限制最大不能大于1G，修改~~–JvmMx=2048~~

4 附录

最后附上使用的批处理供参考(根据操作系统判断32位还是64的，需要根据具体情况修改)

@echo off
rem 关闭命令行脚本显示

rem 设置UTF8中文显示，会导致报错类信息英文显示
chcp 65001 1>nul

rem 服务配置项开始

rem 设置服务名称
set "SERVICE_EN_NAME=untitled"
rem 设置服务显示名称
set "SERVICE_CH_NAME=untitled"
rem 设置服务描述
set "SERVICE_DESCRIPTION=untitled"

rem 设置入口类
set "MAIN_CLASS=com.rens.demo.MyClass"
rem 服务配置项结束

rem 手动编辑输入自定义JRE路径，要求使用JDK的JRE
set "JRE_PATH=C:\Program Files (x86)\Java\jdk1.8.0_144\jre"


goto :checkOS
goto :checkJavaVersion
goto :setpath
goto :print
goto :install
goto :start
goto :end

:checkOS
rem 判断系统是64位系统还是32系统
set ARCH=x64
if %PROCESSOR_IDENTIFIER:~0,3%==x86 (
set ARCH=x86
)

:checkJavaVersion
echo 正在检测Java版本信息
for /f tokens^=2-5^ delims^=.-_^" %%j in ('java -fullversion 2^>^&1') do (
set "JVER=%%j%%k%%l"
)
echo JAVA版本号：%JVER%
if %jver% LSS 180 (
echo 当前Java版本过低，程序无法运行，需要安装java 8。
if defined JRE_PATH (
echo 自定义JRE路径已经设置 JRE_PATH:"%JRE_PATH%"。
) else (
set /p JRE_PATH=请输入JRE1.8安装目录:
goto :checkInput
)
)

:checkInput
if defined JRE_PATH (
set "JVM=%JRE_PATH%\bin\server\jvm.dll"
)


:setpath
rem 设置相关路径
set "BASEDIR=%CD%"
rem 设置java类路径
set "CLASSPATH=%BASEDIR%\*;%BASEDIR%\classes;%BASEDIR%\lib\*"
rem 设置prunsrv路径
set "SRV=%BASEDIR%\bin\%SERVICE_EN_NAME%_%ARCH%.exe"
rem 设置日志路径及日志文件前缀
set "LOGPATH=%BASEDIR%\logs"

:print
rem 输出信息
echo ARCH: %ARCH%
echo SERVICE_NAME: %SERVICE_EN_NAME%
echo MAIN_CLASS: %MAIN_CLASS%
echo prunsrv path: %SRV%
echo JVM path: %JVM%

:install
rem 安装
echo install %SERVICE_EN_NAME%
::如果手工指定了JVM路径，则使用特定JVM配置，没有制定则使用使用系统默认的JVM
if defined JVM (
"%SRV%" //IS//%SERVICE_EN_NAME% --DisplayName="%SERVICE_CH_NAME%" "--Description=%SERVICE_DESCRIPTION%" "--Classpath=%CLASSPATH%" "--Install=%SRV%" "--Jvm=%JVM%" --JvmMs=128 --JvmMx=2048 --Startup=auto --JvmOptions=-Djcifs.smb.client.dfs.disabled=false ++JvmOptions=-Djcifs.resolveOrder=DNS ++JvmOptions=-Dfile.encoding=UTF-8 "--StartPath=%BASEDIR%" "--StartMode=jvm" "--StartClass=%MAIN_CLASS%" --StartMethod=start "--StopPath=%BASEDIR%" --StopMode=jvm "--StopClass=%MAIN_CLASS%" --StopMethod=stop "--LogPath=%LOGPATH%" --StdOutput=auto
) else (
"%SRV%" //IS//%SERVICE_EN_NAME% --DisplayName="%SERVICE_CH_NAME%" "--Description=%SERVICE_DESCRIPTION%" "--Classpath=%CLASSPATH%" "--Install=%SRV%" --JvmMs=128 --JvmMx=2048 --Startup=auto --JvmOptions=-Djcifs.smb.client.dfs.disabled=false ++JvmOptions=-Djcifs.resolveOrder=DNS ++JvmOptions=-Dfile.encoding=UTF-8 "--StartPath=%BASEDIR%" "--StartMode=jvm" "--StartClass=%MAIN_CLASS%" --StartMethod=start "--StopPath=%BASEDIR%" --StopMode=jvm "--StopClass=%MAIN_CLASS%" --StopMethod=stop "--LogPath=%LOGPATH%" --StdOutput=auto
)

:start
rem 启动服务
echo start %SERVICE_EN_NAME%
"%SRV%" //ES//%SERVICE_EN_NAME%

:::monitor
::rem 开启Monitor
::set "MONITOR_PATH=%BASEDIR%\bin\prunsrv.exe"
::"%MONITOR_PATH%" //MR//%SERVICE_EN_NAME%

:end
pause&exit

@echo off
rem 关闭命令行脚本显示

rem 设置UTF8中文显示，会导致报错类信息英文显示
chcp 65001 1>nul

rem 服务配置项开始

rem 设置服务名称
set "SERVICE_EN_NAME=untitled"
rem 设置服务显示名称
set "SERVICE_CH_NAME=untitled"
rem 设置服务描述
set "SERVICE_DESCRIPTION=untitled"

rem 设置入口类
set "MAIN_CLASS=com.rens.demo.MyClass"
rem 服务配置项结束

goto :checkOS
goto :setpath
goto :print
goto :uninstall
goto :end

:checkOS
rem 判断系统是64位系统还是32系统
set ARCH=x64
if %PROCESSOR_IDENTIFIER:~0,3%==x86 (
set ARCH=x86
)

:setpath
rem 设置相关路径
set "BASEDIR=%CD%"
rem 设置prunsrv路径
set "SRV=%BASEDIR%\bin\%SERVICE_EN_NAME%_%ARCH%.exe"

:print
rem 输出信息
echo ARCH: %ARCH%
echo SERVICE_NAME: %SERVICE_EN_NAME%
echo JAVA_HOME: %JAVA_HOME%
echo MAIN_CLASS: %MAIN_CLASS%
echo prunsrv path: %SRV%

:uninstall
rem 卸载
"%SRV%" //DS//%SERVICE_EN_NAME%

:end
pause&exit