中语言超酷特性之 --- 便捷定义数据二

中语言计算技术研究与发展联盟

舒生羽  wzyorg@gmail.com

    在这篇文章里，我们继续介绍中语言对便捷定义有着通用复杂结构的数据的支持。

    我们将在示例里面使用三种通用数据结构：

    1、集这是通常的集合的数据结构，佢对应于C++里面std空间内的set。

佢支持插进等方法。

    2、映这是通常的映射的数据结构，佢对应于C++里面std空间内的map。

    佢支持插进等方法。

    3、双这是通常的对子的数据结构，佢对应于C++里面std间内的pair，佢有两个数据成员：之一、之二。

    另外我们还将使用到中语言标准库内“有名物”这一类，佢可用来支持定义有名变量，其具体内容我俚将在其它文章介绍。

    我们将通过使用这些数据来表达《水浒传》里面若干人物的一些数据信息的方式来构造出一个示例程序，这是很有趣的，而且较以往更加使用汉字，也就是将数字几乎完全用汉字来表示。从中我们可以再次看到中语言的高度可读性，并从理性上认同中语言项目组就汉语得到的“汉语是一门天然的计算语言和一套天然的符号推演系统”这样一个基本结论的确是对事实的揭露。

    下面是程序文本：

来 朴库.标准进出;
来 华库.集;
来 华库.映;
来 华库.有名;


名{
    用 宿 准;
    好汉: 类(公 有名物)=
    公{
        座次: 元;
        生: (座次: 元)=
        [
            座次 (座次);
        ]
        {
        }

        禀 生+: ();

        作 < : 定 (别人: <定  好汉>-牵)->(仪)=
        {
            归 己..座次 < 别人.座次;
        }

    };
}
道: ()->()=
{
    武松, 李逵, 鲁智深, 林冲: 好汉= 0#一四, 0#二二, 0#一三, 0#六;
    梁山先锋队 := [.]{武松};
    梁山先锋队.插进(武松);
    梁山先锋队.插进(李逵);
    梁山先锋队.插进(鲁智深);
    打印文套("梁山先锋队名单:\n");
    /: (好汉集: <好汉>-集)->()=
    {
        周(某 @ 好汉集)
            打印文套("排名第%3d好汉 %s\n", 某.座次, 某.名字());
    }(梁山先锋队);
    顾大嫂, 孙二娘, 扈三娘, 孙新, 王英, 张青: 好汉= 0#一零一, 0#一零三, 0#五九, 0#一零零, 0#五八, 0#一零二;
    水浒鸳鸯配 := [::]{顾大嫂 : 张青,  扈三娘 : 王英 };
    孙新 -> 水浒鸳鸯配[孙二娘];
    //我们还可以这样插入宋江与阎婆惜,西门庆与潘金莲
    宋江, 西门庆, 潘金莲, 阎婆惜: 好汉= 0#一, 0#一一零, 0#一一一, 0#一零九;
    水浒鸳鸯配.插进([:]{阎婆惜, 宋江});
    水浒鸳鸯配.插进([:]{潘金莲, 西门庆});
    打印文套("水浒鸳鸯配名单:\n");
    /: (夫妻们: <好汉, 好汉>-映)->()=
    {
        周(某 @ 夫妻们)
            打印文套("妻 第%3d好汉 %s : 夫 第%3d好汉 %s\n", 某.之一.座次, 某.之一.名字(), 某.之二.座次, 某.之二.名字());
    }(水浒鸳鸯配);
}

    程序的执行结果如下：

 

官网文件参考：

http://www.zhongyuyan.org/ZStudy/超酷程序/便捷定义数据二.html