shell编程--awk使用

最新推荐文章于 2023-11-26 11:51:40 发布

怀揣_梦想

最新推荐文章于 2023-11-26 11:51:40 发布

阅读量656

点赞数 4

分类专栏：笔记文章标签： linux shell awk

本文链接：https://blog.youkuaiyun.com/Liqiufeng_/article/details/108012688

版权

笔记专栏收录该内容

20 篇文章

订阅专栏

本文详细介绍了awk编程语言，包括awk的工作原理、两种语法格式、内置变量、格式化输出、模式与动作、条件判断等核心概念。awk通过逐行处理文件，根据指定模式执行操作，常用于文本和数据处理。文中还展示了如何利用awk进行脚本编程，如自定义分隔符、使用printf函数、条件判断等，是Linux/Unix系统下强大的文本处理工具。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

一、awk简介

awk 是一种编程语言，用于在linux/unix下对文本和数据进行处理。

数据可以来自标准输入、一个或多个文件，或其它命令的输出。

支持用户自定义函数和动态正则表达式等先进功能，是linux/unix
下的一个强大编程工具。

在命令行中使用，但更多是作为脚本来使用。

awk的处理文本和数据的方式是这样的，它逐行扫描文件，从第一行到最后一行，寻找匹配的特定模式的行，并在这些行上进行你想要的操作。如果没有指定处理动作，则把匹配的行显示到标准输出(屏幕)，如果没有指定模式，则所有被操作所指定的行都被处理。

awk分别代表其作者姓氏的第一个字母。因为它的作者是三个人，分别是Alfred Aho、Brian Kernighan、Peter Weinberger。

gawk是awk的GNU版本，它提供了Bell实验室和GNU的一些扩展。

二、awk的两种形式语法格式

awk [options] ‘commands’ filenames
awk [options] -f awk-script-file filenames

options：

-F 对于每次处理的内容，可以指定一个子定义的分隔符，默认的分隔符是空白字符（空格或 tab 键）

command：

BEGIN{}                        {}               END{}

处理所有内容之前的动作       处理内容中的动作   处理所有内容之后的动作

示例

 awk 'BEGIN{print "----开始处理了---"} {print "ok"} END{print "----都处理完毕---"}' /etc/hosts
----开始处理了---
ok
ok
ok
----都处理完毕---

BEGIN{} 通常用于定义一些变量，例如 BEGIN{FS=":";OFS="---"}

三、awk工作原理

awk -F: '{print $1,$3}' /etc/passwd

(1)awk，会处理文件的每一个行，每次处理时，使用一行作为输入，并将这一行赋给内部变量$0，每一行也可称为一个记录，以换行符结束

(2)然后，行被 :（默认为空格或制表符）分解成字段（或称为域），每个字段存储在已编号的变量中，从$1开始，
最多达100个字段

(3)awk如何知道用空白字符来分隔字段的呢？因为有一个内部变量FS来确定字段分隔符。初始时，FS赋为空白字符

(4)awk打印字段时，将以内置的方法使用 print 函数打印，awk 在打印出的字段间加上空格。这个空格是内部的一个变量 OFS 输出字段的分隔符, 逗号 , 会和 OFS 进行映射，通过 OFS 可以控制这个输出分隔符的值。

(5)awk输出之后，将从文件中获取另一行，并将其存储在$0中，覆盖原来的内容，然后将新的字符串分隔成字段并进行处理。该过程将持续到所有行处理完毕

四、记录与字段相关内部变量：

$0 ： awk变量 $0 保存当前正在处理的行内容
NR ：当前正在处理的行是 awk 总共处理的行号。
FNR：当前正在处理的行在其文件中的行号。
NF ：每行被处理时的总字段数
$NF: 当前处理行的分隔后的最后一个字段的值
FS ：输入行时的字段分隔符，默认空格
awk 'BEGIN{FS=":"} {print $1,$3}' /etc/passwd
OFS ：输出字段分隔符,默认是一个空格
awk 'BEGIN{FS=":"; OFS="+++"} /^root/{print $1,$2,$3,$4}' /etc/passwd
ORS 输出记录分隔符, 默认是换行符.

示例

将文件每一行合并为一行

ORS默认输出一条记录应该回车，但是这里是加了一个空格

awk 'BEGIN{ORS="  "} {print $0}' /etc/passwd

五、格式化输出：

printf 函数

awk -F: '{printf "%-15s %-10s %-15s\n", $1,$2,$3}' /etc/passwd
awk -F: '{printf "|%-15s| %-10s| %-15s|\n", $1,$2,$3}' /etc/passwd

%s 字符类型
%d 十进制整数
%.2f 浮点类型 .2表示保留小数点后面的2位，默认 6位
%-15s占15字符 - 表示左对齐，默认是右对齐
printf 默认不会在行尾自动换行，加 \n

六、awk模式和动作

任何 awk 语句都由模式和动作组成。

