asp中用XMLHTTP Post获取IP所在地址

最新推荐文章于 2024-08-12 09:38:18 发布

原创最新推荐文章于 2024-08-12 09:38:18 发布 · 2.9k 阅读

0 ·

CC 4.0 BY-SA版权

文章标签：

#asp #function

本文介绍如何使用XMLHTTP请求从http://www.ip138.com/获取IP地址信息并解决中文乱码问题。通过调整responseText为responseBody及采用特定函数进行字符集转换，实现了正确显示中文。

最近想通过XMLHttp提交IP地址到http://www.ip138.com/ 以获取ip所在地址。但是一开始在使用XMLHTTP的responseText获取返回值时，取得的返回页面中的中文全部变成了乱码，后来改为responseBody后正常显示。

<%
'转换为字符串函数
Function BytesToBstr(body,Cset)
dim objstream
set objstream = Server.CreateObject("adodb.stream")
objstream.Type = 1
objstream.Mode =3
objstream.Open
objstream.Write body
objstream.Position = 0
objstream.Type = 2
objstream.Charset = Cset
BytesToBstr = objstream.ReadText
objstream.Close
set objstream = nothing
End Function

'提交IP到http://www.ip138.com/ips8.asp，并得到查询的地址
Function returnIPAddress(ip)
dim xmlHttp
set xmlHttp=server.createobject("MSXML2.XMLHTTP")
str = "ip="&ip&"&action=2" 'str为POST的数据，既要查询的表单的内容提交。
xmlHttp.open "POST","http://www.ip138.com/ips8.asp",false
xmlHttp.setRequestHeader"Content-Length",Len(str)
xmlHttp.setRequestHeader"CONTENT-TYPE","application/x-www-form-urlencoded"
xmlHttp.send(str)
tempstr=BytesToBstr(xmlHttp.responseBody,"GB2312") '使用responseBody方法获取返回值
tempstr=left(tempstr,instr(1,tempstr,"</li><li>查询结果2：",1)-1)
tempstr=mid(tempstr,instr(1,tempstr,"本站主数据：",1)+6)
returnIPAddress=tempstr
End Function

'取得访问用户的IP
visitorIP = Request.ServerVariables("HTTP_X_FORWARDED_FOR")
If Trim(visitorIP)="" Then visitorIP = request.servervariables("remote_addr")

response.write("您是来自："& returnIPAddress(visitorIP) &"  的用户")
%>