Hive 压缩和储存

Hive 压缩和储存

一、Hadoop压缩配置

1.1 MR支持的压缩编码

压缩编码

为了支持多种压缩/解压缩算法，Hadoop引入了编码/解码器，如下表：

编码器

压缩性能的比较

性能比较

http://google.github.io/snappy/
在64位模式的core i7处理器的单核上，Snappy压缩速度约为250MB/秒或更高，并以大约500 MB/秒或更高的速度解压缩。

1.2 压缩参数配置

要在 Hadoop 中启用压缩，可以配置如下参数（mapred-site.xml 文件中）：

压缩参数

二、Map输出阶段压缩

开启 map 输出阶段压缩可以减少 job 中 map 和 Reduce task 间数据传输量。具体配置如下：

1. 开启 hive 中间传输数据压缩功能

set hive.exec.compress.intermediate=true;

1. 开启 mapreduce 中 map 输出压缩功能

set mapreduce.map.output.compress=true;

1. 设置 mapreduce 中 map 输出数据的压缩方式

set mapreduce.map.output.compress.codec=org.apache.hadoop.io.compress.SnappyCodec;

1. 执行查询语句

select count(ename) name from emp;

22.593s

三、Reduce输出阶段压缩

当 Hive 将输出写入到表中时，输出内容同样可以进行压缩。属性hive.exec.compress.output控制着这个功能。用户可能需要保持默认设置文件中的默认值false，这样默认的输出就是非压缩的纯文本文件了。用户可以通过在查询语句或执行脚本中设置这个值为 true，来开启输出结果压缩功能。

1. 开启 hive 最终输出数据压缩功能

set hive.exec.compress.output=true;

1. 开启 mapreduce 最终输出数据压缩

set mapreduce.output.fileoutputformat.compress=true;

1. 设置 mapreduce 最终数据输出压缩方式

set mapreduce.output.fileoutputformat.compress.codec=org.apache.hadoop.io.compress.SnappyCodec;

1. 设置 mapreduce 最终数据输出压缩为块压缩

set mapreduce.output.fileoutputformat.compress.type=BLOCK;

1. 测试一下输出结果是否是压缩文件

insert overwrite local directory '/root/data/distribute-result0' 
select * from emp 
distribute by deptno 
sort by empno desc;

四、文件储存格式

Hive 支持的存储数据的格式主要有：TEXTFILE 、SEQUENCEFILE、ORC、PARQUET。

4.1 列式储存和行式储存

如图所示左边为逻辑表，右边第一个为行式存储，第二个为列式存储。

• 行存储的特点
  查询满足条件的一整行数据的时候，列存储则需要去每个聚集的字段找到对应的每个列的值，行存储只需要找到其中一个值，其余的值都在相邻地方，所以此时行存储查询的速度更快。

• 列存储的特点
  因为每个字段的数据聚集存储，在查询只需要少数几个字段的时候，能大大减少读取的数据量；每个字段的数据类型一定是相同的，列式存储可以针对性的设计更好的设计压缩算法。

TEXTFILE 和 SEQUENCEFILE 的存储格式都是基于行存储的；
ORC 和 PARQUET 是基于列式存储的。

4.2 TextFile 格式

默认格式，数据不做压缩，磁盘开销大，数据解析开销大。可结合 Gzip、Bzip2 使用，但使用 Gzip 这种方式，hive 不会对数据进行切分，从而无法对数据进行并行操作。

4.3 Orc格式

Orc (Optimized Row Columnar)是 Hive 0.11 版里引入的新的存储格式。

如下图所示可以看到每个 Orc 文件由 1 个或多个 stripe 组成，每个 stripe 一般为 HDFS的块大小，每一个 stripe 包含多条记录，这些记录按照列进行独立存储，对应到 Parquet中的 row group 的概念。每个 Stripe 里有三部分组成，分别是 Index Data，Row Data，StripeFooter：

1）Index Data：一个轻量级的 index，默认是每隔 1W 行做一个索引。这里做的索引应该只是记录某行的各字段在 Row Data 中的 offset。

2）Row Data：存的是具体的数据，先取部分行，然后对这些行按列进行存储。对每个列进行了编码，分成多个 Stream 来存储。

3）Stripe Footer：存的是各个 Stream 的类型，长度等信息。

每个文件有一个 File Footer，这里面存的是每个 Stripe 的行数，每个 Column 的数据类型信息等；每个文件的尾部是一个 PostScript，这里面记录了整个文件的压缩类型以及FileFooter 的长度信息等。在读取文件时，会 seek 到文件尾部读 PostScript，从里面解析到File Footer 长度，再读 FileFooter，从里面解析到各个 Stripe 信息，再读各个 Stripe，即从后往前读。

4.4 Parquet 格式

Parquet 文件是以二进制方式存储的，所以是不可以直接读取的，文件中包括该文件的数据和元数据，因此 Parquet 格式文件是自解析的。

（1）行组(Row Group)：每一个行组包含一定的行数，在一个 HDFS 文件中至少存储一个行组，类似于 orc 的 stripe 的概念。

（2）列块(Column Chunk)：在一个行组中每一列保存在一个列块中，行组中的所有列连续的存储在这个行组文件中。一个列块中的值都是相同类型的，不同的列块可能使用不同的算法进行压缩。

