电子计数跳绳原型V1.1

原创已于 2025-07-03 00:36:43 修改 · 448 阅读

10 ·

CC 4.0 BY-SA版权

文章标签：

#硬件工程 #经验分享

于 2025-07-03 00:35:00 首次发布

引子

电子计数跳绳原型-优快云博客文章浏览阅读439次，点赞3次，收藏8次。摘要：作者尝试用3D打印和编程实现跳绳计数功能，采用Arduino Nano和两个霍尔传感器搭建原型系统。通过调试程序（含去抖动处理）和万用表检测，最终成功实现旋转计数。实验发现AI生成的初版代码仍需人工优化，并总结了老款Nano需选旧Bootloader的上传问题。未来计划改用ESP32-C3开发板，并进一步研究PCB设计，最终实现完整的跳绳手柄定制开发。（149字）https://blog.youkuaiyun.com/zfive5/article/details/149004730?spm=1001.2014.3001.5501增加一个屏幕，之前esp32还没有搞好，只能ariduino nano+led的方案继续，直接上成品图

正文

主机设备是一块网上购买的20多元nano+led一体设备

代码

#include <Arduino.h>
#include <Wire.h>
#include <U8g2lib.h>

// 根据你的屏幕型号选择构造函数
U8G2_SSD1306_128X64_NONAME_F_HW_I2C u8g2(U8G2_R0, U8X8_PIN_NONE);


// 模拟引脚定义（两个传感器平分圆，相距180度）
const int hallA = A0;   // 霍尔传感器 A 接 A0
const int hallB = A1;   // 霍尔传感器 B 接 A1
 
// 参数设置
const int threshold = 410;      // 磁场阈值（根据实际校准）
const int debounceDelay = 5;    // 去抖动时间（毫秒）
 
// 变量声明
long totalRevolutions = 0;       // 总圈数（整数）
int lastTriggered = 0;           // 上次触发的传感器（0: 无，1: A，2: B）
 
void setup() {
  pinMode(hallA, INPUT);
  pinMode(hallB, INPUT);

  u8g2.begin();
  u8g2.clearBuffer();

  // 设置大号字体
  u8g2.setFont(u8g2_font_logisoso32_tr);   // 清晰数字字体

  // 显示一个大数字
  u8g2.setCursor(10, 40);  // x=10, y=40
  u8g2.print("0");        // 假设这是温度值
  u8g2.sendBuffer();

}
 
void loop() {
  static long lastRev = -1;
 
  if (totalRevolutions != lastRev) {

    // 显示一个大数字
    u8g2.setCursor(10, 40);  // x=10, y=40
    u8g2.clearBuffer();
    u8g2.print(String(totalRevolutions));        // 假设这是温度值
    u8g2.sendBuffer();
 
    lastRev = totalRevolutions;
  }
 
  checkHall();  // 检测并更新状态
 
  delay(10);  // 控制刷新频率
}
 
// 获取当前状态（转换为高低电平）
int getState(int pin) {
  int val = analogRead(pin);
  return (val < threshold) ? LOW : HIGH;
}
 
// 检测并处理触发事件
void checkHall() {
  static unsigned long lastTime = 0;
  unsigned long now = millis();
 
  if (now - lastTime < debounceDelay) return;
  lastTime = now;
 
  int stateA = getState(hallA);
  int stateB = getState(hallB);
 
  // 判断是哪一个传感器被触发
  if (stateA == LOW && stateB == HIGH) {
    // A 被触发
    if (lastTriggered == 2) {
      // B → A = 完成一圈
      totalRevolutions++;
    }
    lastTriggered = 1;
  } else if (stateA == HIGH && stateB == LOW) {
    // B 被触发
    if (lastTriggered == 1) {
      // A → B = 半圈（暂不计数）
    }
    lastTriggered = 2;
  } else if (stateA == LOW && stateB == LOW) {
    // A 和 B 同时触发 -> 中间位置，忽略
    lastTriggered = 0;
  }
}