洛谷P1908 逆序对（树状数组）

最新推荐文章于 2025-05-22 14:34:13 发布

hxxxx!

最新推荐文章于 2025-05-22 14:34:13 发布

阅读量660

点赞数

CC 4.0 BY-SA版权

分类专栏：树状数组快排

本文链接：https://blog.youkuaiyun.com/zhanghaoxian1/article/details/72461390

快排同时被 2 个专栏收录

21 篇文章

订阅专栏

树状数组

16 篇文章

订阅专栏

本文介绍了一种通过树状数组高效统计逆序对数量的方法。针对给定的正整数序列，采用快速排序配合树状数组来计算逆序对总数。此算法避免了传统O(n^2)暴力解法的效率瓶颈。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

逆序对

题目描述
猫猫TOM和小老鼠JERRY最近又较量上了，但是毕竟都是成年人，他们已经不喜欢再玩那种你追我赶的游戏，现在他们喜欢玩统计。最近，TOM老猫查阅到一个人类称之为“逆序对”的东西，这东西是这样定义的：对于给定的一段正整数序列，逆序对就是序列中ai>aj且i<j的有序对。知道这概念后，他们就比赛谁先算出给定的一段正整数序列中逆序对的数目。

输入输出格式

输入格式：
第一行，一个数n，表示序列中有n个数。

第二行n个数，表示给定的序列。

输出格式：
给定序列中逆序对的数目。

分析：通过暴力O(n^2)我们可以知道只有加一和求和两种操作，所以我们使用树状数组维护排序后后面比当前位置小的数的个数，边维护边求和。

代码

const
  maxn=50000;
var
  a,b,c:array[0..maxn] of longint;
  i,n,ans:longint;

procedure qsort(l,r:longint);
var
  i,j,k:longint;
begin
  if l>=r then exit;
  i:=l;j:=r;
  k:=a[(l+r) div 2];
  repeat
    while a[i]>k do inc(i);
    while a[j]<k do dec(j);
    if i<=j then
      begin
        a[0]:=a[i];a[i]:=a[j];a[j]:=a[0];
        b[0]:=b[i];b[i]:=b[j];b[j]:=b[0];
        inc(i);dec(j);
      end;
  until i>j;
  qsort(l,j);qsort(i,r);
end;

procedure insert(x:longint);
begin
  while x<=n do
    begin
      inc(c[x]);
      x:=x+(x and -x);
    end;
end;

function count(x:longint):longint;
var
  s:longint;
begin
  s:=0;
  while x>0 do
    begin
      inc(s,c[x]);
      x:=x-(x and -x);
    end;
  exit(s); 
end;

begin
  readln(n);
  for i:=1 to n do
    begin
      read(a[i]);
      b[i]:=i;
    end;
  qsort(1,n);
  for i:=1 to n do
    begin
      inc(ans,count(b[i]));
      insert(b[i]);
    end;
  writeln(ans);
end.