建立快捷方式

本实例介绍如何在桌面、程序组和启动菜单中建立快捷方式。
向窗体上添加3个TButton组件，分别用于向桌面、程序组和启动菜单中添加快捷方式。设计完成的主界面如图4-16所示。

图4-16  主界面

首先在程序的uses段中添加对ComObj、ShlObj和Activex的引用，然后添加6个全局变量如下：

  tmpObject : IUnknown;
  tmpSLink : IShellLink;
  tmpPFile : IPersistFile;
  PIDL : PItemIDList;
  StartupDirectory : array[0..MAX_PATH] of Char;
  LinkFilename : WideString;

其中tmpObject、tmpSLink和tmpPFile分别为IUnknown、IShellLink和IPersistFile接口，而PIDL用于存储项目标识符列表，数组StartupDirectory用于存储快捷方式的路径信息，LinkFilename则为快捷方式文件(*.lnk)的路径和文件名信息。
最后添加如下程序初始化代码来初始化各个全局变量：

procedure TfrmMain.FormCreate(Sender: TObject);
begin
    tmpObject := CreateComObject(CLSID_ShellLink);
    //创建建立快捷方式的外壳扩展
    tmpSLink := tmpObject as IShellLink;
    //取得接口
    tmpPFile := tmpObject as IPersistFile;
    //用来储存*.lnk文件的接口
    tmpSLink.SetPath(pChar(Application.ExeName));
    //设定程序所在路径
    tmpSLink.SetWorkingDirectory(pChar(ExtractFilePath(Application.ExeName)));
    //设定工作目录
end;

下面说明如何在桌面建立快捷方式。
在程序运行过程中，如果读者单击“在桌面上建立快捷方式”按钮，就会激活下面的响应代码：

procedure TfrmMain.btnDesktopClick(Sender: TObject);
begin
    SHGetSpecialFolderLocation(0,CSIDL_DESKTOPDIRECTORY,PIDL);
    Fillchar(StartupDirectory,Max_Path+1,0);
    SHGetPathFromIDList(PIDL,StartupDirectory);
    LinkFilename := StartupDirectory + '\Delphi.lnk';
    tmpPFile.Save(pWChar(LinkFilename),FALSE);
end;

程序首先取得桌面快捷方式对应的项目标识符列表，然后通过SHGetPathFromIDList (PIDL,StartupDirectory)语句把取得的项目标识符列表转化为路径信息存储到全局变量StartupDirectory中，最后调用IPersistFile接口的Save方法把本程序的快捷方式存储起来，这时在桌面上就会看到新建的本程序的快捷方式。
在程序组和启动菜单中建立快捷方式的原理与在桌面上建立快捷方式的原理大体相同。
程序代码如下：

unit Unit1;
interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, comobj,ShlObj,activex, StdCtrls;
 
type
  TfrmMain = class(TForm)
    btnDesktop: TButton;
    btnProgram: TButton;
    btnStartup: TButton;
    procedure btnDesktopClick(Sender: TObject);
    procedure btnStartupClick(Sender: TObject);
    procedure btnProgramClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  frmMain: TfrmMain;
  tmpObject : IUnknown;
  tmpSLink : IShellLink;
  tmpPFile : IPersistFile;
  PIDL : PItemIDList;
  StartupDirectory : array[0..MAX_PATH] of Char;
  LinkFilename : WideString;
 
implementation
{$R *.dfm}
 
procedure TfrmMain.btnDesktopClick(Sender: TObject);
begin
    SHGetSpecialFolderLocation(0,CSIDL_DESKTOPDIRECTORY,PIDL);
    //获得桌面的ItemIDList
    Fillchar(StartupDirectory,Max_Path+1,0);
    SHGetPathFromIDList(PIDL,StartupDirectory);
    //获得路径
    LinkFilename := StartupDirectory + '\Delphi.lnk';
    tmpPFile.Save(pWChar(LinkFilename),FALSE);
    //保存*.lnk文件
end;
 
procedure TfrmMain.btnStartupClick(Sender: TObject);
begin
    SHGetSpecialFolderLocation(0,CSIDL_STARTUP,PIDL);
    Fillchar(startupdirectory,Max_Path+1,0);
    SHGetPathFromIDList(PIDL,StartupDirectory);
    LinkFilename := StartupDirectory + '\Delphi.lnk';
    tmpPFile.Save(pWChar(LinkFilename),FALSE);
end;
 
procedure TfrmMain.btnProgramClick(Sender: TObject);
begin
    SHGetSpecialFolderLocation(0,  CSIDL_PROGRAMS,PIDL);
    Fillchar(startupdirectory,Max_Path+1,0);
    SHGetPathFromIDList(PIDL,StartupDirectory);
    if not DirectoryExists(StartupDirectory+'\Delphi') then
    begin
        MkDir(StartupDirectory+'\Delphi');
    end;
    LinkFilename := StartupDirectory + '\Delphi\Delphi.lnk';
    tmpPFile.Save(pWChar(LinkFilename),FALSE);
end;
 
procedure TfrmMain.FormCreate(Sender: TObject);
begin
    tmpObject := CreateComObject(CLSID_ShellLink);
    //创建建立快捷方式的外壳扩展
    tmpSLink := tmpObject as IShellLink;
    //取得接口
    tmpPFile := tmpObject as IPersistFile;
    //用来储存*.lnk文件的接口
    tmpSLink.SetPath(pChar(Application.ExeName));
    //设定程序所在路径
    tmpSLink.SetWorkingDirectory(pChar(ExtractFilePath(Application.ExeName)));
    //设定工作目录
end;
 
end.

保存文件，然后按F9键运行程序，程序运行的初始画面如图4-17所示。

图4-17  程序运行的初始画面
读者可以在程序运行过程中，在桌面、程序组和启动菜单中建立快捷方式，图4-18所示为在桌面上建立了一个快捷方式。

在成熟的软件发布过程中，一般要建立快捷方式以方便用户操作，本程序介绍了如何在3个不同的位置建立快捷方式。

图4-18  在桌面上建立快捷方式