《开发效率》IDEA使用Generate POJOs.groovy自动生成数据库实体类

1.使用IDEA连接数据库

参考：https://blog.youkuaiyun.com/qq_45344586/article/details/131493510

2.修改自定义生成脚本

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.text.SimpleDateFormat

/* 关键点请看 TODO */


/* TODO 项目包名 */
packageName = "com.改成你自己的包名;"

typeMapping = [
        (~/(?i)int/)                      : "long",
        (~/(?i)float|double|decimal|real/): "double",
        (~/(?i)datetime|timestamp/)       : "String",
        (~/(?i)date/)                     : "String",
        (~/(?i)time/)                     : "String",
        (~/(?i)/)                         : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true)
    def fields = calcFields(table)
    /* TODO 需要设置编码，否则，导出的脚本会有乱码*/
    new File(dir, className + ".java").withPrintWriter("utf-8") { out -> generate(out, className, fields,table) }
}

def generate(out, className, fields,table) {
    out.println "package $packageName"
    /* TODO 手动添加项目需要的包*/
    out.println "import com.baomidou.mybatisplus.annotation.IdType;"
    out.println "import com.baomidou.mybatisplus.annotation.TableField;"
    out.println "import com.baomidou.mybatisplus.annotation.TableId;"
    out.println "import com.baomidou.mybatisplus.annotation.TableName;"
    out.println "import io.swagger.annotations.ApiModel;"
    out.println "import io.swagger.annotations.ApiModelProperty;"
    out.println "import lombok.*;"
    out.println ""
    /* TODO 添加注释*/
    out.println "/**\n" +
            " * @Description \n" +
            " * @Author  xx\n" +
            " * @Date: "+new SimpleDateFormat("yyyy-MM-dd HH:mm:ss").format(new Date()) +"\n" +
            " */"
    out.println ""
    /* TODO
        1.添加@Data 注解,使用lombok,所以不生成 get/set 方法
    */
    out.println "@Data"
    out.println "@AllArgsConstructor"
    out.println "@NoArgsConstructor"
    out.println "@ToString"
    out.println "@Builder"
    out.println "@TableName(\""+table.getName()+"\")"

    /* TODO 添加表名和表说明*/
    out.println "@ApiModel(value=\" " + table.getName()+" \", description=\" "+table.getComment()+" \")"
    out.println "public class $className {"
    out.println ""
    fields.each() {
        /* TODO 添加字段属性和注解*/
        out.println "  @TableField(value = \""+it.commoent+"\")"
        out.println "  @ApiModelProperty(value = \""+it.commoent+"\")"
        out.println "  private ${it.type} ${it.name};"
        out.println " \n"
    }
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        fields += [[
                           /* TODO name:字段名 type:字段类型 commoent:字段说明*/
                           name : javaName(col.getName(), false),
                           type : typeStr,
                           commoent: col.getComment()]]
    }
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}