poj2777 Count Color(线段树)

Count Color

Description

Chosen Problem Solving and Program design as an optional course, you are required to solve all kinds of problems. Here, we get a new problem. 

There is a very long board with length L centimeter, L is a positive integer, so we can evenly divide the board into L segments, and they are labeled by 1, 2, ... L from left to right, each is 1 centimeter long. Now we have to color the board - one segment with only one color. We can do following two operations on the board: 

1. "C A B C" Color the board from segment A to segment B with color C. 
2. "P A B" Output the number of different colors painted between segment A and segment B (including). 

In our daily life, we have very few words to describe a color (red, green, blue, yellow…), so you may assume that the total number of different colors T is very small. To make it simple, we express the names of colors as color 1, color 2, ... color T. At the beginning, the board was painted in color 1. Now the rest of problem is left to your. 

Input

First line of input contains L (1 <= L <= 100000), T (1 <= T <= 30) and O (1 <= O <= 100000). Here O denotes the number of operations. Following O lines, each contains "C A B C" or "P A B" (here A, B, C are integers, and A may be larger than B) as an operation defined previously.

Output

Ouput results of the output operation in order, each line contains a number.

Sample Input

2 2 4
C 1 1 2
P 1 2
C 2 2 2
P 1 2

Sample Output

2
1

题意：在长度为L的线段上涂色，给出两种操作：C A B C表示给[A,B]涂上颜色C，P A B表示询问区间[A,B]有多少种颜色。

分析：与zoj1610差不多。

代码

const
  maxn=1000000;
type
  tnode=record
    a,b:longint;
end;
var
  tree:array[0..maxn] of tnode;
  cover:array[0..maxn] of longint;
  fl:array[0..100] of boolean;
  m,t,n,ans,i,x,y,c:longint;
  ch:char;


procedure create(p:longint);
var
  m:longint;
begin
  cover[p]:=1;
  if tree[p].a=tree[p].b then exit;
      m:=(tree[p].a+tree[p].b) div 2;
      tree[p*2].a:=tree[p].a;
      tree[p*2].b:=m;
      tree[p*2+1].a:=m+1;
      tree[p*2+1].b:=tree[p].b;
      create(p*2);
      create(p*2+1);
end;


procedure insert(p,x,y:longint);
var
  m:longint;
begin
  if (x=tree[p].a) and (y=tree[p].b)
    then cover[p]:=c
    else begin
           if cover[p]=c then exit;
           if cover[p]<>-1 then
             begin
               cover[p*2]:=cover[p];
               cover[p*2+1]:=cover[p];
               cover[p]:=-1;
             end;
           m:=(tree[p].a+tree[p].b) div 2;
           if y<=m then insert(p*2,x,y)
           else if x>m then insert(p*2+1,x,y)
           else begin
                  insert(p*2,x,m);
                  insert(p*2+1,m+1,y);
                end;
         end;
end;


procedure find(p,x,y:longint);
var
  m:longint;
begin
  if cover[p]<>-1 then
    begin
      fl[cover[p]]:=true;
      exit;
    end
    else begin
           m:=(tree[p].a+tree[p].b) div 2;
           if y<=m then find(p*2,x,y)
             else if x>m then find(p*2+1,x,y)
             else begin
                    find(p*2,x,m);
                    find(p*2+1,m+1,y);
                  end;
         end;
end;


begin
  while not eof do
    begin
      readln(m,t,n);
      tree[1].a:=1;
      tree[1].b:=m;
      create(1);
      for i:=1 to n do
        begin
          read(ch);
          if ch='C'
            then begin
                   readln(x,y,c);
                   if x<y then insert(1,x,y) else insert(1,y,x);
                 end
            else begin
                   ans:=0;
                   fillchar(fl,sizeof(fl),false);
                   readln(x,y);
                   if x<y then find(1,x,y) else find(1,y,x);
                   for x:=1 to t do
                     if fl[x] then inc(ans);
                   writeln(ans);
                 end;
        end;
    end;
end.