实现进程间数据交换的两种方法和应用_用127.0.0.1实现程序之间的数据交换-优快云博客

本文介绍两种Windows进程间数据交换方法：通过剪贴板和直接内存读取。使用Delphi语言实现具体应用案例。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

Windows操作系统是一个多任务系统，每个任务都有相应的进程对应。熟悉windows系统的用户知道，每个进程都有自己独立的内存地址和内存空间。这对进程间之间的数据相互访问和相互交换带来一定的不便，但是在实际应用中有时要在进程间进行数据交换。windows系统提供了许多方法实现进程间的数据交换，比如我们可以通过磁盘文件来进行交换，这实际是最简单可行的办法，但运行速度大打折扣，特别是对于大批量数据交换时。另外我们可以通过Windows系统提供的CreateFileMaping、OpenFileMapping、MapViewofFile等API函数来实现进程间的数据交换，但实现方法相对复杂。

本文将介绍另外两种进程间数据交换的方法，一种是通过剪贴板的进程数据交换方法，另一种是直接内存读取的进程数据交换方法。最后将用Delphi语言举例加以实现应用。

一、通过剪贴板的进程数据交换方法

剪贴板是windows系统专门提供用来不同应用程序之间的数据交换，用户只要通过“复制”和“粘帖”两个动作就可以实现应用程序之间的数据交换。用户可以自定义剪贴板格式实现数据交换的目的。

其方法步骤为：

1、数据发送进程向剪贴板“复制”用户自定义的数据内容

2、数据发送进程向数据接受进程发送数据交换的消息。

3、数据接受进程收到消息以后向剪贴板“粘贴”用户自定义的数据内容。

这种方法的实现过程如图一所示：

该方法涉及到的重要API函数主要有：

1、RegisterClipboardFormat

这个函数是向系统剪贴板注册新的剪贴板数据格式其函数调用格式为：

     
     UINT RegisterClipboardFormat(
    LPCTSTR lpszFormat 	  // 新剪贴板数据格式的名称
   );

如果该名称的剪贴板格式已经注册函数返回已经的标示号，否则函数返回一个新的标示号。

2、GlobalAlloc、GlobalLock

这两个函数前者是用于从当前进程的内存空间分配一定字节数的内存，后者是对指定的内存加锁。它们的函数调用格式分别为：

     
     HGLOBAL GlobalAlloc(
    UINT uFlags,  	//分配到的内存属性
    DWORD dwBytes 	// 需要内存分配的空间大小
   );
LPVOID GlobalLock(
    HGLOBAL hMem  	// 需要加锁的内存“句柄”
   );

3、Clipboard的Open、SetAsHandle、Close、GetAsHandle

这四个函数是Delphi语言Clipboard全局变量提供专门用于对剪贴板数据“复制”和“粘帖”动作所要用到的函数。在Clipbrd.pas单元中实现。其函数格式略。

二、直接内存读取的进程数据交换方法

这种方法是通过Windows系统一系列API函数调用直接读取另一个进程的内存，来实现数据交换的目的。

其方法步骤为：

1、数据发送方进程数据接受方进程发送数据交换的消息，Wparam参数值为数据发送方进程标示号，Lparam参数值为要发送的数据的地址。

2、数据接受方进程收到消息以后直接读取数据发送方进程内存地址的数据。

这种方法的实现过程如图二所示：

该方法涉及的重要API函数主要有：

1、GetCurrentProcessId

这个函数主要获取当前运行进程的进程标示号，其函数格式为：

     
     DWORD GetCurrentProcessId(VOID)

2、openProcess

这个函数主要获得一个已经运行的进程的“进程句柄”，以便在另外的API函数调用。其函数格式为：

     
     HANDLE OpenProcess(
    DWORD dwDesiredAccess,	// 要打开的进程的访问模式
    BOOL bInheritHandle,	// 该进程句柄是否在子线程中继承
    DWORD dwProcessId 	// 进程的标示号
   );

3、ReadProcessMemory

这个函数是直接内存读取的进程数据交换方法最核心的一个函数，它实现从另一个进程中读取内存数据。其函数格式为：

     
     BOOL ReadProcessMemory(
    HANDLE hProcess,  	    //进程句柄
    LPCVOID lpBaseAddress,	// 要读取内存的起始地址
    LPVOID lpBuffer,	       //存放读取的数据的变量
    DWORD nSize,	           //需要读取的字节数
    LPDWORD lpNumberOfBytesRead 	// 实际读取到的字节数
   );

三、两种进程数据交换方法的应用举例

为了更加详细地介绍上述两种方法，下面利用Delphi语言结合实际的例子来阐述它的应用。该例子分别用通过剪贴板的进程数据交换的方法和直接内存读取的进程数据交换方法实现两个进程间的交换一个记录数据，该记录的数据格式为：

     
     TFriend=packed record
     name    :array[1..8] of char;
     age     :byte;
     address :array[1..30] of char;
  end;

另外定义两条消息和几个需要用到的常量：

     
     1．WM_Datasend_byClpbrd=WM_user+1000;  //用于通过剪贴板的进程数据交换的方法的消息；
