SQL完整备份 wz_Backup.bat

:: 以下脚本实现SQL server多个数据库的完整备份，备份文件名为：数据库_sqldb_日期.bak，并将所有备份文件进行压缩，压缩文件名为：wz_sqldb_日期.bak.rar，压缩完毕后自动删除原备份文件，并ftp上传至另一台服务器。整个脚本的运行过程自动写入tkblbackup.log中，方便进行错误分析。
@echo off
color 27
title 数据库完整备份
rem andyxu
rem http://www.infozc.com
set basePath=D:\sqlBackup
set rar="C:\Program Files\WinRAR\WinRAR.exe"
set svr=sqlbak
set svrrole=wz
set nowtime=%date:~0,10% %time%
set today=%date:~0,10%
if "%time:~0,1%" == " " (set nowh=%time:~1,1%) else (set nowh=%time:~0,2%)
set rarlist="%basePath%\scriptarlst.txt"
set ftplist="%basePath%\script\ftplst.txt"
set baklog="%basePath%\script\tkblbackup.log"
set FtpSrv=10.145.26.188
set FtpPort=21
set FtpUser=jdda
set FtpPwd=jdda_2011
@echo. >> %baklog%
@echo -------------------------------------------------- >> %baklog%
@echo %nowtime% BackupScript is starting....... >> %baklog%

cd /d %basePath%\backupdb
del *.bak /Q

::数据库备份语句，可添加多个数据库
for %%a in (cacheDatas powerDB bamdb) do (
@echo %nowtime% BackupDB %%a is beginning....... >> %baklog%
@osql -s localhost -d master  -E -Q "backup database %%a to disk='%basePath%\backupdb\%%a_%svr%_%today%.bak' with init" >> %baklog%
echo %%a_%svr%_%today%.bak >> %rarlist%
)
::Rar files
%rar% a %svrrole%_%svr%_%today%.bak.rar @%rarlist%  >> %baklog%

::Upload files by ftp
echo open %FtpSrv% %FtpPort% > %ftplist%
echo user %FtpUser% >> %ftplist%
echo %FtpPwd% >> %ftplist%
echo cd %svr% >>%ftplist%
echo bin >> %ftplist%
echo prompt >> %ftplist%
echo lcd  %basePath%\backupdb  >>%ftplist%
echo put %svrrole%_%svr%_%today%.bak.rar >> %ftplist%
echo quit   >> %ftplist%
echo bye    >> %ftplist%
ftp -n -s:%ftplist% >> %baklog%
echo. > %rarlist%
@echo -------------------------------------------------- >> %baklog%
@echo. >> %baklog%
@echo on
@echo 数据库完整备份完成！！！
@pause