模式部分 决定动作语句何时触发及触发事件。
如果省略模式部分，动作将时刻保持执行状态。

模式可以是任何条件语句或复合语句或正则表达式。

模式可以是

正则表达式：

将整行进行正则匹配（包含）：

就是当前处理的行有没有包含指定的模式（书写的正则表达式）
/正则/ 正则需要写在双斜线内

awk '/^root/' /etc/passwd  # 整行开头是 root 的
awk '$0 ~ /^root/' /etc/passwd  # 整行开头是 root 的
awk '!/root/' /tec/ passwd    # 整行开头 不是 root 的
awk '$0 !~ /^root/' /etc/passwd  # 整行开头 不是 root 的

将某一字段进行正则匹配：

可以使用的匹配操作符（~ 和 !~）
字段 ~ /正则/

awk -F: '$1 ~ /^root/' /etc/passwd # 分隔后的第一个字段的值开头是 root 的
awk -F: '$NF !~ /bash$/' /etc/passwd # 最后一个字段的值的结尾不是 bash 的

匹配开头是 bin 的或者开头是 root 的行

[root@localhost ~]# awk -F: '/^(bin|root)/' /etc/passwd
root:x:0:0:root:/root:/bin/zsh
bin:x:1:1:bin:/bin:/sbin/nologin

关系运算符号

实现字符串的完全相等需要使用 ==

字符串需要使用双引号
!= 表示不等于

awk -F: '$NF == "/bin/bash"' /etc/passwd
awk -F: '$1 == "root"' /etc/passwd

比较表达式：

比较表达式采用对文本进行比较，只有当条件为真，才执行指定的动作。
比较表达式使用***关系运算符***，用于比较数字与字符串。

关系运算符有
< 小于例如 x<y
> 大于 x>y
<= 小于或等于 x<=y
== 等于 x==y
!= 不等于 x!=y
>= 大于等于 x>=y

示例

awk -F: '$3 == 0' /etc/passwd
awk -F: '$3 < 10' /etc/passwd

df -P | grep '/' |awk '$4 > 25000'

算术运算：+, -, *, /, %(模: 取余), ^(幂：2^3)

可以在模式中执行计算，awk都将按浮点数方式执行算术运算

awk -F: '$3 * 10 > 500' /etc/passwd
awk -F: '{ if($3*10>500){print $0} }' /etc/passwd

逻辑操作符和复合模式

&& 逻辑与, 相当于并且
||逻辑或，相当于或者
! 逻辑非 , 取反

awk -F: '$1~/root/ && $3<=15' /etc/passwd
awk -F: '$1~/root/ || $3<=15' /etc/passwd
awk -F: '!($1~/root/ || $3<=15)' /etc/passwd

[root@localhost ~]# cat passwd
root:x:0:0:root:/root:/bin/zsh
bin:x:1:1:bin:/bin:/sbin/nologin
daemon:x:20:2:daemon:/sbin:/sbin/nologin
root:x:20:2:daemon:/sbin:/sbin/nologin
[root@localhost ~]# awk -F: '!($1~/root/ || $3<=15){print $0}' passwd
daemon:x:20:2:daemon:/sbin:/sbin/nologin
[root@localhost ~]# awk -F: '($1~/root/ || $3<=15){print $0}' passwd
root:x:0:0:root:/root:/bin/zsh
bin:x:1:1:bin:/bin:/sbin/nologin
root:x:20:2:daemon:/sbin:/sbin/nologin

范围模式, 模式之间用逗号 , 隔开

使用语法是： 起始表达式, 终止表达式

下面的意思是: 从开头是 bin 的行开始匹配成功一直到含有 adm 的行结束匹配
也就是开头是 bin 的行到含有 adm 的行的所有内容都符合匹配条件。

[root@localhost ~]# awk -F: '/^bin/,/adm/ {print $0 }' /etc/passwd
bin:x:1:1:bin:/bin:/sbin/nologin
daemon:x:2:2:daemon:/sbin:/sbin/nologin
adm:x:3:4:adm:/var/adm:/sbin/nologin

awk使用外部变量：

awk参数-v（推荐使用，易读）

[root@sharkyun ~]# w=hello
[root@sharkyun ~]# echo "hello world" | awk -v var=$w '$1 == var {print $1}'
hello

指定多个分隔符：`[]`

[root@localhost ~]# echo "a b|c d| ||||e | |" |awk -F'[ |]' '{print $10}'
e
[root@localhost ~]# echo "a b|c d| ||||e | |" |awk -F'[ |]+' '{print $5}'
e

awk -F'[][ ]+' '$4 ~ /^11\/Apr\/2020/, $4 ~ /^17\/Apr\/2020/ && $7 ~ /^\/star\/local\/app/ {j++}END{print "总访问量:"j,"平均:"j/7}' access.log

注意：中括号内的任意字符均视为普通字符，比如 . * 都被看做是普通字符。
例如：
$ echo "a.b*c" |awk -F'[.*]' '{print $1, $2,$3}'
a b c

