Windows安装MySQL8.0.40（附带bat脚本引导）

最新推荐文章于 2025-05-13 23:35:58 发布

Rick*

最新推荐文章于 2025-05-13 23:35:58 发布

阅读量906

点赞数 9

CC 4.0 BY-SA版权

文章标签： windows adb mysql

本文链接：https://blog.youkuaiyun.com/GreenhandChen/article/details/144564900

!!!首先需要确保mysql的安装目录必须不带有中文路径!!!

MySQL8.0.40安装

压缩包下载

下载网址MySQL :: Download MySQL Community Serverhttps://dev.mysql.com/downloads/mysql/

文件介绍

文件目录如下（需要包含红框中两个文件）

其中，初始状态下MYSQL文件夹下只包含一个安装压缩包mysql-8.0.40-winx64.zip

操作介绍

右键mysql-install.bat，选择以管理员身份运行

(必须在管理员身份运行，否则无法自动启动MySQL服务)

这个操作将会自动解压安装压缩包mysql-8.0.40-winx64.zip到MYSQL目录下

稍等片刻后，脚本会自动创建root用户并初始化一个随机密码，随后将会自动启动MySQL服务。

2.检查MySQL80服务是否已经正常启动

运行成功截图

在修改MySQL密码完成之前，请不要关闭上述弹窗！否则需要删除MYSQL文件夹下的MySQLServer8.0文件夹，然后重新开始

方法一:需要仔细检查方框中的内容是否一致,如果一致则表示MySQL服务已经启动，

方法二:也可键盘输入win后输入”服务”

打开服务页面找到MySQL80查看其状态是否为正在运行

3.修改MySQL密码

首先保存上面方框中产生的随机密码，

键盘输入win，然后输入”cmd”,点击”以管理员身份运行”

打开后的页面如下：

随后按照下列方框中的步骤执行即可完成mysql修改密码的操作

Windows的bat脚本

@echo off
setlocal
chcp 65001
REM 设置变量
set MYSQL_ZIP=%~dp0MySQL\mysql-8.0.40-winx64.zip
set MYSQL_INSTALL_DIR=%~dp0MySQL\MySQLServer8.0
set MYSQL_DATA_DIR=%MYSQL_INSTALL_DIR%\mysql-8.0.40-winx64\data
set MYSQL_ROOT_PASSWORD=toor3.14159

REM 解压 MySQL ZIP Archive
if not exist "%MYSQL_INSTALL_DIR%" (
    echo 正在解压 MySQL 到 %MYSQL_INSTALL_DIR%...
    powershell -command "Expand-Archive -Path '%MYSQL_ZIP%' -DestinationPath '%MYSQL_INSTALL_DIR%' -Force"
) else (
    echo MySQL 已安装在 %MYSQL_INSTALL_DIR%。
)

REM 初始化数据目录（如果需要）
if not exist "%MYSQL_DATA_DIR%" (
    echo 正在初始化 MySQL 数据目录...
    "%MYSQL_INSTALL_DIR%\mysql-8.0.40-winx64\bin\mysqld" --initialize --console --basedir="%MYSQL_INSTALL_DIR%\mysql-8.0.40-winx64" --datadir="%MYSQL_DATA_DIR%" --lower_case_table_names=1
) else (
    echo MySQL 数据目录已存在。
)

REM 安装 MySQL 服务
echo 正在安装 MySQL 服务...
"%MYSQL_INSTALL_DIR%\mysql-8.0.40-winx64\bin\mysqld" --install MySQL80

REM 启动 MySQL 服务
echo 正在启动 MySQL 服务...
net start MySQL80

REM 配置 root 用户密码（使用 mysql_secure_installation 或直接在 mysql 客户端中）
echo.
echo 请以管理员身份打开一个新终端，手动运行以下命令来配置 root 用户密码：
echo.

echo 第一步：输入 "%MYSQL_INSTALL_DIR%\mysql-8.0.40-winx64\bin\mysql" -u root -p 
echo.

echo 第二步：输入上面产生的随机初始密码
echo.
echo 第三步：输入ALTER USER 'root'@'localhost' IDENTIFIED BY '%MYSQL_ROOT_PASSWORD%';

echo.
echo 请注意第三步最后的分号必须一并复制
echo.
echo 如果出现Query OK, 0 rows affected (0.01 sec)，则说明修改密码完成!
REM 注意：出于安全考虑，建议通过 mysql_secure_installation 来配置 root 用户密码和其他安全选项。

echo.
echo MySQL 安装和配置已完成。
pause

endlocal