王爽《汇编语言》实验12 编写0号中断的处理程序

xmanmanman

于 2018-03-01 15:40:07 发布

阅读量2k

点赞数

分类专栏：汇编语言文章标签：王爽汇编语言实验12 编写0号中断的处理程序

本文链接：https://blog.youkuaiyun.com/BigStone_79/article/details/79413349

版权

汇编语言专栏收录该内容

6 篇文章

订阅专栏

本文介绍了一个简单的8086汇编语言程序，用于处理0号中断，展示如何设置中断向量表并实现特定的中断处理程序。程序通过修改中断向量表来响应除法错误，并在屏幕上显示错误信息。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

assume cs:code
code segment	
start:
	;将Do0程序代码复制至0:200处
	mov ax,cs
	mov ds,ax
	mov si,offset do0
	
	mov ax,0
	mov es,ax
	mov di,200h
	mov cx,offset do0end-offset do0
	cld
	rep movsb
	;设置0号中断向量表指向0:200h
	mov word ptr es:[0*4],200h
	mov word ptr es:[0*4+2],0h
	
	mov ax,4c00h
	int 21h

do0:
	jmp short do0start
	db "Divide error!"
do0start:	
	push ax				;保存现场
	push ds
	push si
	push di
	push cx	
	
	mov ax,cs
	mov ds,ax
	mov si,202h
	
	mov ax,0b800h		;设置显存开始位置
	mov es,ax
	mov di,12*160+34*2	;设置显示位置
	
	mov cx,13			;复制字符串
s:
	mov al,ds:[si]
	mov es:[di],al
	mov byte ptr es:[di+1],07h
	inc si
	add di,2
	loop s
							
	pop cx				;恢复现场
	pop di
	pop si
	pop ds
	pop ax
	
	mov ax,4c00h                    ;正常应使用iret回到中断结束程序处，实验要求返回DOS，所以调用int 21h
	int 21h
do0end:nop
code ends
end start