解决wmsys.wm_concat在11G不兼容问题

最新推荐文章于 2025-05-13 14:25:08 发布

转载最新推荐文章于 2025-05-13 14:25:08 发布 · 6.1k 阅读

orcale 专栏收录该内容

17 篇文章

订阅专栏

本文介绍了一种使用 Oracle 数据库的自定义类型 zh_concat_im 实现字符串聚合的方法。此类型通过 ODCIAGGREGATE 接口定义了初始化、迭代、终止及合并操作，从而能够高效地将一组 VARCHAR2 类型的数据聚合为一个由逗号分隔的字符串。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

--type_bodies
CREATE OR REPLACE TYPE BODY zh_concat_im
 IS
   STATIC FUNCTION ODCIAGGREGATEINITIALIZE(SCTX IN OUT zh_concat_im)
   RETURN NUMBER 
  IS
   BEGIN
     SCTX := zh_concat_im(NULL) ;
     RETURN ODCICONST.SUCCESS;
   END;
   MEMBER FUNCTION ODCIAGGREGATEITERATE(SELF IN OUT zh_concat_im,
           P1 IN VARCHAR2) 
  RETURN NUMBER 
  IS
   BEGIN
     IF(CURR_STR IS NOT NULL) THEN 
      CURR_STR := CURR_STR || ',' || P1;
     ELSE
       CURR_STR := P1;
     END IF;
     RETURN ODCICONST.SUCCESS;
   END;
   MEMBER FUNCTION ODCIAGGREGATETERMINATE(SELF IN zh_concat_im,
                                  RETURNVALUE OUT VARCHAR2,
                                  FLAGS IN NUMBER)
     RETURN NUMBER 
  IS
   BEGIN
     RETURNVALUE := CURR_STR ;
     RETURN ODCICONST.SUCCESS;
   END;
   MEMBER FUNCTION ODCIAGGREGATEMERGE(SELF IN OUT zh_concat_im, 
                                   SCTX2 IN zh_concat_im) 
  RETURN NUMBER 
  IS
   BEGIN
     IF(SCTX2.CURR_STR IS NOT NULL) THEN 
      SELF.CURR_STR := SELF.CURR_STR || ',' || SCTX2.CURR_STR ;
     END IF;
     RETURN ODCICONST.SUCCESS;
   END;
 END;


--types
CREATE OR REPLACE TYPE zh_concat_im
AUTHID CURRENT_USER AS OBJECT
 (
   CURR_STR VARCHAR2(32767),
   STATIC FUNCTION ODCIAGGREGATEINITIALIZE(SCTX IN OUT zh_concat_im) RETURN NUMBER,
   MEMBER FUNCTION ODCIAGGREGATEITERATE(SELF IN OUT zh_concat_im, 
               P1 IN VARCHAR2) RETURN NUMBER,
   MEMBER FUNCTION ODCIAGGREGATETERMINATE(SELF IN zh_concat_im,
                                  RETURNVALUE OUT VARCHAR2,
                                  FLAGS IN NUMBER)
                      RETURN NUMBER,
   MEMBER FUNCTION ODCIAGGREGATEMERGE(SELF IN OUT zh_concat_im, 
                    SCTX2 IN  zh_concat_im) RETURN NUMBER
 );


--function:

CREATE OR REPLACE FUNCTION zh_concat(P1 VARCHAR2)
RETURN VARCHAR2 AGGREGATE USING zh_concat_im ;