（3）页(Page)：每一个列块划分为多个页，一个页是最小的编码的单位，在同一个列块的不同页可能使用不同的编码方式。

通常情况下，在存储 Parquet 数据的时候会按照 Block 大小设置行组的大小，由于一般情况下每一个 Mapper 任务处理数据的最小单位是一个 Block，这样可以把每一个行组由一个 Mapper 任务处理，增大任务执行并行度。Parquet 文件的格式。

上图展示了一个 Parquet 文件的内容，一个文件中可以存储多个行组，文件的首位都是该文件的 Magic Code，用于校验它是否是一个 Parquet 文件，Footer length 记录了文件元数据的大小，通过该值和文件长度可以计算出元数据的偏移量，文件的元数据中包括每一个行组的元数据信息和该文件存储数据的 Schema 信息。除了文件中每一个行组的元数据，每一页的开始都会存储该页的元数据，在 Parquet 中，有三种类型的页：数据页、字典页和索引页。数据页用于存储当前行组中该列的值，字典页存储该列值的编码字典，每一个列块中最多包含一个字典页，索引页用来存储当前行组下该列的索引，目前 Parquet 中还不支持索引页。

4.5 主流文件存储格式对比

从存储文件的压缩比和查询速度两个角度对比。

存储文件的压缩比测试：

1. 测试数据

   

2. TextFile

   1. 创建表，存储数据格式为 TextFile

      create table log_text (
      track_time string,
      url string,
      session_id string,
      referer string,
      ip string,
      end_user_id string,
      city_id string
      )
      row format delimited fields terminated by '\t'
      stored as textfile;
      

   2. 向表中加载数据

      load data local inpath '/opt/module/hive/datas/log.data' into table log_text ;
      

   3. 查看表中数据大小

      dfs -du -h /user/hive/warehouse/log_text;
      # 18.13 M /user/hive/warehouse/log_text/log.data
      

3. ORC

   1. 创建表，存储数据格式为 ORC

      create table log_orc(
      track_time string,
      url string,
      session_id string,
      referer string,
      ip string,
      end_user_id string,
      city_id string
      )
      row format delimited fields terminated by '\t'
      stored as orc
      tblproperties("orc.compress"="NONE"); -- 设置 orc 存储不使用压缩
      

   2. 向表中加载数据

      insert into table log_orc select * from log_text;
      

   3. 查看表中数据大小

      dfs -du -h /user/hive/warehouse/log_orc/ ;
      # 7.7 M /user/hive/warehouse/log_orc/000000_0
      

4. Parquet

   1. 创建表，存储数据格式为 parquet

      create table log_parquet(
      track_time string,
      url string,
      session_id string,
      referer string,
      ip string,
      end_user_id string,
      city_id string
      )
      row format delimited fields terminated by '\t'
      stored as parquet;
      

   2. 向表中加载数据

      insert into table log_parquet select * from log_text;
      

   3. 查看表中数据大小

      dfs -du -h /user/hive/warehouse/log_parquet/;
      # 13.1 M /user/hive/warehouse/log_parquet/000000_0
      

存储文件的对比总结：ORC > Parquet > textFile

存储文件的查询速度测试：

1. TextFile

   insert overwrite local directory '/opt/module/data/log_text' select substring(url,1,4) from log_text;
   

2. ORC

   insert overwrite local directory '/opt/module/data/log_orc' select substring(url,1,4) from log_orc;
   

3. Parquet

   insert overwrite local directory '/opt/module/data/log_parquet' select substring(url,1,4) from log_parquet;
   

存储文件的查询速度总结：查询速度相近。

五、存储和压缩结合

测试存储和压缩

官网：https://cwiki.apache.org/confluence/display/Hive/LanguageManual+ORC

ORC 存储方式的压缩：

压缩方式

注意：所有关于 ORCFile 的参数都是在 HQL 语句的 TBLPROPERTIES 字段里面出现

1. 创建一个 ZLIB 压缩的 ORC 存储方式

create table log_orc_zlib(
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as orc
tblproperties("orc.compress"="ZLIB");

insert into log_orc_zlib select * from log_text;

dfs -du -h /user/hive/warehouse/log_orc_zlib/ ;
# 2.78 M /user/hive/warehouse/log_orc_none/000000_0

1. 创建一个 SNAPPY 压缩的 ORC 存储方式

create table log_orc_snappy(
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as orc
tblproperties("orc.compress"="SNAPPY");

insert into log_orc_snappy select * from log_text;

dfs -du -h /user/hive/warehouse/log_orc_snappy/;
# 3.75 M /user/hive/warehouse/log_orc_snappy/000000_0

ZLIB 比 Snappy 压缩的还小。原因是 ZLIB 采用的是 deflate 压缩算法。比 snappy 压缩的压缩率高。

1. 创建一个 SNAPPY 压缩的 parquet 存储方式

create table log_parquet_snappy(
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as parquet
tblproperties("parquet.compression"="SNAPPY");

insert into log_parquet_snappy select * from log_text;

dfs -du -h /user/hive/warehouse/log_parquet_snappy/;
# 6.39 MB /user/hive/warehouse/ log_parquet_snappy /000000_0

1. 存储方式和压缩总结

在实际的项目开发当中，hive 表的数据存储格式一般选择：orc 或 parquet。压缩方式一般选择 snappy，lzo。