生产实例：
统计日志中某个时间范围的 IP 访问量，并进行排序

部分日志

110.183.58.144 - - [10/May/2018:23:49:27 +0800] "GET http://app.znds.com/html/20180504/y222sks_2.2.3_dangbei.dangbei HTTP/1.1" 200 14306614 "-" "okhttp/3.4.1"
1.69.17.127 - - [10/May/2018:23:49:31 +0800] "GET http://app.znds.com/down/20180205/ttjs_3.0.0.1_dangbei.apk HTTP/1.1" 200 13819375 "-" "okhttp/3.4.1"
1.69.17.127 - - [10/May/2018:23:49:40 +0800] "GET http://app.znds.com/down/20180416/ttyj_1.1.6.0_dangbei.apk HTTP/1.1" 200 16597231 "-" "okhttp/3.4.1"
1.69.17.127 - - [10/May/2018:23:50:00 +0800] "GET http://app.znds.com/down/20170927/jydp_1.06.00_dangbei.apk HTTP/1.1" 200 36659203 "-" "okhttp/3.4.1"

具体实现

gsub(r,s) 在整个$0中用s替代r

gsub(r,s,t) 在整个t中用s替代r

awk '{gsub(/\[/,"",$4);gsub(/\//,"",$4);print $4}' access.log

日志文件名：app.log

[root@localhost ~]#  start_dt='10/May/2018:23:47:43
[root@localhost ~]#  end_dt='10/May/2018:23:49:05'
[root@localhost ~]#  awk -v st=${start_dt} -v ent=${end_dt} -F'[][ ]' '$5 == st,$5 == ent  {print $1}' app.log  |sort |uniq -c |sort -nr |head -n 10
     66 223.13.142.15
      6 110.183.13.212
      4 1.69.17.127
      1 113.25.94.69
      1 110.183.58.144

方式二

[root@shark ~]# st="10May2018:23:49:31"
[root@shark ~]# endt="10May2018:23:49:40"
[root@shark ~]#
[root@shark ~]# awk -F'[][ ]' -v st=$st -v ent=$endt '{gsub(/\[/,"",$5);gsub(/\//,"",$5); if ($5 >= st && $5 <= ent){print $1}}' access.log
1.69.17.127
1.69.17.127
1.69.17.127
1.69.18.129
1.69.17.128
1.69.18.129
1.69.17.128
1.69.17.127
[root@shark ~]#

七、awk 脚本编程

条件判断

if语句

d格式 { if (表达式) {语句; 语句; ...}}

条件表达式的演进

awk -F: '$3>300 {print $0}' /etc/passwd
awk -F: '{ if($3>300) print $0 }' /etc/passwd
awk -F: '{ if($3>300) {print $0} }' /etc/passwd
awk -F: '{ if($3>300) {print $3} else{print $1} }' /etc/passwd

awk -F: '{if($3==0) {print $1 " is administrator."}}' /etc/passwd
输出： root is administrator.

# 统计系统级别用户的数量
awk -F: '{if($3>0 && $3<1000){count++;}} END{print count}' /etc/passwd 
输出： 22

if…else语句

格式 {if(表达式)｛语句;语句;...｝else{语句;语句;...}}

awk -F: '{if($3==0){print $1} else {print $7}}' /etc/passwd

awk -F: '{ if($3==0){count++} else{i++} } END{print "管理员个数: "count "系统用户数: "i}' /etc/passwd
输入：
管理员个数: 1系统用户数: 24

awk -F: '{ if($3==0){count++} else{i++} } END{print "管理员个数: "count ; print  "系统用户数: "i}' /etc/passwd
输出：
管理员个数: 1
系统用户数: 24

if…else if…else语句

格式
{if(表达式1) {语句;语句；...} else if (表达式2) {语句;语句；...} else if(表达式3){语句;语句；...} else {语句;语句；...} }

awk -F: '{if($3==0){i++} else if($3>999){k++} else{j++}} END{print i; print k; print j}' /etc/passwd
输出：
1
2
22

awk -F: '{if($3==0){i++} else if($3>999){k++} else{j++}} END{print "管理员个数: "i; print "普通用个数: "k; print "系统用户: "j}' /etc/passwd
输出：
管理员个数: 1
普通用个数: 2
系统用户: 22

其他练习

[root@tianyun ~]# df -h
Filesystem Size Used Avail Use% Mounted on
/dev/mapper/cl-root 2.8T 246G 2.5T 9% /
tmpfs 24G 20K 24G 1% /dev/shm
/dev/sda2 1014M 194M 821M 20% /boot

[root@tianyun ~]# df -h |awk '{ if(int($5)>5){print $6":"$5} }'
/:9%
/boot:20%

[root@tianyun ~]# i=10
[root@tianyun ~]# df -h |awk '{ if(int($5)>'''$i'''){print $6":"$5} }'
/boot:20%