[USACO 1.2.3] Name That Number

最新推荐文章于 2024-12-27 21:04:33 发布

原创最新推荐文章于 2024-12-27 21:04:33 发布 · 505 阅读

0 ·

CC 4.0 BY-SA版权

文章标签：

#output #input #insert #pascal #file #手机

USACO 专栏收录该内容

38 篇文章

订阅专栏

这是一篇关于USACO比赛的编程问题解析，内容涉及将给定的连续数字转化为母牛可理解的名字。程序要求接收一个1到12位的数字，并利用标准手机键盘布局将其转换为对应的文字。例如，输入4734，输出为"GREG"。解题策略包括枚举和使用哈希表，确保输出的名字按字典序排列。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

[题目描述]

Name That Number

命名那个数字

在威斯康辛州牛大农场经营者之中，都习惯于请会计部门用连续数字给母牛打上烙印。
但是,母牛用手机时并没感到这个系统的便利,它们更喜欢用它们喜欢的名字来呼叫它们的同伴，而不是用像这个的语句"C'mon, #4734, get along."。
请写一个程序来帮助可怜的牧牛工将一只母牛的烙印编号翻译成一个可能的名字。
因为母牛们现在都有手机了，使用那标准的按键的排布来把收到从数目翻译到文字:( 除了为之外 "Q" 和 "Z")

          2: A,B,C     5: J,K,L    8: T,U,V
          3: D,E,F     6: M,N,O    9: W,X,Y
          4: G,H,I     7: P,R,S

可接受的名字都被放在这样一个叫作"dict.txt" 的文件中，它包含一连串的少于 5,000个可接受的牛名字。 (所有的名字都是大写的)
收到母牛的编号返回那些能从编号翻译出来并且在字典中的名字。
举例来说,编号 4734 能产生的下列各项名字:

GPDG GPDH GPDI GPEG GPEH GPEI GPFG GPFH GPFI GRDG GRDH GRDI
GREG GREH GREI GRFG GRFH GRFI GSDG GSDH GSDI GSEG GSEH GSEI
GSFG GSFH GSFI HPDG HPDH HPDI HPEG HPEH HPEI HPFG HPFH HPFI
HRDG HRDH HRDI HREG HREH HREI HRFG HRFH HRFI HSDG HSDH HSDI
HSEG HSEH HSEI HSFG HSFH HSFI IPDG IPDH IPDI IPEG IPEH IPEI
IPFG IPFH IPFI IRDG IRDH IRDI IREG IREH IREI IRFG IRFH IRFI
ISDG ISDH ISDI ISEG ISEH ISEI ISFG ISFH ISFI

碰巧，81个中只有一个"GREG"是有效的(在字典中)。

Challenge One
写一个程序来对给出的编号打印出所有的有效名字，如果没有则输出"NONE'' 。
编号可能有12位数字。

PROGRAM NAME: namenum

INPUT FORMAT
单独的一行包含一个编号(长度可能从1到12)。

SAMPLE INPUT (file namenum.in)
4734

OUTPUT FORMAT
以字典顺序输出一个有效名字的不负列表，一行一个名字。

SAMPLE OUTPUT (file namenum.out)
GREG

[解题思路]

枚举+Hash

最多12个数字，每个数字对应3个字符，枚举量为3^12。重点就是如何判断该名字是否合法了，由于名册是有序的，可以用二分，也可以用Hash，找到一个合法的名字就输出，因为是顺序枚举，所以一定是按字典序大小排列的。

[Code]

x数组是名册里的名字。

{
ID: zane2951
PROG: namenum
LANG: PASCAL
}

program namenum;
const
   word:array['2'..'9',1..3] of char=(('A','B','C'),('D','E','F'),('G','H','I'),
                                      ('J','K','L'),('M','N','O'),('P','R','S'),
                                      ('T','U','V'),('W','X','Y'));
   mo=100007;

var
   node,ed:array[0..mo+11] of int64;
   w:array[0..mo+11] of ansistring;
   e,len,i:longint;
   s,cs:ansistring;
   ko:boolean;

//----------find-----------
function find(hash:int64; s:ansistring):boolean;
var
   ce:longint;

begin
   ce:=node[hash];
   while ce<>0 do
      begin
         if w[ce]=s then exit(true);
         ce:=ed[ce];
      end;
   exit(false);
end;

//---------insert----------
procedure insert(s:ansistring);
var
   l,i:longint;
   ce:int64;

begin
   l:=length(s); ce:=1;
   for i:=1 to l do ce:=(ce+ord(s[i]))*26 mod mo;
   if not find(ce,s) then
      begin
         inc(e);
         ed[e]:=node[ce]; node[ce]:=e; w[e]:=s;
      end;
end;

//-----------dfs-----------
procedure dfs(dp:longint; cs:ansistring; hash:int64);
var
   i:longint;

begin
   if dp>len then
      begin
         if find(hash,cs) then begin writeln(cs); ko:=true; end;
         exit;
      end;
   for i:=1 to 3 do dfs(dp+1,cs+word[s[dp],i],(hash+ord(word[s[dp],i]))*26 mod mo);
end;

//----------main-----------
begin
   assign(input,'namenum.in'); reset(input);
   assign(output,'namenum.out'); rewrite(output);
   fillchar(w,sizeof(w),0); e:=0;
   for i:=1 to 4617 do insert(x[i]);
   readln(s);
   len:=length(s);
   cs:=''; ko:=false;
   dfs(1,cs,1);
   if not ko then writeln('NONE');
   close(input); close(output);
end.