2．WM_DataSend_byMemory=WM_user+1001;// 直接内存读取的进程数据交换方法的消息；
3．receivewindowcaption='DataReceiver';     //接收数据进程窗口的标题；
4．receivewindowclassname='Data Receive Window';//接受数据进程窗口的类别名称；
5．userDefineformat='process data exchange'; //自定义剪贴板数据格式名称；

以上常量和记录结构是发送进程和接受进程的两个程序都要用到的数据。可以单独存放在一个文件中用uses引用，或用{$I }的方法引用。

(一)数据发送进程程序的实现

1、在Delphi的IDE环境中新建Application

2、在Form1中加入一个Tspinedit、两个Tedit和两个Tbutton控件(分别为Button1和button2)，两个Edit控件分别供输入姓名和地址，SpinEdit控件供输入年龄。

3、重载Button1的onClick程序用于剪贴板数据交换，如下所示：

     
     procedure TForm1.Button1Click(Sender: TObject);
var
   wnd     :Hwnd;
   Friend  :TFriend;
   hmem    :Thandle;
   datapointer :pointer;
   CF_User  :Uint;
begin
   //寻找数据接受进程的窗口
   wnd:=findwindow(receivewindowclassname,receivewindowcaption);
   //如果找到了向剪贴板复制数据并且向数据接受进程发送消息
   if wnd<>0 then  
begin
   //申请内存
         hmem:=globalAlloc(GMEM_MOVEABLE,sizeof(friend));
         //给记录赋值
         strpcopy(@friend.name,edit1.text);
         friend.age:=byte(spinedit1.Value);
         strpcopy(@friend.address,edit2.text);
         //获取申请到的内存地址并且把记录的值导入内存
         DataPointer := GlobalLock(hmem);
         //把记录数据复制到Global内存中
         move(friend,datapointer^,sizeof(friend));
         //注册或获取新的剪贴板数据格式标号
         CF_User:=registerclipboardformat(userdefineformat);
         //向剪贴板复制数据
         clipboard.Open;
         clipboard.SetAsHandle(CF_USER,hmem);
         clipboard.Close;
         //向接收进程窗口发送消息
         sendmessage(wnd,WM_Datasend_byClpbrd,0,0);
      end;
end;

4、重载button2的OnClick程序用于直接内存读取的数据交换，如下所示：

     
     procedure TForm1.Button2Click(Sender: TObject);
var
   wnd       :Hwnd;
   Friend    :TFriend;
Begin
   //寻找数据接受进程的窗口
   wnd:=findwindow(receivewindowclassname,receivewindowcaption);
   //如果找到了向数据接收进程窗口发送消息
   if wnd<>0 then
begin
   //对记录赋值
         strpcopy(@friend.name,edit1.text);
         friend.age:=byte(spinedit1.Value);
         strpcopy(@friend.address,edit2.text);
         //发送消息，把发送进程的进程标示号作为Wparam
         //把记录地址作为Lparam进行传递
       sendmessage(wnd,WM_DataSend_byMemory,
getcurrentprocessID,lparam(@Friend));
      end;
end;

5、保存、编译、运行

(二)数据接受进程程序的实现

1、在Delphi的IDE环境新建Application；

2、在Form1中加入三个Tedit控件，接受发送过来的数据；

3、重载Form1的CreateParams程序，重新定义Form1的类，程序如下：

     
     procedure TForm1.CreateParams(var Params: TCreateParams);
    begin
      inherited CreateParams(Params);
      params.Caption:=receivewindowcaption;
      Params.WinClassName :=receivewindowclassname;
    end;

4、重载在Form1的wndproc程序接受两种方法发送过来的数据，程序如下：

     
     procedure Tform1.wndproc(var message:Tmessage);
   var
    processhnd   :Thandle;
      Friend       :TFriend;
numread     :dword;
hmem       :Thandle;
clipdata      :pointer;
CF_User     :Uint;
        Begin
           Case message.msg of
               //处理剪贴板方式发送过来的消息
WM_Datasend_byClpbrd:
   Begin
     //注册或获取新的剪贴板数据格式标号
     CF_User:= registerclipboardformat(userdefineformat);
     if clipboard.HasFormat(CF_User) then
        begin
           //获取剪贴板的内容，并且分别赋值给三个Edit
           hmem:=clipboard.GetAsHandle(CF_user);
           clipdata:=globallock(hmem);
           if clipdata<>nil then
              begin
                 move(clipdata^,Friend,sizeof(Friend));
                 edit1.text:=Friend.name;
                 edit2.text:=inttostr(Friend.age);
                 edit3.text:=Friend.address;
              end;
        end;
       message.Result:=1;
   End;
//处理直接内存读取发送过来的消息
               WM_DataSend_byMemory:
                  Begin
                     //获取发送进程的“进程句柄”，设置访问模式为“读”
                     processhnd:=openprocess(PROCESS_VM_READ,
false,message.WParam);
                     //读取发送进程的内存数据
  readprocessmemory(processhnd,
ptr(message.lparam),
@friend,sizeof(friend),numread);
edit1.text:=Friend.name;
    edit2.text:=inttostr(Friend.age);
    edit3.text:=Friend.address;
     closehandle(processhnd);
     message.result:=1;
                  End;
Else
   //对于其它消息依然按照原来的方法进行消息处理
Inherited wndproc(message);
        End;

5、保存、编译、运行

到这里为止已经实现上述进程间记录数据的交换的两种方法。运行结果如图三所示：